标题: 【Arduino】168种传感器模块系列实验（140）---跑马灯矩阵键盘模块 [打印本页]
作者: eagler8    时间: 2020-2-7 19:15
标题: 【Arduino】168种传感器模块系列实验（140）---跑马灯矩阵键盘模块
37款传感器与模块的提法，在网络上广泛流传，其实Arduino能够兼容的传感器模块肯定是不止37种的。鉴于本人手头积累了一些传感器和模块，依照实践出真知（一定要动手做）的理念，以学习和交流为目的，这里准备逐一动手试试做实验，不管成功与否，都会记录下来---小小的进步或是搞不定的问题，希望能够抛砖引玉。

【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
（4*4矩阵键盘+4位独立按键+8位跑马灯组合模块）




作者: eagler8    时间: 2020-2-27 20:57
4X4矩阵键盘
是单片机外部设备中所使用的排布类似于矩阵的键盘组。矩阵式结构的键盘显然比直接法要复杂一些，识别也要复杂一些，列线通过电阻接正电源，并将行线所接的单片机的I/O口作为输出端，而列线所接的I/O口则作为输入。由于电路设计时需要更多的外部输入，单独的控制一个按键需要浪费很多的IO资源，所以就有了矩阵键盘，常用的矩阵键盘有4X4和8X8,其中用的最多的是4X4。


作者: eagler8    时间: 2020-2-27 21:00
工作原理
矩阵键盘又称为行列式键盘，它是用4条I/O线作为行线，4条I/O线作为列线组成的键盘。在行线和列线的每一个交叉点上，设置一个按键。这样键盘中按键的个数是4X4个。这种行列式键盘结构能够有效地提高单片机系统中I/O口的利用率。由于单片机IO端口具有线与的功能，因此当任意一个按键按下时，行和列都有一根线被线与，通过运算就可以得出按键的坐标从而判断按键键值。






作者: eagler8    时间: 2020-2-27 21:08
行列扫描法原理
1、使行线为编程的输入线，列线是输出线，拉低所有的列线，判断行线的变化，如果有按键按下，按键按下的对应行线被拉低，否则所有的行线都为高电平。
2、在第一步判断有键按下后， 延时10ms消除机械抖动，再次读取行值，如果此行线还处于低电平状态则进入下 一步，否则返回第一步重新判断。
3、开始扫描按键位置，采用逐 行扫描，每间隔1ms的时间，分别拉低第一列，第二列，第三列，第四 列，无论拉低哪一列其他三列都为高电平，读取行值找到按键的位置，分别把行值和列值储存在寄存器里。
4、从寄存器中找到行值和列 值并把其合并，得到按键值，对此按键值进行编码，按照从第一行第一个一直到第四行第四个逐行进行编码，编码值从“0000” 至“1111” ， 再进行译码，最后显示按键号码。




作者: eagler8    时间: 2020-2-28 08:30
4X4矩阵4管脚直插按键键盘
（1）体积小；
（2）节省空间；
（3）使用方便；
（4）共计16按键；
（5）单片机外扩键盘的上佳选择。



作者: eagler8    时间: 2020-2-28 09:16
矩阵键盘所需库文件<Keypad>
在Arduino IDE 1.8.10 或者以上版本中, 项目->加载库->管理库中搜索Keypad，然后安装即可。
也可以下载库（需要下载库文件 https://github.com/Chris--A/Keypad），然后手动添加到IDE中。




作者: eagler8    时间: 2020-2-28 09:24
4*4矩阵键盘+4位独立按键+8位跑马灯组合模块



作者: eagler8    时间: 2020-2-28 09:28
4*4矩阵键盘+4位独立按键+8位跑马灯组合模块



作者: eagler8    时间: 2020-2-28 10:01



作者: eagler8    时间: 2020-2-28 12:54
测试矩阵键盘部分接线示意图



