求一份51单片机和DS18B20汇编程序 -

标题: 求一份51单片机和DS18B20汇编程序 [打印本页]

作者: 979856362dlut 时间: 2020-8-23 11:01
标题: 求一份51单片机和DS18B20汇编程序
学习DS18B20好久了，想用汇编语言。以下是我的代码，仿真LED用来检测温度能否正确转换。求大佬可以指正，或者有汇编语言写的ds18b20直接分享我一份谢谢

DQ BIT P1.3
DQ_DELAY EQU 40H ;40H存放延时所需的时间
LSB       EQU 29H ;读取温度的低字节
MSB       EQU 28H ;读取温度的高字节
TEMP_XIAO EQU 27H ;保存温度的小数部分
TEMP_GE       EQU 26H ;保存温度的个位
TEMP_SHI EQU 25H ;保存温度的十位
TEMP_BAI EQU 24H ;保存温度的百位
TEMP_FU       EQU 23H ;保存温度的正负号
ORG 0000H
LJMP START
ORG 001BH       ;T1中断入口地址
LJMP INT_T1
ORG 0100H
START: MOV SP,#60H
;MOV R1,#28H
LCALL INTI_T1       ;设置T1相关的寄存器

LOOP:
CJNE R2,#1,NEXT
;R2=1,2s定时，开始进行温度转换
LCALL STRAT_18B20 ;启动一次18B20
LCALL TEMP_PROC ;转换得到温度的各位

MOV A,25H          ;选转换后的十位简单检测是否能转换成功
CPL A
MOV P0,A
NEXT: LJMP LOOP

;转换得到温度的各位
TEMP_PROC:
MOV A,MSB
MOV TEMP_FU,#'+'
RLC A
JNC TEMP_VALUE
MOV TEMP_FU,#'-'
MOV A,LSB       ;若为负值，取反加一
CPL A
INC A
MOV LSB,A
MOV A,MSB
CPL A
MOV MSB,A

TEMP_VALUE:
MOV A,LSB
ANL A,#0FH       ;小数部分，低字节低四位
MOV B,#10       ;小数部分处理，乘以10，再除以16即为小数值
MUL AB
MOV B,#16
DIV AB
MOV TEMP_XIAO,A ;存储小数值

MOV A,LSB
SWAP A       ;交换指令，整数部分在低位
ANL A,#0FH       ;屏蔽高四位得到低4位的整数部分
MOV R0,A       ;暂存低四位
MOV A,MSB       ;取高字节的整数部分
SWAP A
ORL A,R0       ;与低位相或，得到实际温度的整数部分
MOV B,#100
DIV AB
MOV TEMP_BAI,A ;存储百位
MOV A,B       ;十位个位数据
MOV B,#10
DIV AB
MOV TEMP_SHI,A
MOV TEMP_GE,B
RET

;启动一次18B20
STRAT_18B20:
;复位总线，获取存在脉冲，以启动一次读写操作
CLR EA       ;禁止中断
CLR DQ       ;产生500us复位脉冲
MOV DQ_DELAY,#50
LCALL DELAY_US
SETB DQ
MOV DQ_DELAY,#6 ;延时60us
LCALL DELAY_US
WAIT1:
JB DQ,WAIT1 ;DQ=0时，表示读取到了低电平
SETB EA       ;使能总中断
;DQ=0，18B20正确应答，读取温度值
MOV A,#0CCH       ;跳过ROM
LCALL WR_18B20
MOV A,#44H       ;启动一次温度转换
LCALL WR_18B20
MOV A,#0BEH       ;发送读命令
LCALL WR_18B20
LCALL READ_18B20 ;读低八位
MOV LSB,A
LCALL READ_18B20 ;读高八位
MOV MSB,A
RET

;向18B20写一字节，内容存在A
WR_18B20:
CLR EA
MOV R3,#8       ;一个字节8bit
CLR C
LOOP2:
RRC A
CLR DQ
NOP          ;延时2us
NOP
MOV DQ,C
MOV DQ_DELAY,#6 ;延时60us
LCALL DELAY_US
SETB DQ       ;拉高通信引脚
NOP
DJNZ R3,LOOP2
SETB EA
RET

