标题: 基于单片机汇编语言的电子时钟程序和仿真 [打印本页]
作者: 木皇PHP    时间: 2017-12-26 13:22
标题: 基于单片机汇编语言的电子时钟程序和仿真

  1. /*************************************************
  2. *文件名：电子时钟
  3. *说  明：通过T0方式1定时时时更新，晶振：6MHZ
  4. *************************************************/
  5.                 ORG                0000H
  6.                 AJMP        MAIN
  7.                 ORG                000BH
  8.                 AJMP        IT0P
  9.                 ORG                0100H
  10. MAIN:        MOV         DPTR,#TAB
  11.                 MOV                TMOD,#01H                        ;设T0为方式一，定时
  12.                 MOV                30H,#0AH                        ;装入中断次数
  13.                 MOV                42H,#55                                ;显示55秒位
  14.                 MOV                41H,#59                                ;显示59分位
  15.                 MOV                40H,#23                                ;显示23时位
  16.                 MOV                TH0,#3CH                        ;给T0装入初值
  17.                 MOV                TL0,#0B0H
  18.                 SETB        ET0                                        ;允许T0申请中断               
  19.                 SETB        TR0                                        ;启动T0
  20.                 SETB        EA                                        ;开总中断

  22. HERE:        MOV                R3,42H                                ;调显示子程序（等待中断）
  23.                 MOV                R2,#00
  24.                 ACALL        DISPLAY
  25.                 MOV                R3,41H
  26.                 MOV                R2,#02
  27.                 ACALL        DISPLAY
  28.                 MOV                R3,40H
  29.                 MOV         R2,#04
  30.                 ACALL        DISPLAY
  31.                 AJMP        HERE                                 

  33. ;******1S定时子程序（并显示）******
  34. IT0P:        PUSH        PSW                                        ;现场保护
  35.                 PUSH        Acc                                                                  
  36.                 MOV                TH0,#3CH                        ;重装初值
  37.                 MOV                TL0,#0B0H
  38.                 DJNZ        30H,RETURN                        ;1秒未到，返回
  39.                 MOV                30H,#0AH                        ;重置中断次数
  40.                 ;******显示秒*********
  41.                 MOV                A,42H                                ;"秒"单元加1
  42.                 INC                A
  43.                 MOV                42H,A                                ;“秒”的BCD码返回“秒”单元
  44.                 CJNE        A,#60,RETURN                ;是否到60秒，未到则返回
  45.                 MOV                42H,#00H                        ;计满60秒，“秒”单元清零
  46.                 ;******显示分*********
  47.                 MOV                A,41H                                ;"分"单元加1
  48.                 INC                A
  49.                 MOV                41H,A                                ;“分”的BCD码返回“分”单元
  50.                 CJNE        A,#60,RETURN                ;是否到60分，未到则返回
  51.                 MOV                41H,#00H                        ;计满60分，“分”单元清零
  52.                 ;******显示时*********
  53.                 MOV                A,40H                                ;"时"单元加1
  54.                 INC                A
  55.                 MOV                40H,A                                ;“时”的BCD码返回“时”单元
  56.                 CJNE        A,#24,RETURN                ;是否到24小时，未到则返回
  57.                 MOV                40H,#00H                        ;计满24小时，“时”单元清零
  58. RETURN:        POP                Acc                                        ;恢复现场
  59.                 POP                PSW
  60.                 RETI         

  62. ;******显示子程序（分两屏显示）******
  63. DISPLAY:MOV                A,R3                        ;R3存要显示的两位数字
  64.         MOV                B,#0AH
  65.                 MOV         P2,R2
  66.                 DIV                AB                                ;A为商,表十位；B为余数,表个位
  67.                 MOV                R3,A
  68.                 MOV         A,B                                ;显示个位
  69.         MOVC         A,@A+DPTR
  70.         MOV         P0,A
  71.                 ACALL         DELY
  72.         INC         R2                                ;显示十位
  73.                 MOV         P2,R2
  74.                 MOV         A,R3
  75.         MOVC         A,@A+DPTR
  76.                 MOV         P0,A
  77.         ACALL         DELY
  78.         RET

  80. ;******延时0.5MS子程序******
  81. DELY:        MOV R7,#10
  82. DEL1:        MOV R6,#100
  83.         DJNZ R6,$
  84.         DJNZ R7,DEL1                ;（100*2+2+1）*10+2+1
  85.         RET
  86. TAB:        DB 3FH,06H,5BH,4FH,66H  ;七段共阴显示码
  87.         DB 6DH,7DH,07H,7FH,6FH,3FH               
  88.               END

复制代码
全部资料51hei下载地址：
电子时钟.zip (182.92 KB, 下载次数: 27)



作者: hanzhe    时间: 2017-12-27 19:50
于单片机汇编语言的电子时钟程序和仿真



欢迎光临 (http://www.51hei.com/bbs/) Powered by Discuz! X3.1