作者: eagler8    时间: 2020-2-28 13:02
模块上4*4矩阵键盘有一个8脚的端口，理论上可以直接插到Arduino的0-7脚上，但0,1脚用于串口通信，所以只能选择2~13脚，这里选用了2-9脚。

Keypad Pin L1 –> Arduino Pin 2  （行）
Keypad Pin L2 –> Arduino Pin 3
Keypad Pin L3 –> Arduino Pin 4
Keypad Pin L4 –> Arduino Pin 5
Keypad Pin R1 –> Arduino Pin 6  （列）
Keypad Pin R2 –> Arduino Pin 7
Keypad Pin R3 –> Arduino Pin 8
Keypad Pin R4 –> Arduino Pin 9

作者: eagler8    时间: 2020-2-28 14:01

程序之一：测试矩阵键盘部分

  1. /*
  2. 【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3. 实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4. 程序之一：测试矩阵键盘部分
  5. */

  7. #include <Keypad.h>

  9. const byte ROWS = 4;
  10. const byte COLS = 4;

  12. char hexaKeys[ROWS][COLS] = {
  13.   {'1','2','3','A'},
  14.   {'4','5','6','B'},
  15.   {'7','8','9','C'},
  16.   {'*','0','#','D'}
  17. };

  19. byte rowPins[ROWS] = {2, 3, 4, 5};
  20. byte colPins[COLS] = {6, 7, 8, 9};

  22. Keypad customKeypad = Keypad( makeKeymap(hexaKeys), rowPins, colPins, ROWS, COLS);

  24. void setup(){
  25.   Serial.begin(9600);
  26. }

  28. void loop(){
  29.   char customKey = customKeypad.getKey();

  31.   if (customKey){
  32.     Serial.println(customKey);
  33.   }
  34. }
复制代码



作者: eagler8    时间: 2020-2-28 14:05
串口输出16位矩阵键值




作者: eagler8    时间: 2020-2-28 15:19

程序之二：矩阵键盘部分测试每个按键的按下与松开

  1. /*
  2.   【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3.   实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4.   程序之二：矩阵键盘部分测试每个按键的按下与松开
  5. */

  7. #include "Adafruit_Keypad.h"

  9. const byte ROWS = 4; // 行
  10. const byte COLS = 4; // 列
  11. //定义键盘按钮上的符号
  12. char hexaKeys[ROWS][COLS] = {
  13.   {'1', '2', '3', 'A'},
  14.   {'4', '5', '6', 'B'},
  15.   {'7', '8', '9', 'C'},
  16.   {'*', '0', '#', 'D'}
  17. };

  19. byte rowPins[ROWS] = {2, 3, 4, 5}; //连接到键盘的行插脚
  20. byte colPins[COLS] = {6, 7, 8, 9}; //连接到键盘的列插脚

  22. //初始化类NewKeypad的实例
  23. Adafruit_Keypad customKeypad = Adafruit_Keypad( makeKeymap(hexaKeys), rowPins, colPins, ROWS, COLS);

  25. void setup() {
  26.   Serial.begin(9600);
  27.   customKeypad.begin();

  29. }

  31. void loop() {
  32.   //把你的主代码放在这里，重复运行
  33.   customKeypad.tick();

  35.   while (customKeypad.available()) {
  36.     keypadEvent e = customKeypad.read();
  37.     Serial.print((char)e.bit.KEY);
  38.     if (e.bit.EVENT == KEY_JUST_PRESSED) Serial.println(" pressed");
  39.     else if (e.bit.EVENT == KEY_JUST_RELEASED) Serial.println(" released");
  40.   }

  42.   delay(10);
  43. }
复制代码



作者: eagler8    时间: 2020-2-28 15:22

作者: eagler8    时间: 2020-2-28 16:17
本帖最后由 eagler8 于 2020-2-28 16:19 编辑