;读取DS18B20一个字节，存在A中
READ_18B20:
CLR EA
MOV R4,#8

LOOP3:
CLR DQ
NOP          ;延时2us
NOP
SETB DQ
NOP
NOP
MOV C,DQ       ;读取通信引脚，赋值给Cy
RRC A
MOV DQ_DELAY,#6 ;延时60us
LCALL DELAY_US
DJNZ R4,LOOP3
SETB EA
RET

;初始化T1设置相关寄存器
INTI_T1:
MOV TMOD,#11H ;设置T1为方式1
MOV TL1,#0FCH ;设定时为50ms
MOV TH1,#4BH
MOV R1,#28H       ;辅助定时器1定时2s
SETB TR1       ;启动T1
SETB ET1       ;开T1中断
SETB EA       ;开总中断
RET

;T1中断服务子程序，定时2s
INT_T1:
PUSH PSW       ;保护现场
MOV TL1,#0FCH ;设定时为50ms，重新装载
MOV TH1,#4BH
DJNZ R1,RETURN

MOV R1,#28H       ;延时2s的常数
MOV R2,#1       ;定时2s，开启新一次温度转换
RETURN: POP PSW
RETI

;延时us的子程序，延时时间存在DQ_DELAY
DELAY_US:
MOV R6,DQ_DELAY
DELAY:
MOV R7,#3
DJNZ R7,$
DJNZ R6,DELAY
RET

END

11.png (59.4 KB, 下载次数: 77)

作者: csmyldl 时间: 2020-8-24 13:05
晶振：12M
TEMPER_L EQU 36H
TEMPER_H EQU 35H
TEMPER_NUM  EQU 60H
FLAG1    BIT 00H
DQ       BIT P0.0

AAA:MOV SP,#70H
   LCALL GET_TEMPER
   LCALL TEMPER_COV
   LJMP  AAA
   NOP
   ;------------------读出转换后的温度值
GET_TEMPER:
   SETB  DQ          ; 定时入口
BCD:LCALL INIT_1820
   JB FLAG1,S22
   LJMP  BCD       ; 若DS18B20不存在则返回

S22:LCALL DELAY1
   MOV A,#0CCH       ; 跳过ROM匹配------0CC
   LCALL WRITE_1820
   MOV A,#44H       ; 发出温度转换命令
   LCALL WRITE_1820
   NOP
   LCALL DELAY
   LCALL DELAY
CBA:LCALL INIT_1820
   JB FLAG1,ABC
   LJMP  CBA
ABC:LCALL DELAY1
   MOV A,#0CCH       ; 跳过ROM匹配
   LCALL WRITE_1820
   MOV A,#0BEH       ; 发出读温度命令
   LCALL WRITE_1820
   LCALL READ_18200 ;READ_1820
   RET
      ;------------------读DS18B20的程序,从DS18B20中读出一个字节的数据
READ_1820:
   MOV R2,#8
RE1:
   CLR C
   SETB DQ
   NOP
   NOP
   CLR DQ
   NOP
   NOP
   NOP
   SETB DQ
   MOV R3,#7
   DJNZ R3,$
   MOV C,DQ
   MOV R3,#23
   DJNZ R3,$
   RRC A
   DJNZ R2,RE1
   RET

   ;-------------------写DS18B20的程序
WRITE_1820:
   MOV R2,#8
   CLR C
WR1:
   CLR DQ
   MOV R3,#6
   DJNZ R3,$
   RRC A
   MOV DQ,C
   MOV R3,#23
   DJNZ R3,$
   SETB DQ
   NOP
   DJNZ R2,WR1
   SETB DQ
   RET
   ;-------------------读DS18B20的程序,从DS18B20中读出两个字节的温度数据
READ_18200:
   MOV R4,#2          ; 将温度高位和低位从DS18B20中读出
   MOV R1,#36H       ; 低位存入36H(TEMPER_L),高位存入35H(TEMPER_H)
RE00:
   MOV R2,#8
