[原创diy]试验51单片机驱动3脚增量型旋转编码器 -

标题: [原创diy]试验51单片机驱动3脚增量型旋转编码器 [打印本页]

作者: lxa0 时间: 2018-1-30 14:05
标题: [原创diy]试验51单片机驱动3脚增量型旋转编码器
有很多场合都会用到增量型旋转编码器
比如：数字PLL收音机、音响中的电子音量、等等
于是找了一个旧的做试验(型号是EC16-2A)
效果还不错
给有兴趣的坛友做个参考

试验的图里：
A接单片机（AT89S52）的P32(INT0)
B接在P34口

在P0口接8个led做类似流水灯的指示
即可观察到左右旋转时的效果

作者: lxa0 时间: 2018-1-30 14:06

作者: lxa0 时间: 2018-1-30 14:24
试验用的参考代码：

;这是一个旋转编码器的试验汇编代码2018-1-20
;最后试验修改2018-1-26,几乎没有了抖动
;at89s52,11.0592MHz,
;p32(int0)下降沿做中断判别A,p34(t0)做引脚B判别

ORG 0000H
LJMP mm
ORG 0003H
LJMP pd             ;中断判别A脚

;程序入口*********************************************************
org 0100h
mm:nop
mov 17h,#0feh       ;循环显示p0口的led
mov 18h,#00h          ;4个做判别缓冲用
mov 19h,#00h
mov 1ah,#00h
mov 1bh,#05h
mov p0,17h
mov sp,#4fh          ;设堆栈入口50h
mov tcon,#01h       ;int0下降沿中断
setb ea             ;开总中断
setb ex0             ;开int0
mm0:nop
sjmp mm0

;int0中断代码*****************************************************
org 0300h
pd:nop
clr ea
push acc
push psw
push dph
push dpl
mov a,p3
anl a,#00010100b       ;保留p32和p34脚屏蔽其余引脚
mov 18h,a             ;暂存在r7
acall ys100          ;延时约1.5ms
mov a,p3
anl a,#00010100b
cjne a,18h,pd0       ;不是正转则判别是否反转
cjne a,#10h,pd0       ;A=L,B=H时右移
mov a,17h
rl a
mov 17h,a
mov p0,a
sjmp pd00
pd0:mov a,p3
anl a,#00010100b
mov 19h,a
acall ys100          ;延时约1.5ms
mov a,p3
anl a,#00010100b
cjne a,19h,pd00       ;是干扰则返回
cjne a,#00h,pd00       ;A=B=L时左移
mov a,17h
rr a
mov 17h,a
mov p0,a
pd00:setb ea
pop dpl
pop dph
pop psw
pop acc
reti

ys100:nop             ;延时约1.5mS
ys0:djnz 1ah,$
djnz 1bh,ys0
mov 1ah,#00h
mov 1bh,#05h
ret

end

作者: lxa0 时间: 2018-1-30 14:25
继续实验模拟调谐电台：

作者: lxa0 时间: 2018-1-30 14:26
模拟调谐电台的试验参考代码：

;1602-LCD模拟调电台汇编代码
;Lxa0最后修改于2018-1-28-V1.0
;本代码晶体为11.0592MHz
;代码中未注明的只占用区0

RS EQU p2.5          ;定义液晶接口
RW EQU p2.6
E  EQU p2.7

org 0000h
ljmp mm

;主程序*********************************************************
org 0100h
mm:nop
acall ys
mov tmod,#90h       ;T0设方式0,T1门控与方式1
mov tcon,#04h       ;T0原始方式,INT1下降沿触发
;mov ie,#84h          ;设中断允许
mov ip,#04h          ;设中断优先级别
mov sp,#7fh          ;设堆栈入口
mov 08h,#30h          ;解码转换用
mov 09h,#07h          ;解码转换用
mov 10h,#30h          ;读红外波头存放首址
mov 11h,#2fh          ;读红外波头48个
mov 20h,#00h          ;读红外、解码、动作,电台最大最小标志位06h和05h
mov 21h,#00h          ;动作指令码占
mov 22h,#09h          ;电台频率小数位
mov 23h,#07h          ;电台频率个位
mov 24h,#00h          ;电台频率十位
mov 25h,#01h          ;电台频率百位
mov 26h,#00h          ;XX暂存单元
mov 27h,#00h          ;XX暂存单元
mov p0,#01H          ;清屏
acall wcom
MOV p0,#38H          ;使用8Bits汇流排，显示2行5*7字符
acall wcom
MOV p0,#0CH          ;显示开，光标关
acall wcom
MOV p0,#06H          ;字符不动，光标自动右移一格
acall wcom
MOV p0,#80H          ;第一行的开始位置
acall wcom
MOV DPTR,#TAB001    ;到TABLE1取码
acall xsztab
MOV p0,#0C0H          ;第二行的开始位置
acall wcom
MOV DPTR,#TAB002    ;到TABLE2 取码
acall xsztab
acall cgwr
m0:nop
acall ys
acall xsz
sjmp m0