程序之三：矩阵键盘部分测试按键'*'和 '#'控制LED灯（板载13脚）

  1. /*
  2.   【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3.   实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4.   程序之三：矩阵键盘部分测试按键'*'和 '#'控制LED灯（板载13脚）
  5. */

  7. #include <Keypad.h>

  9. const byte ROWS = 4; //四行
  10. const byte COLS = 3; //三列
  11. //定义键盘按钮上的符号
  12. char keys[ROWS][COLS] = {
  13.   {'1', '2', '3'},
  14.   {'4', '5', '6'},
  15.   {'7', '8', '9'},
  16.   {'*', '0', '#'}
  17. };

  19. byte rowPins[ROWS] = {2, 3, 4, 5}; //连接到键盘的行插脚
  20. byte colPins[COLS] = {6, 7, 8};  //连接到键盘的列插脚

  22. Keypad keypad = Keypad( makeKeymap(keys), rowPins, colPins, ROWS, COLS );
  23. byte ledPin = 13;

  25. boolean blink = false;
  26. boolean ledPin_state;

  28. void setup() {
  29.   Serial.begin(9600);
  30.   pinMode(ledPin, OUTPUT);              // 将数字管脚设置为输出
  31.   digitalWrite(ledPin, HIGH);           // 打开LED
  32.   ledPin_state = digitalRead(ledPin);   // 存储初始LED状态。当LED亮起时为高
  33.   keypad.addEventListener(keypadEvent); // 为此键盘添加事件侦听器
  34. }

  36. void loop() {
  37.   char key = keypad.getKey();

  39.   if (key) {
  40.     Serial.println(key);
  41.   }
  42.   if (blink) {
  43.     digitalWrite(ledPin, !digitalRead(ledPin));   // 将LED引脚从Hi2Lo或Lo2Hi更改
  44.     delay(100);
  45.   }
  46. }

  48. // 处理一些特殊事件
  49. void keypadEvent(KeypadEvent key) {
  50.   switch (keypad.getState()) {
  51.     case PRESSED:
  52.       if (key == '#') {
  53.         digitalWrite(ledPin, !digitalRead(ledPin));
  54.         ledPin_state = digitalRead(ledPin);        // 记住LED状态，亮或不亮
  55.       }
  56.       break;

  58.     case RELEASED:
  59.       if (key == '*') {
  60.         digitalWrite(ledPin, ledPin_state);   // 从开始闪烁前恢复LED状态
  61.         blink = false;
  62.       }
  63.       break;

  65.     case HOLD:
  66.       if (key == '*') {
  67.         blink = true;    // 按住*键时，LED闪烁
  68.       }
  69.       break;
  70.   }
  71. }
复制代码



作者: eagler8    时间: 2020-2-28 16:25
'#'键控制LED灯自锁开关，'*'键按下时LED闪烁，松开熄灭



作者: eagler8    时间: 2020-2-28 16:38
测试跑马灯部分接线示意图



作者: eagler8    时间: 2020-2-28 16:41

作者: eagler8    时间: 2020-2-29 09:43
程序之四：测试跑马灯部分，循环逐个点亮，逐个熄灭

  1. /*
  2.   【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3.   实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4.   程序之四：测试跑马灯部分，循环逐个点亮，逐个熄灭
  5. */

  7. int BASE = 6 ;
  8. int NUM = 8;

  10. void setup()
  11. {
  12.   for (int i = BASE; i < BASE + NUM; i ++)
  13.   {
  14.     pinMode(i, OUTPUT);
  15.   }
  16. }

  18. void loop()
  19. {
  20.   for (int i = BASE; i < BASE + NUM; i ++)
  21.   {
  22.     digitalWrite(i, LOW);
  23.     delay(200);
  24.   }
  25.   for (int i = BASE; i < BASE + NUM; i ++)
  26.   {
  27.     digitalWrite(i, HIGH);
  28.     delay(200);
  29.   }
  30. }
复制代码



作者: eagler8    时间: 2020-2-29 09:51