RE01:
   CLR C
   SETB DQ
   NOP
   NOP
   CLR DQ
   NOP
   NOP
   NOP
   SETB DQ
   MOV R3,#7
   DJNZ R3,$
   MOV C,DQ
   MOV R3,#23
   DJNZ R3,$
   RRC A
   DJNZ R2,RE01
   MOV @R1,A
   DEC R1
   DJNZ R4,RE00
   RET

   ;-------------------将从DS18B20中读出的温度数据进行转换
TEMPER_COV:
   MOV A,#0F0H
   ANL A,TEMPER_L       ; 舍去温度低位中小数点后的四位温度数值
   SWAP A
   MOV TEMPER_NUM,A
   MOV A,TEMPER_L
   JNB ACC.3,TEMPER_COV1 ; 四舍五入去温度值
   INC TEMPER_NUM

TEMPER_COV1:
   MOV A,TEMPER_H
   ANL A,#07H
   SWAP A
   ORL A,TEMPER_NUM
   MOV TEMPER_NUM,A ; 保存变换后的温度数据
   LCALL BIN_BCD
   RET
   ;-------------------将16进制的温度数据转换成压缩BCD码
BIN_BCD:
   MOV DPTR,#TEMP_TAB
   MOV A,TEMPER_NUM
   MOVC A,@A+DPTR
   MOV TEMPER_NUM,A
   RET

TEMP_TAB:
   DB 00H,01H,02H,03H,04H,05H,06H,07H
   DB 08H,09H,10H,11H,12H,13H,14H,15H
   DB 16H,17H,18H,19H,20H,21H,22H,23H
   DB 24H,25H,26H,27H,28H,29H,30H,31H
   DB 32H,33H,34H,35H,36H,37H,38H,39H
   DB 40H,41H,42H,43H,44H,45H,46H,47H
   DB 48H,49H,50H,51H,52H,53H,54H,55H
   DB 56H,57H,58H,59H,60H,61H,62H,63H
   DB 64H,65H,66H,67H,68H,69H,70H,71H
   DB 72H,73H,74H,75H,76H,77H,78H,79H
   DB 80H,81H,82H,83H,84H,85H,86H,87H
   DB 88H,89H,90H,91H,92H,93H,94H,95H
   DB 96H,97H,98H,99H

   ;-------------------DS18B20初始化程序
INIT_1820:
      SETB DQ
      NOP
      CLR DQ
      MOV R0,#80H
TSR1:
      DJNZ R0,TSR1       ; 延时
      SETB DQ
      MOV R0,#25H       ;96US-25H
TSR2:
      DJNZ R0,TSR2
      JNB DQ,TSR3
      LJMP TSR4          ; 延时
TSR3:
      SETB FLAG1 ; 置标志位,表示DS1820存在
      LJMP TSR5
TSR4:
      CLR FLAG1    ; 清标志位,表示DS1820不存在
      LJMP TSR7
TSR5:
      MOV R0,#06BH       ;200US
TSR6:
      DJNZ R0,TSR6       ; 延时
TSR7:
      SETB DQ
      RET
      ;------------------重新写DS18B20暂存存储器设定值
RE_CONFIG:
      JB FLAG1,RE_CONFIG1 ; 若DS18B20存在,转RE_CONFIG1
      RET
RE_CONFIG1:
      MOV A,#0CCH       ; 发SKIP ROM命令
      LCALL WRITE_1820
      MOV A,#4EH       ; 发写暂存存储器命令
      LCALL WRITE_1820

      MOV A,#00H       ; TH(报警上限)中写入00H
      LCALL WRITE_1820
      MOV A,#00H       ; TL(报警下限)中写入00H
      LCALL WRITE_1820
      MOV A,#7FH       ; 选择12位温度分辨率
      LCALL WRITE_1820
      RET
      ;------------------延时子程序
  DELAY:MOV R7,#00H
MIN:DJNZ  R7,YS500
      RET
  YS500:LCALL YS500US
      LJMP  MIN
YS500US:MOV R6,#00H
      DJNZ  R6,$
      RET
DELAY1:MOV R7,#20H
      DJNZ  R7,$
      RET

欢迎光临 (http://www.51hei.com/bbs/)