;显示tab001和tab002子代码*****************************************
xsztab:nop
push dph
push dpl
push acc
push psw
clr psw.3             ;进入区0工作寄存器
clr psw.4
mov r1,#00h
A1:mov a,r1
MOVC A,@A+DPTR       ;到table取码
mov p0,a
acall wdat             ;显示到lcd
INC r1
CJNE A,#0,A1          ;是否到00h
pop psw
pop acc
pop dpl
pop dph
RET

;延时0.5mS子代码**************************************************
ys:nop
push dph
push dpl
push acc
push psw
clr psw.3             ;进入区0工作寄存器
clr psw.4
MOV R7,#04             ;延时0.5mS子程序
ys00:MOV R6,#0FFH
DJNZ R6,$
DJNZ R7,ys00
pop psw
pop acc
pop dpl
pop dph
RET

;以下是字符数据表**************************************************
tab001: db"    Lxa0    ",00h
tab002: db" FM--000.0 MHz  ",00h

;显示xsz子程序<占用区0>********************************************
org 0200h
xsz:nop
push dph             ;保护现场
push dpl
push acc
push psw
mov p0,#0c9h       ;设置小数位地址
lcall wcom
mov a,22h          ;取小数位数据
add a,#30h          ;加上#30h就是去CGROM取数据
mov p0,a
lcall wdat          ;送出显示
mov p0,#0c7h       ;设置频率个位地址
lcall wcom
mov a,23h          ;取频率个位数据
add a,#30h
mov p0,a
lcall wdat          ;送出显示
mov p0,#0c6h       ;设置频率十位地址
lcall wcom
mov a,24h          ;取频率十位数据
add a,#30h
mov p0,a
lcall wdat          ;送出显示
mov p0,#0c5h       ;设置频率百位地址
lcall wcom
mov a,25h          ;取频率百位数据
add a,#30h
mov p0,a
lcall wdat          ;送出显示
mov p0,#80h          ;显示天线符号
lcall wcom
mov p0,#00h
lcall wdat
mov p0,#81h          ;显示信号符号
lcall wcom
mov p0,#01h
lcall wdat
mov p0,#8fh          ;显示电池符号
lcall wcom
mov p0,#02h
lcall wdat
pop psw             ;恢复现场
pop acc
pop dpl
pop dph
ret                ;返回

;写命令和数据子代码************************************************
org 0280h
wcom:CLR RS          ;送命令
CLR RW
clr E
acall ys
setb E
clr E
RET

wdat:SETB RS       ;送数据
CLR RW
clr E
acall ys
setb E
clr E
RET

;建立自定义CGRAM字符库子程序(占用区0工作寄存器)********************
org 0300h
cgwr:nop
push dph
push dpl
push acc
push psw
mov p0,#40h          ;设置CGRAM首地址
lcall wcom
mov r2,#64          ;设置天线信号电池等共8X8=64个代码
mov r3,#00h
mov dptr,#cgtab1    ;设置字符代码表首地址
cgwr00:mov a,r3
movc a,@a+dptr       ;取字符代码
mov p0,a
lcall wdat
inc r3
djnz r2,cgwr00
pop psw
pop acc
pop dpl
pop dph
ret

;以下是CGRAM数据表*************************************************
cgtab1:
db 15H,15H,15H,0EH,04H,04H,04H,00H       ;"天线"代码=0x08h
db 00H,00H,01H,03H,07H,0fH,1fH,00H       ;"信号"代码=0x09h
db 04H,1FH,11H,15H,15H,11H,1FH,00H       ;"电池"代码=0x10h
db 00h,01h,02h,03h,04h,05h,06h,07h       ;"空"代码=0x05h
db 00h,01h,02h,03h,04h,05h,06h,07h       ;"空"代码=0x00h
db 00h,01h,02h,03h,04h,05h,06h,07h       ;"空"代码=0x01h
db 00h,01h,02h,03h,04h,05h,06h,07h       ;"空"代码=0x02h
db 00h,01h,02h,03h,04h,05h,06h,07h       ;"空"代码=0x03h
;******************************************************************
end

作者: xrfxrfxrf008 时间: 2018-2-27 08:54
学习下装备试验

欢迎光临 (http://www.51hei.com/bbs/)