作者: eagler8    时间: 2020-2-29 10:07
  1. /*
  2.   【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3.   实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4.   程序之五：测试跑马灯部分，循环单个熄灭
  5. */

  7. byte ledPin[] = {6, 7, 8, 9, 10, 11, 12, 13};
  8. int ledDelay(300);
  9. int direction = 1;
  10. int currentLED = 0;
  11. unsigned long changeTime;
  12. void setup() {
  13.   for (int x = 0; x <= 7; x++)
  14.     pinMode(ledPin[x], OUTPUT); //数组从0开始分配存储单元，这里要非常注意循环变量的初值和终值，0－7刚好循环至8
  15.   changeTime = millis();
  16. }

  18. void loop() {
  19.   if ((millis() - changeTime) > ledDelay)
  20.   { changeLED(); //运行时间如果超过一个数量的延时时间，则由函数changeLED()控制LED点亮的变化
  21.     changeTime = millis();
  22.   }
  23. }



  27. void changeLED() {
  28.   for (int x = 0; x <= 7; x++)
  29.   { digitalWrite(ledPin[x], LOW); //8只LED灯低平信号，熄灭
  30.   }
  31.   digitalWrite(ledPin[currentLED], HIGH); //设当前LED高平信号，点亮
  32.   currentLED += direction; //当前值增加为direction表示的值
  33.   if (currentLED == 7) {
  34.     direction = -1; //当前灯为第8只灯，currentLED当前值改为－1，改变亮灯方向
  35.   }
  36.   if (currentLED == 0) {
  37.     direction = 1; //当前灯为第1只灯，currentLED当前值为+1，从第1只灯开始计数
  38.   }

  40. }
复制代码


作者: eagler8    时间: 2020-2-29 10:17
测试独立按键部分+跑马灯部分




作者: eagler8    时间: 2020-2-29 10:42
程序之六：测试独立按键部分+跑马灯部分，按键控制跑马灯

  1. /*
  2.   【Arduino】168种传感器模块系列实验（资料+代码+图形+仿真）
  3.   实验一百四十：YL-004老款20按键独立键盘 跑马灯矩阵键盘模块
  4.   程序之六：测试独立按键部分+跑马灯部分，按键控制跑马灯
  5. */

  7. int buttonPin = 2 ;   // 定义按键引脚
  8. int BASE = 6;        // 定义第一个LED引脚
  9. int NUM = 8;         // LED 的总数
  10. int val;

  12. void setup()
  13. {
  14.   Serial.begin(9600);
  15.   pinMode(buttonPin, INPUT);
  16.   for (int i = BASE; i < BASE + NUM; i ++)
  17.   {
  18.     pinMode(i, OUTPUT);   // 设定LED引脚为输出引脚
  19.   }
  20. }

  22. void loop()
  23. {
  24.   liangdeng();            // 循环亮灯子程序
  25.   delay(200);             // 每次循环间隔时间
  26.   miedeng();              // LED全灭子程序
  27. }

  29. void liangdeng()
  30. {
  31.   for (int i = BASE; i < BASE + NUM; i ++)
  32.   {
  33.     digitalWrite(i, LOW);  //设定LED引脚逐个输出高电平逐个点亮
  34.     val = digitalRead(buttonPin);   // 储存按键变换量
  35.     if (val == HIGH)          //判断是否按下按键，弱已按下按键跳出当前循环
  36.     {
  37.       val = HIGH;
  38.       break;
  39.     }
  40.     delay(200);        //延时
  41.   }
  42. }

  44. void miedeng()
  45. {
  46.   for (int i = BASE; i < BASE + NUM; i ++)
  47.   {
  48.     digitalWrite(i, HIGH);    //设定LED引脚逐个输出低电平逐个点亮
  49.   }
  50. }
复制代码



作者: eagler8    时间: 2020-2-29 15:02
编玩边学开源图形编程




作者: eagler8    时间: 2020-2-29 15:17
实验开源仿真编程（linkboy3.6）







欢迎光临 (http://www.51hei.com/bbs/) Powered by Discuz! X3.1