Arduino ESP8266气象站制作附源程序 -

/**********************************************************************
// 项目：简易气象台
// 硬件：适用于NodeMCU ESP8266 + SSD1306
// 功能：连接WiFi后获取相关数据并在OLED屏上显示
// 原版作者：How To Electronics
// 魔改：油管机器猫 bilibili UID:16872024
// 日期：2019/10/04
// 硬件连接说明：
// OLED --- ESP8266
// VCC --- 3V(3.3V)
// GND --- G (GND)
// SDA --- D2(GPIO4)
// SCL --- D3(GPIO0)
**********************************************************************/
#include <ESP8266WiFi.h>
#include <ESP8266HTTPClient.h> // http web access library
#include <ArduinoJson.h> // JSON decoding library 注意：ArduinoJson库5.13.5测试有效
// Libraries for SSD1306 OLED display
#include <Wire.h> // include wire library (for I2C devices such as the SSD1306 display)
#include <Adafruit_GFX.h> // include Adafruit graphics library
#include <Adafruit_SSD1306.h> // include Adafruit SSD1306 OLED display driver
#define OLED_RESET 5 // define SSD1306 OLED reset at ESP8266 GPIO5 (NodeMCU D1)
Adafruit_SSD1306 display(OLED_RESET);
// set Wi-Fi SSID and password
const char *ssid = "*******";
const char *password = "*******";
// 设置当地城市和API
String Location = "Chengdu, CN";//这里我以成都为例
String API_Key = "*************";// 获取API密匙网址：openweathermap点org/price
//注册，登陆获取密匙搜索城市操作简单
void setup(void)
{
Serial.begin(115200);
delay(1000);
Wire.begin(4, 0); // set I2C pins [SDA = GPIO4 (D2), SCL = GPIO0 (D3)], default clock is 100kHz
display.begin(SSD1306_SWITCHCAPVCC, 0x3C); // initialize with the I2C addr 0x3D (for the 128x64)
Wire.setClock(400000L); // set I2C clock to 400kHz
display.clearDisplay();
display.setTextColor(WHITE, BLACK);
display.setTextSize(0.1);
display.setCursor(0, 0);
display.println(" Weather Station ");
display.print("bilibili-Doraemon ");
display.display();
WiFi.begin(ssid, password);
Serial.print("Connecting.");
display.setCursor(0, 36);
display.println("Connecting...");
display.display();
while ( WiFi.status() != WL_CONNECTED )
{
delay(500);
Serial.print(".");
}
Serial.println("connected");
display.print("connected");
display.display();
delay(1000);
display.clearDisplay();
display.display();
display.drawCircle(60,30,30,WHITE);
display.fillCircle(50,20,5,WHITE);
display.fillCircle(70,20,5,WHITE);
display.setTextSize(1);
display.setCursor(38,40);
display.print("Doraemon");
display.display();
delay(1000);
display.clearDisplay();
display.setTextSize(2);
display.setCursor(0, 0);
display.println("Doraemon");
}
void loop()
{
if (WiFi.status() == WL_CONNECTED) //Check WiFi connection status
{
HTTPClient http; //Declare an object of class HTTPClient
// specify request destination
http.begin("api.openweathermap点org/data/2.5/weather?q=" + Location + "&APPID=" + API_Key); // !!
int httpCode = http.GET(); // send the request
if (httpCode > 0) // check the returning code
{
String payload = http.getString(); //Get the request response payload
DynamicJsonBuffer jsonBuffer(512);
// Parse JSON object
JsonObject& root = jsonBuffer.parseObject(payload);
if (!root.success()) {
Serial.println(F("Parsing failed!"));
return;
}
float temp = (float)(root["main"]["temp"]) - 273.15; // get temperature in °C
int humidity = root["main"]["humidity"]; // get humidity in %
float pressure = (float)(root["main"]["pressure"]) / 1000; // get pressure in bar
float wind_speed = root["wind"]["speed"]; // get wind speed in m/s
int wind_degree = root["wind"]["deg"]; // get wind degree in °
// print data
Serial.printf("Temperature = %.2f°C\r\n", temp);
Serial.printf("Humidity = %d %%\r\n", humidity);
Serial.printf("Pressure = %.3f bar\r\n", pressure);
Serial.printf("Wind speed = %.1f m/s\r\n", wind_speed);
Serial.printf("Wind degree = %d°\r\n\r\n", wind_degree);
display.setTextSize(0.1);
display.setCursor(0, 24);
display.printf("Temperature: %5.2f C\r\n", temp);
display.printf("Humidity : %d %%\r\n", humidity);
display.printf("Pressure : %.3fbar\r\n", pressure);
display.printf("Wind speed : %.1f m/s\r\n", wind_speed);
display.printf("Wind degree: %d", wind_degree);
display.drawRect(109, 24, 3, 3, WHITE); // put degree symbol ( ° )
display.drawRect(97, 56, 3, 3, WHITE);
display.display();
}
http.end(); //Close connection
}
delay(60000); // wait 1 minute 每分钟刷新数据一次
}
//结束

复制代码