用STC15F104W单片机制作定时IC源码，适用于各种需延时通断、循环通断的控制场合 -

;----------------------------- 端口定义 ------------------------------------
MOC EQU P3.0 ;5脚，导通状态输出低电平；断开状态输出高电平
KEY EQU P3.1 ;6脚，按键KEY
EC11A EQU P3.2 ;7脚，接编码器的A引脚
EC11B EQU P3.3 ;8脚，接编码器的B引脚
DIO EQU P3.4 ;1脚，接显示模块TM1637的DIO
CLK EQU P3.5 ;3脚，接显示模块TM1637的CLK
;---------------------------- 位地址及RAM的使用 ----------------------------
;(20H)第0位：1=编码器有旋转动作；0=没有旋转动作
;(20H)第1位：1=编码器顺时针正转；0=编码器逆时针反转
;(20H)第2位：1=暂停；0=正常运行
;(20H)第3位：1=禁止；0=允许。进行各项设置时使用，允许/禁止检查剩余时间
;(20H)第4位：1=闪烁显示；0=不闪烁。进行各项设置时用
;(20H)第5位：1=不显示，0=显示，数字及冒号闪烁时用，每0.5秒变化一次
;(20H)第6位：1=关闭时间显示，3秒88:88或5秒E1显示占用；0=正常显示
;(20H)第7位：1=已进入“上电延时导通”的始终导通状态；0=正常
;(21H)第8位：1=禁止响应按键动作；0=正常
;(21H)第9位：1=允许恢复响应按键动作；0=正常
FWBZ1 EQU 022H ;复位判断标志1，也作EEPROM数据判断标志
FWBZ2 EQU 023H ;复位判断标志2，也作EEPROM数据判断标志
DTS EQU 024H ;导通时间(时)，0~99
DTF EQU 025H ;导通时间(分)，0~59
DTM EQU 026H ;导通时间(秒)，0~59
DTHM EQU 027H ;导通时间，100(0~99)×10毫秒
XHDS EQU 028H ;循环定时，0=无限循环；1=不循环；2~99=循环次数
SMMS EQU 029H ;睡眠模式，0=始终显示；1~59=无操作进入睡眠（分钟）
BMQZJ EQU 02AH ;编码器每转动一小格的增/减值，1~30分钟
SMGLD EQU 02BH ;数码管亮度，1~8级
DKS EQU 02CH ;断开时间(时)，0~99
DKF EQU 02DH ;断开时间(分)，0~59
DKM EQU 02EH ;断开时间(秒)，0~59
DKHM EQU 02FH ;断开时间，100(0~99)×10毫秒
SDYSS EQU 030H ;上电延时导通(时)，0~99
SDYSF EQU 031H ;上电延时导通(分)，0~59
SDYSM EQU 032H ;上电延时导通(秒)，0~59
YSMS EQU 033H ;延时导通模式，0~2
YSJS EQU 034H ;在上电延时导通状态时，按下KEY持续0~99秒结束该状态
YSXY EQU 035H ;延时响应，在上电延时导通状态时，此处为0才响应按键动作
DSSJS EQU 036H ;定时时间，时
DSSJF EQU 037H ;定时时间，分
DSSJM EQU 038H ;定时时间，秒
DSSJHM EQU 039H ;定时时间，毫秒，100(0~99)×10毫秒=1秒
SMJSF EQU 03AH ;睡眠计时(分)
SMJSM EQU 03BH ;睡眠计时(秒)
SMJS EQU 03CH ;睡眠处理计时用
XHJS EQU 03DH ;循环定时用，导通次数计数
SHMJS EQU 03EH ;(10)毫秒计数，每10毫秒减1，直到为0
HMJS EQU 03FH ;(10)毫秒计数2，为0后自动重新放入99
MJS EQU 040H ;秒计数，每秒减1，直到为0
DQZT EQU 041H ;当前状态，0=导通、1=断开，2=上电延时导通
XSHC1 EQU 042H ;缓存1，与上次不同就立即显示，否则0.5秒显示一次
XSHC2 EQU 043H ;缓存2，与上次不同就立即显示，否则0.5秒显示一次
XXSZ EQU 044H ;下限数值，进行各项设置时用
SXSZ EQU 045H ;上限数值，进行各项设置时用
ZXM1 EQU 046H ;显示用，待发送到TM1637的字形码1
ZXM2 EQU 047H ;显示用，待发送到TM1637的字形码2
ZXM3 EQU 048H ;显示用，待发送到TM1637的字形码3
ZXM4 EQU 049H ;显示用，待发送到TM1637的字形码4
DSZJ EQU 04AH ;加减定时时间使用
DISPL EQU 04BH ;要显示的项目
;
;定义主界面状态下长按快速加减使能的常数：
KSJJ EQU 080H ;禁止主界面状态下长按快速加减
;KSJJ EQU 081H ;允许主界面状态下长按快速加减
;当使用按键代替编码器，需要“长按快速加减”功能时，把080H改为081H。
;
;--------------- 看门狗、EEPROM特殊功能寄存器地址 ---------------
AUXR EQU 08EH ;辅助寄存器
WDT_CONTR EQU 0C1H ;看门狗地址
IAP_DATA EQU 0C2H ;数据寄存器，读出、写入的数据放在此处
IAP_ADDRH EQU 0C3H ;地址寄存器高八位
IAP_ADDRL EQU 0C4H ;地址寄存器低八位
IAP_CMD EQU 0C5H ;命令寄存器，0=关闭，1=读，2=写，3=擦除
IAP_TRIG EQU 0C6H ;命令触发寄存器，每次操作先放入5A再放入A5，命令立即被触发起动
IAP_CONTR EQU 0C7H ;控制寄存器，Flash操作允许/禁止及等待时间
ENABLE_IAP EQU 083H ;定义Flash操作等待时间及允许IAP/ISP/EEPROM操作的常数，时钟<12MHz时为83H
;======================= 程序代码开址 =======================
ORG 0000H
LJMP START
ORG 000BH ;T0中断入口
LJMP T0INT ;T0中断入口
ORG 0030H ;程序代码始址安排在30H
;--------------- 定时器0中断(10毫秒产生一次中断) ---------------
T0INT:
PUSH ACC
PUSH PSW
SETB RS1 ;RS1、RS0组合为11，选择第3组工作寄存器，R0~R7地址为18H~1FH
SETB RS0 ;退出中断时恢复默认的工作寄存器（第0组：R0~R7地址为00H~07H）
LCALL TIME ;处理各项时间、状态切换
LCALL DISPLAY ;显示
JB 02H,T0INT0 ;如果位地址02H为1(暂停)就转移，断开
JB 07H,T0INT1 ;如果位地址07H为1(始终导通)就转移，导通
MOV A,DQZT ;装入“当前状态”
JNZ T0INT0 ;不是0(导通时间)就转移，断开
MOV A,DSSJHM ;是“导通时间”，装入定时时间(毫秒)到寄存器A
JNZ T0INT1 ;不是0就转移，导通
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JNZ T0INT1 ;不是0就转移，导通
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JNZ T0INT1 ;不是0就转移，导通
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ T0INT1 ;不是0就转移，导通
T0INT0:
SETB MOC ;定时时间为0，置MOC为高电平，断开
LJMP T0INT2
T0INT1:
CLR MOC ;置MOC为低电平，可控硅(或继电器)导通,通电
T0INT2:
POP PSW
POP ACC
RETI
;--------------- 设置各项默认值（#号后面都为十进制数） ----------------
SZMRZ:
MOV DTS,#10 ;导通时长(时)，0~99。默认10小时
MOV DTF,#0 ;导通时长(分)，0~59
MOV DTM,#0 ;导通时长(秒)，0~59
MOV DTHM,#0 ;导通时长，0~99(×10毫秒)
MOV XHDS,#1 ;循环定时，0=无限循环；1=不循环；2~99=导通次数
MOV SMMS,#0 ;睡眠模式，0=始终显示；1~59=无操作进入睡眠（分钟）
MOV BMQZJ,#1 ;实时调整时，编码器每转动一格的+、-值（分钟)
MOV SMGLD,#3 ;数码管亮度，8级亮度最高
MOV DKS,#2 ;断开时长(时)，0~99
MOV DKF,#0 ;断开时长(分)，0~59
MOV DKM,#0 ;断开时长(秒)，0~59
MOV DKHM,#0 ;断开时长，0~99(×10毫秒)
MOV SDYSS,#0 ;上电延时导通时长(时)，0~99
MOV SDYSF,#0 ;上电延时导通时长(分)，0~59
MOV SDYSM,#0 ;上电延时导通时长(秒)，0~59
MOV YSMS,#0 ;延时导通模式，0~2；
MOV YSJS,#99 ;结束“上电延时导通”的“按下持续时间”秒计数，0~99
RET
;--------------- 定时器T0设置(10毫秒产生一次中断) ----------------
SETINT: ;10毫秒@11.0592MHz
ANL AUXR,#7FH ;定时器时钟12T模式
ANL TMOD,#0F0H ;设置定时器模式
MOV TL0,#000H ;设置定时初值
MOV TH0,#0DCH ;设置定时初值
CLR TF0 ;清除TF0标志
SETB TR0 ;定时器0开始计时
SETB ET0 ;允许定时器0中断
SETB EA ;允许全局中断
RET
;---- 启动看门狗及喂狗，11.0592MHz预分频数=2(71.1毫秒)，00111000B(38H) ----
WG:
MOV WDT_CONTR,#00111000B
RET
;*********************************** 主程序开始 ***********************************
START:
MOV SP,#050H ;设置堆栈指针
MOV A,FWBZ1 ;检查复位判断标志，不相同就是初次上电，从初始化开始运行
CJNE A,#0C8H,START0 ;检查复位判断标志，不相同就是初次上电，从初始化开始运行
MOV A,FWBZ2 ;检查复位判断标志，不相同就是初次上电，从初始化开始运行
CJNE A,#0D9H,START0 ;检查复位判断标志，不相同就是初次上电，从初始化开始运行
LCALL SETINT ;相同，定时器设置(10毫秒产生一次中断)
LJMP START2 ;相同，跳过初始化继续运行
START0:
CLR A ;初始化，RAM从20H开始清零30H个字节
MOV R0,#30H ;初始化，RAM从20H开始清零30H个字节
MOV R1,#20H ;初始化，RAM从20H开始清零30H个字节
START1:
MOV @R1,A ;初始化，RAM从20H开始清零30H个字节
INC R1 ;初始化，RAM从20H开始清零30H个字节
DJNZ R0,START1 ;初始化，RAM从20H开始清零30H个字节
MOV FWBZ1,#0C8H ;初始化，放入复位判断标志1到RAM
MOV FWBZ2,#0D9H ;初始化，放入复位判断标志2到RAM
MOV YSXY,#0FFH ;初始化，放入结束“上电延时导通”的延时响应时间，4.2分钟
LCALL SETINT ;初始化，定时器设置(10毫秒产生一次中断)
LCALL REEP ;初始化，读EEPROM保存的各项设置，没有就设为默认值并保存
START2:
CLR 06H ;位地址06H置为0，正常显示
MOV DISPL,#0 ;设置要显示的目标，0=显示定时时间
LCALL SKEY ;扫描KEY
JC START3 ;有按键动作(C=1)就转移
LCALL Scan1 ;扫描编码器（有方向标志）
JNB 00H,START2 ;如果位地址00H为0（编码器没有转动）就转移
LCALL BMQCL ;调用编码器动作处理子程序
LJMP START2
START3:
LCALL AJDZCL ;调用按键动作处理子程序
LJMP START2
;*********************************** 主程序结束 ***********************************
;
;----------------------------------------------------------------------------------------
;子程序：编码器动作处理，实时调整定时时间
;如果是用按键代替编码器，支持长按快速加减(需要把“长按快速加减使能常数”由080H改为081H)。
;----------------------------------------------------------------------------------------
BMQCL:
MOV A,#KSJJ ;装入“长按快速加减使能常数”
CJNE A,#081H,BMQCL5 ;如果不是“支持长按快速加减”就转移
MOV SHMJS,#50 ;设置有效长按所需时长，50×10毫秒=500毫秒
BMQCL1:
MOV A,SHMJS ;装入(10)毫秒计数
JZ BMQCL2 ;如果时长达到(为0)就转移
LCALL Scan2 ;扫描编码器（无方向标志）
JB 00H,BMQCL1 ;动作未结束就转移
LCALL DSSJZJ ;动作结束，根据方向加/减定时时间
RET
BMQCL2:
LCALL DSSJZJ ;根据方向加/减定时时间
MOV SHMJS,#13 ;加/减间隔时间，(×10)毫秒
BMQCL3:
MOV A,SHMJS ;装入(10)毫秒计数
JNZ BMQCL4 ;时间未到(不为0)就转移
LJMP BMQCL2 ;已达到设定的时长，转移，根据方向加/减定时时间
BMQCL4:
LCALL DELAY10 ;延时10毫秒
LCALL Scan2 ;扫描编码器（无方向标志）
JB 00H,BMQCL3 ;动作未结束就转移
LCALL DELAY10 ;延时10毫秒
LCALL Scan2 ;第2次扫描编码器（无方向标志）
JB 00H,BMQCL3 ;动作未结束就转移
LCALL DELAY10 ;延时10毫秒
LCALL Scan2 ;第3次扫描编码器（无方向标志）
JB 00H,BMQCL3 ;动作未结束就转移
RET ;动作结束，退出
BMQCL5:
MOV MJS,#10 ;设置等待时间(秒)
BMQCL6:
LCALL Scan2 ;扫描编码器（无方向标志）
JB 00H,BMQCL7 ;如果还没转到卡点位置就转移
LCALL DSSJZJ ;已经旋转到卡点位置，根据旋转方向增/减定时时间
RET
BMQCL7:
MOV A,MJS ;装入秒计数到寄存器A
CJNE A,#7,BMQCL6 ;检查剩余时间，如果不是7(10秒-3秒=7)就转移，继续扫描
SETB 06H ;达到3秒了，把位地址06H设置为1，数码管显示“--:--”
MOV ZXM1,#0C0H ;-
MOV ZXM2,#0C0H ;-
MOV ZXM3,#0C0H ;-
MOV ZXM4,#0C0H ;-
LCALL DISP ;显示“--:--”
BMQCL8:
LCALL Scan2 ;扫描编码器（无方向标志）
MOV A,MJS ;装入秒计数到寄存器A
JZ BMQCL9 ;如果秒计数为0（达到10秒）就转移
JB 00H,BMQCL8 ;如果还没转到卡点位置就转移，继续扫描
MOV SMJSF,#0FFH ;已经旋转到卡点位置，先放入一个数值，等退出后才恢复睡眠计时
LCALL TZGXSZ ;调用“调整各项设置”子程序
MOV SMJSF,SMMS ;睡眠模式
MOV SMJSM,#0
RET
BMQCL9:
MOV ZXM1,#0FFH ;达到了10秒，显示3秒88:88
MOV ZXM2,#0FFH ;8
MOV ZXM3,#0FFH ;8
MOV ZXM4,#0FFH ;8
LCALL DISP ;显示
MOV MJS,#3 ;显示3秒
BMQCL10:
MOV A,MJS ;装入秒计数到寄存器A
LCALL WG ;喂狗
JNZ BMQCL10 ;等待MJS变为0秒
LCALL SZMRZ ;延时时间到，恢复各项默认设置
LCALL WSET ;保存设置
BMQCL11:
LCALL Scan2 ;扫描编码器（无方向标志）
JB 00H,BMQCL11 ;如果还没转到卡点位置就继续扫描
LCALL REEPR ;把“导通时间”放入“定时时间”，从“导通”开始运行。
CLR 02H ;位地址02H置为0（正常运行）
MOV MJS,#2 ;延时2秒才退出
BMQCL12:
MOV A,MJS ;装入秒计数到寄存器A
LCALL WG ;喂狗
JNZ BMQCL12
RET
;-------------------------------------------------------------------------------------
;子程序：根据编码器旋转方向加减定时时间
;3小时及以下，按设置的值加减：1~30分钟
;3小时以上每次增(减)30分钟；10小时以上每次增(减)1个小时；20小时以上每次增(减)2个小时
;-------------------------------------------------------------------------------------
DSSJZJ:
MOV DSSJM,#0 ;放入0到定时时间(秒)
MOV DSSJHM,#99
CLR 05H
MOV A,DSSJS ;装入定时时间（时）
CJNE A,#20,DSZJ1 ;当前“时”是否等于或大于20
DSZJ1:
JC DSZJ2 ;小于就转移
MOV DSZJ,#2 ;等于或大于20，加减2个小时
LJMP DSZJ4
DSZJ2:
CJNE A,#10,DSZJ3 ;当前“时”是否等于或大于10
DSZJ3:
JC DSZJ8 ;小于就转移
MOV DSZJ,#1 ;等于或大于10，加减1个小时
DSZJ4:
JNB 01H,DSZJ6 ;如果位地址01H为0（逆时针反转）就转移
ADD A,DSZJ ;是正转，加
CJNE A,#100,DSZJ5 ;加完后是否等于或大于100
DSZJ5:
JC DSZJ7 ;如果小于就转移，把A放回到DSSJS
MOV DSSJS,#99 ;已经大于99了，直接设置为99:59:59+DSSJHM(1秒)，100小时
MOV DSSJF,#59 ;已经大于99了，直接设置为99:59:59+DSSJHM(1秒)，100小时
MOV DSSJM,#59 ;已经大于99了，直接设置为99:59:59+DSSJHM(1秒)，100小时
RET
DSZJ6:
SUBB A,DSZJ ;是反转，减
DSZJ7:
MOV DSSJS,A ;把计算结果放入DSSJS
RET
DSZJ8:
MOV DSZJ,BMQZJ ;把设置的“增(减)值”放入DSZJ
CJNE A,#3,DSZJ11 ;当前“时”不是3就转移
JB 01H,DSZJ12 ;是3，如果位地址01H为1(正转)就转移，把DSZJ处的“增(减)值”改为30（分钟）
MOV A,DSSJF ;是反转，装入定时时间（分）
JZ DSZJ13 ;如果当前“分”为0（3:00）就转移，按设置的增(减)值减
CJNE A,#30,DSZJ9 ;“分”不为0，是否等于或大于30
DSZJ9:
JC DSZJ10 ;小于就转移，把0放入定时时间（分），使时间变为3:00
SUBB A,#30 ;等于或大于，减30分
MOV DSSJF,A ;把计算结果放入定时时间（分）
RET
DSZJ10:
MOV DSSJF,#0 ;小于30，把0放入定时时间（分），使时间变为3:00
RET
DSZJ11:
JC DSZJ13 ;小于3就转移
DSZJ12:
MOV DSZJ,#30 ;大于3:00，把DSZJ处的“增(减)值”改为30（分钟）
DSZJ13:
MOV A,DSSJF ;装入定时时间（分）
JNB 01H,DSZJ17 ;如果位地址01H为0（逆时针反转）就转移
ADD A,DSZJ ;是正转，当前“分”直接加DSZJ处的“增(减)值”
CJNE A,#60,DSZJ14 ;加完后“分”是否等于或大于60
DSZJ14:
JC DSZJ15 ;小于60就转移，把A放入定时时间（分）
SUBB A,#60 ;等于或大于60，就减60，然后小时加1
MOV DSSJF,A ;把A放入定时时间（分）
MOV A,DSSJS ;装入“时”
INC A ;小时加1
MOV DSSJS,A
CJNE A,#3,DSZJ16 ;加完后“时”不是3就转移，退出
CLR A ;加完后大于3:00了，把0放入定时时间（分），使时间变为3:00
DSZJ15:
MOV DSSJF,A
DSZJ16: RET
DSZJ17:
CJNE A,DSZJ,DSZJ18 ;是逆时针反转，当前“分”是否等于或大于DSZJ处的“增(减)值”
DSZJ18:
JC DSZJ19 ;小于就转移
SUBB A,DSZJ ;等于或大于，定时时间（分）减“增(减)值”
MOV DSSJF,A ;把计算结果放入定时时间（分）
RET
DSZJ19:
MOV A,DSZJ ;“分”小于“增(减)值”，装入DSZJ处的“增(减)值”
CLR C ;进位标志清0
SUBB A,DSSJF ;“增(减)值”减“定时时间（分）”
MOV DSSJF,A ;减完后的结果暂时放入DSSJF
MOV A,#60
SUBB A,DSSJF ;60减上面的计算结果，得出定时时间（分），然后小时减1
MOV DSSJF,A ;得出的数放入定时时间（分）
MOV A,DSSJS ;装入定时时间（时）
JZ DSSJQL ;如果“时”为0就转移
DEC DSSJS ;“时”不为0，减1
RET
DSSJQL:
MOV DSSJF,#0 ;把“分”置为0
MOV DSSJHM,#0
RET
;-------------------------------------------------------------------------------------
;子程序：按键动作处理
;短按1次暂停计时；短按2次当前项时间(当次)清零；短按3次重新启动，相当于重新上电。
;长按3秒显示“--:--”时释放，进入“设置”；长按10秒，恢复默认设置，显示88:88。
;
;启用“上电延时导通”，“延时导通模式”为2时，上电4.2分钟内按键失效，4.2分钟之后
;按键只有时间清零功能，持续按下按键的时间达到设置的时长（0~99秒）就清零，清零后
;继续执行下一项，执行到“导通”状态运行结束时，按键功能恢复正常。
;-------------------------------------------------------------------------------------
AJDZCL:
JB 08H,JSYSDT2 ;位地址08H为1就转移，不响应按键动作。
MOV A,DQZT ;装入“当前状态”，0=导通、1=断开，2=上电延时导通
CJNE A,#2,KEY0 ;不是“上电延时导通”状态就转移
MOV A,YSMS ;装入“延时导通模式”
CJNE A,#2,KEY0 ;不是2（延时时间到后从“断开”继续运行）就转移
MOV A,YSXY ;装入“延时响应”
JNZ JSYSDT2 ;延时响应时间未到就转移退出
MOV MJS,YSJS ;把设置的“按下持续时间”秒计数放入MJS
JSYSDT1:
MOV A,MJS
JNZ JSYSDT3 ;等待秒计数为0
MOV DSSJS,A ;持续按下的时间到，定时时间（时）清零
MOV DSSJF,A ;持续按下的时间到，定时时间（分）清零
MOV DSSJM,A ;持续按下的时间到，定时时间（秒）清零
MOV DSSJHM,A ;持续按下的时间到，定时时间（毫秒）清零
LCALL KEYEX ;等待按键释放
SETB 08H ;位地址08H置为1，不响应按键动作。
JSYSDT2:
RET
JSYSDT3:
LCALL SKEY0
JC JSYSDT1 ;如果C=1(按键还没释放)，就继续扫描等待
RET
KEY0:
MOV MJS,#10 ;放入等待时间，10秒
KEY1:
MOV A,MJS ;装入等待时间
CJNE A,#7,KEY5 ;按下未达到3秒(10-3=7)就转移
SETB 06H ;到3秒了，把位地址06H设置为1，数码管显示“--:--”
MOV ZXM1,#0C0H ;-
MOV ZXM2,#0C0H ;-
MOV ZXM3,#0C0H ;-
MOV ZXM4,#0C0H ;-
LCALL DISP ;显示“--:--”
KEY2:
MOV A,MJS ;装入等待时间
JZ KEY3 ;如果为0(长按达到了10秒)就转移
LCALL SKEY ;扫描按键
JC KEY2 ;如果C=1(按键还没释放)，就继续扫描
MOV SMJSF,#0FFH ;先放入一个数值，等退出后才恢复睡眠计时
LCALL TZGXSZ ;调用“调整各项设置”子程序
MOV SMJSF,SMMS ;睡眠模式
MOV SMJSM,#0 ;
RET
KEY3:
MOV ZXM1,#0FFH ;达到了10秒，显示3秒88:88
MOV ZXM2,#0FFH ;8
MOV ZXM3,#0FFH ;8
MOV ZXM4,#0FFH ;8
LCALL DISP ;显示
MOV MJS,#3 ;显示3秒
KEY4:
MOV A,MJS ;显示3秒
LCALL WG ;喂狗
JNZ KEY4 ;等待MJS为0秒
LCALL SZMRZ ;延时时间到，恢复各项默认设置
LCALL WSET ;保存设置
LCALL KEYEX ;等待按键释放
LCALL REEPR ;把“导通时间”放入“定时时间”，从“导通”开始运行。
CLR 02H ;位地址02H置为0（正常运行）
RET
KEY5:
LCALL SKEY ;扫描按键
JC KEY1 ;如果C=1(按键还没释放)，就继续扫描
MOV A,DSSJHM ;装入定时时间(毫秒)到寄存器A
JNZ KEY6 ;不是0就转移
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JNZ KEY6 ;不是0就转移
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JNZ KEY6 ;不是0就转移
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ KEY6 ;不是0就转移
CLR 02H ;定时时间为0，位地址02H置为0（正常）
LJMP KEY7
KEY6:
CPL 02H ;位地址02H取反，暂停/正常切换
KEY7:
LCALL KEYA ;第1次按键释放了，再次扫描按键500毫秒
JZ KEY8 ;如果500毫秒内有按键动作就转移
RET
KEY8:
LCALL KEYEX ;有按键动作，等待第2次按键释放
LCALL KEYA ;按键释放了，扫描按键500毫秒
JZ KEY9 ;如果500毫秒内有按键动作就转移
MOV DSSJS,#0 ;没有按键动作，按了2次，把当前时间清零
MOV DSSJF,#0 ;把当前时间清零
MOV DSSJM,#0 ;把当前时间清零
MOV DSSJHM,#0 ;把当前时间清零
CLR 02H ;位地址02H置为0（正常）
RET
KEY9:
LCALL KEYEX ;等待第3次按键释放
CLR EA ;关闭全局中断
INC FWBZ1 ;加1，改变复位判断标志1
LJMP START ;跳转到START，重新初始化
;------------------------------------------------------------------
;子程序：调整各项设置值
;短按2次KEY保存并退出，或在最后一项无操作自动保存退出。
;闪烁5秒无操作或者短按KEY释放0.5秒后，跳到下一项设置。
;按住KEY不放，旋转编码器可向上/下跳到任意一项设置
;如果是用按键代替编码器，支持长按快速加/减
;------------------------------------------------------------------
TZGXSZ:
CLR 06H ;位地址06H置为0，正常显示
MOV DISPL,#1 ;第一项，导通时间(时)，0~99小时
SZTZ:
MOV MJS,#7 ;放入无操作等待时间(秒)到MJS
CLR 03H ;位地址03H置为0，允许检查剩余时间
SZTZ1:
LCALL SKEY0 ;扫描按键
JNC SZTZ7 ;没有按键动作(C=0)就转移
CLR 04H ;已经按下，把位地址04H置为0，不闪烁显示
SZTZ2:
LCALL Scan10 ;扫描编码器（有方向标志）
JB 00H,SZTZ4 ;如果编码器有旋转动作(位地址00H为1)就转移
LCALL SKEY0 ;扫描按键
JC SZTZ2 ;按键未释放(C=1)就转移
LCALL KEYA ;释放了，再次扫描按键500毫秒
JNZ SZTZ3 ;没有第2次按键动作就转移
LCALL WSET ;已经第2次按下，保存设置
LCALL KEYEX ;等待按键释放
RET
SZTZ3:
SETB 01H ;把位地址01H置为1，顺时针正转（切换到下一项）
LCALL QHXM ;根据位地址01H的方向，切换到上/下一项
LJMP SZTZ
SZTZ4:
LCALL QHXM ;根据位地址01H的方向，切换到上/下一项
SZTZ5:
LCALL Scan20 ;扫描编码器（无方向标志）
JB 00H,SZTZ5 ;编码器动作未结束就继续扫描，等待
SZTZ6:
LCALL SKEY0 ;扫描按键
JNC SZTZ ;按键释放(C=0)就转移
LCALL Scan10 ;扫描编码器（有方向标志）
JB 00H,SZTZ4 ;编码器有动作(位地址00H为1)就转移，切换到上/下一项
LJMP SZTZ6
SZTZ7:
LCALL Scan10 ;扫描编码器（有方向标志）
JB 00H,SZTZ9 ;如果编码器有旋转动作(位地址00H为1)就转移
MOV A,MJS ;没有转动，装入秒计数到寄存器A
JZ SZTZ8 ;如果秒计数为0(等待时间到)就转移
JB 03H,SZTZ1 ;不为0，如果位地址03H为1就转移，不检查剩余时间
CJNE A,#5,SZTZ1 ;检查剩余时间，不到就转移，继续扫描编码器
SETB 04H ;把位地址04H置为1，设置为闪烁显示
SETB 03H ;位地址03H置为1，禁止检查剩余时间
LJMP SZTZ1
SZTZ8:
CLR 04H ;等待时间到，把位地址04H置为0，不闪烁显示
MOV A,DISPL ;装入当前目标项
CJNE A,#17,SZTZ3 ;不是最后一项就转移，跳到下一项
LCALL WSET ;保存设置
RET
SZTZ9:
CLR 04H ;编码器已经转动，把位地址04H置为0，不闪烁显示
MOV SHMJS,#50 ;设置有效长按所需时长，50×10毫秒=500毫秒
SZTZ10:
MOV A,SHMJS ;装入(10)毫秒计数
JZ SZTZ11 ;如果时长达到(为0)就转移
LCALL Scan20 ;扫描编码器（无方向标志）
JB 00H,SZTZ10 ;动作未结束就转移，继续扫描
LCALL MBSZ ;动作结束了，调整DISPL指向的对象，加/减1
LJMP SZTZ
SZTZ11:
LCALL MBSZ ;加/减1。已经为有效长按，下面进入长按快速加/减
MOV SHMJS,#13 ;间隔加/减时间，(×10)毫秒
SZTZ12:
MOV A,SHMJS ;装入(10)毫秒计数
JNZ SZTZ13 ;时间未到(不为0)就转移
LJMP SZTZ11 ;已达到设定的间隔时长，转移，加/减1
SZTZ13:
LCALL DELAY10 ;延时10毫秒
LCALL Scan20 ;扫描编码器（无方向标志）
JB 00H,SZTZ12 ;动作未结束就转移
LCALL DELAY10 ;延时10毫秒
LCALL Scan20 ;第2次扫描编码器（无方向标志）
JB 00H,SZTZ12 ;动作未结束就转移
LCALL DELAY10 ;延时10毫秒
LCALL Scan20 ;第3次扫描编码器（无方向标志）
JB 00H,SZTZ12 ;动作未结束就转移
LJMP SZTZ ;动作结束
MBSZ:
MOV A,DISPL ;装入要调整的目标项
LCALL SXXFW ;设置上下限限值
DEC A ;减1
ADD A,#DTS ;加上各项设置的起始地址
MOV R0,A ;把得出的目标项地址放入R0
JB 01H,MBSZ2 ;如果位地址01H为1（顺时针正转）就转移
INC XXSZ ;是反转，下限值先加1
MOV A,@R0 ;装入R0指向的目标数值
CJNE A,XXSZ,MBSZ0 ;与加1后的下限值比较
MBSZ0:
JC MBSZ1 ;如果小于“下限值+1”（不够减）就转移
DEC @R0 ;等于或大于下限值，目标数值减1
DEC XXSZ ;减1，恢复下限值
RET
MBSZ1:
DEC XXSZ ;减1，恢复下限值
MOV @R0,XXSZ ;不够减了，直接放入下限值
RET
MBSZ2:
MOV A,@R0 ;是正转，装入R0指向的RAM地址的目标数值
INC A ;加1
CJNE A,SXSZ,MBSZ3 ;加完后与上限数值比较
MBSZ3:
JC MBSZ4 ;如果小于就转移
MOV @R0,SXSZ ;等于或大于上限值，直接放入上限值
RET
MBSZ4:
MOV @R0,A ;小于上限值，把计算结果放回去
RET
;-------------------------------------------------------------------------
;子程序：切换项目。根据位地址01H的方向标志，把当前设置项切换到上/下一项
;-------------------------------------------------------------------------
QHXM:
MOV A,DISPL ;装入当前项目号
JB 01H,QHXM2 ;如果位地址01H为1(正转)就转移，切换到下一项
CJNE A,#1,QHXM1 ;是反转，如果不是1就转移
MOV DISPL,#17 ;切换到上一项17
RET
QHXM1:
DEC DISPL ;减1，切换到上一项
RET
QHXM2:
CJNE A,#17,QHXM3 ;是正转，如果不是17就转移
MOV DISPL,#1 ;切换到下一项1
RET
QHXM3:
INC DISPL ;加1，切换到下一项
RET
;-------------------------------------------------------------------------
;子程序：根据当前项目号设置加/减调整的上下限值。入口参数：A=项目号。
;-------------------------------------------------------------------------
SXXFW:
CJNE A,#1,SXXFW1 ;1=显示“1A”设置导通时间(时)，0~99小时
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW1:
CJNE A,#2,SXXFW2 ;2=显示“1b”设置导通时间(分)，0~59分钟
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW2:
CJNE A,#3,SXXFW3 ;3=显示“1C”设置导通时间(秒)，0~59秒
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW3:
CJNE A,#4,SXXFW4 ;4=显示“1d”设置导通时间(×10毫秒)，0~99
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW4:
CJNE A,#5,SXXFW5 ;5=显示“o-”设置循环定时，0~99
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW5:
CJNE A,#6,SXXFW6 ;6=显示“C-”设置睡眠模式，0~59
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW6:
CJNE A,#7,SXXFW7 ;7=显示“bC”设置实时调整时的增/减值(步长)：1~30分钟
MOV XXSZ,#1 ;下限为1
MOV SXSZ,#30 ;上限为30
RET
SXXFW7:
CJNE A,#8,SXXFW8 ;8=显示“Ld”设置数码管亮度，1~8级。
MOV XXSZ,#1 ;下限为1
MOV SXSZ,#8 ;上限为8
RET
SXXFW8:
CJNE A,#9,SXXFW9 ;9=显示“2A”设置断开时间(时)，0~99小时
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW9:
CJNE A,#10,SXXFW10 ;10=显示“2b”设置断开时间(分)，0~59分钟
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW10:
CJNE A,#11,SXXFW11 ;11=显示“2C”设置断开时间(秒)，0~59秒
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW11:
CJNE A,#12,SXXFW12 ;12=显示“2d”设置断开时间(×10毫秒)，0~99
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW12:
CJNE A,#13,SXXFW13 ;13=显示“3A”设置上电延时导通(时)，0~99小时
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
SXXFW13:
CJNE A,#14,SXXFW14 ;14=显示“3b”设置上电延时导通(分)，0~59分钟
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW14:
CJNE A,#15,SXXFW15 ;15=显示“3C”设置上电延时导通(秒)，0~59秒
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#59 ;上限为59
RET
SXXFW15:
CJNE A,#16,SXXFW16 ;16=显示“d-”设置延时导通模式，0~2。默认为0
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#2 ;上限为2
RET
SXXFW16: ;17=显示“E-”设置“持续按下时间”秒计数0~99
MOV XXSZ,#0 ;下限为0
MOV SXSZ,#99 ;上限为99
RET
;----------------------------------------------------------------------------------------
;子程序：扫描编码器是否有旋转动作并设置好方向标志
;出口参数：位地址第00位=1已经转动，=0没有转动；位地址第01位=1顺时针正转，=0逆时针反转
;----------------------------------------------------------------------------------------
Scan1:
LCALL Scan10 ;扫描编码器
JNB 00H,Scan1E ;如果没有旋转动作就转移退出
LCALL SMCL ;有旋转动作，调用睡眠处理子程序
JZ Scan1E ;如果是0(从睡眠状态唤醒)就转移，下次才退出“始终导通”状态
LCALL TCSZDT ;退出上电延时导通的“始终导通”状态
Scan1E: RET
Scan10:
LCALL WG ;喂狗
SETB EC11A ;拉高编码器A引脚电平
SETB EC11B ;拉高编码器B引脚电平
JNB EC11A,Scan11 ;如果为0(低电平)就转移，编码器有旋转动作，顺时针正转
JNB EC11B,Scan12 ;如果为0(低电平)就转移，编码器有旋转动作，逆时针反转
CLR 00H ;没有旋转动作，把位地址00H置为0
RET
Scan11:
SETB 01H ;顺时针正转，把位地址01H置为1
SETB 00H ;有旋转动作，把位地址00H置为1
RET
Scan12:
CLR 01H ;逆时针反转，把位地址01H置为0
SETB 00H ;有旋转动作，把位地址00H置为1
Scan13: RET
;-----------------------------------------------------------
;子程序：扫描编码器是否有旋转动作，不设置方向标志
;出口参数：位地址第0位=1已经转动，=0没有转动
;-----------------------------------------------------------
Scan2:
LCALL Scan20 ;扫描编码器
JNB 00H,Scan2E ;如果没有旋转动作就转移退出
LCALL SMCL ;有旋转动作，调用睡眠处理子程序
JZ Scan2E ;如果是0(从睡眠状态唤醒)就转移，下次才退出“始终导通”状态
LCALL TCSZDT ;退出上电延时导通的“始终导通”状态
Scan2E: RET
Scan20:
LCALL WG ;喂狗
SETB EC11A ;拉高编码器A引脚电平
SETB EC11B ;拉高编码器B引脚电平
JNB EC11A,Scan21 ;如果为0(低电平)就转移，编码器有旋转动作
JNB EC11B,Scan21 ;如果为0(低电平)就转移，编码器有旋转动作
CLR 00H ;没有旋转动作，把位地址00H置为0
RET
Scan21:
SETB 00H ;有旋转动作，把位地址00H置为1
Scan22: RET
;-----------------------------------------------------------
;子程序：扫描按键，未按C=0，已按下C=1
;-----------------------------------------------------------
SKEY:
LCALL SKEY0 ;扫描按键
JNC SKEYE ;如果没有按键动作(C为0)就转移退出
LCALL SMCL ;有按键动作，调用睡眠处理子程序
JZ SKEYE ;如果是0(从睡眠状态唤醒)就转移，下次才退出“始终导通”状态
LCALL TCSZDT ;退出上电延时导通的“始终导通”状态
SKEYE: RET
SKEY0:
LCALL WG ;喂狗
SETB KEY ;按键端口置为高电平
JNB KEY,SKEY1 ;为0(低电平)就转移，表示按键已经被按下
CLR C ;C置为0，没有按键动作
RET
SKEY1:
LCALL DELAY10 ;延时10毫秒
LCALL DELAY10 ;延时10毫秒
SETB KEY ;延时结束后再次把按键端口置为高电平
JNB KEY,SKEY2 ;为0(低电平，按键被有效按下)就转移
CLR C ;C置为0，没有按键动作
RET ;按键未被有效按下，退出
SKEY2:
SETB C ;C置为1，按键已有效按下
RET
;------------------ 扫描按键500毫秒，有按键动作A=0，无按键动作A=1 ------------------
KEYA:
MOV SHMJS,#50 ;等待500毫秒
KEYB:
MOV A,SHMJS ;装入(10)毫秒计数
JZ KEYC ;为0（时间到）就转移
LCALL SKEY0 ;扫描按键
JNC KEYB ;没有按键动作(C=0)就转移
CLR A ;有按键动作A=0
RET
KEYC:
MOV A,#1 ;等待时间已到，A=1没有按键动作
RET
;------------------ 等待按键释放 ------------------
KEYEX:
LCALL SKEY0 ;扫描按键
JC KEYEX ;如果C=1(按键还没释放)就继续扫描
RET
;------------------ 延时10毫秒 ------------------
DELAY10: ;@11.0592MHz
NOP
NOP
NOP
PUSH 16H
PUSH 17H
MOV 16H,#87
MOV 17H,#10
NEXT:
DJNZ 17H,NEXT
DJNZ 16H,NEXT
POP 17H
POP 16H
RET
;-----------------------------------------------------------------------------------
;子程序：睡眠模式处理，如果当前处于睡眠状态就重新放入睡眠倒计时，恢复显示，等待
;编码器或按键动作结束并延时2秒才退出；如果不是睡眠状态，重新放入睡眠计时，返回
;出口参数：A=0从睡眠状态唤醒
;-----------------------------------------------------------------------------------
SMCL:
MOV A,SMMS ;装入睡眠模式设置值
JNZ SMCL1 ;不为0就转移
INC A ;为0，加1，使返回时A不为0
RET ;当前睡眠模式为“始终显示”，返回
SMCL1:
MOV A,SMJSF ;装入睡眠计时(分)
JNZ SMCL2 ;不为0就转移
MOV A,SMJSM ;装入睡眠计时(秒)
JZ SMCL3 ;是0就转移
SMCL2:
MOV SMJSF,SMMS ;不为0，还没进入睡眠状态，重新放入倒计时
MOV SMJSM,#0 ;不为0，还没进入睡眠状态，重新放入倒计时
RET
SMCL3:
MOV SMJSF,SMMS ;已进入睡眠状态，重新放入倒计时，唤醒睡眠，恢复显示
MOV SMJSM,#0 ;已进入睡眠状态，重新放入倒计时，唤醒睡眠，恢复显示
INC XSHC1 ;改变XSHC1数据，触发“立即显示”
SMCL4:
MOV SMJS,#2 ;放入秒计时
SMCL5:
LCALL WG ;喂狗
SETB KEY ;按键端口置为高电平
SETB EC11A ;编码器A引脚置为高电平
SETB EC11B ;编码器B引脚置为高电平
JNB KEY,SMCL4 ;为0(低电平)未释放就转移
JNB EC11A,SMCL4 ;为0(低电平)未释放就转移
JNB EC11B,SMCL4 ;为0(低电平)未释放就转移
MOV A,SMJS ;装入计时
JNZ SMCL5 ;不为0就转移继续扫描按键和编码器
CLR C ;C置为0，没有按键动作
CLR 00H ;把位地址00H置为0，没有旋转动作
RET
;-------------------------------------------------------------------------------------
;子程序：退出始终导通状态处理。当进入“延时时间到后始终导通”状态时，按键、编码器有
;动作就退出始终导通状态，切换到“导通时间”的结束(断开)状态，如设置为循环定时，就转
;换到“断开时间”继续运行。
;-------------------------------------------------------------------------------------
TCSZDT:
JB 07H,TC1 ;如果为1(已进入“上电延时导通”的始终导通状态)就转移
RET
TC1:
MOV A,XHDS ;装入“循环定时”设置
CJNE A,#1,TC2 ;不是1(不循环)就转移
MOV DQZT,#0 ;把当前状态切换到“导通”
CLR 07H ;位地址07H置为0(正常)
LCALL SMCL4 ;等待编码器或按键动作结束后延时2秒才退出
RET
TC2:
MOV DQZT,#1 ;把当前状态设为1，从“断开时间”继续运行
MOV DSSJS,DKS ;装入“断开时间”
MOV DSSJF,DKF ;装入“断开时间”
MOV DSSJM,DKM ;装入“断开时间”
MOV DSSJHM,DKHM ;装入“断开时间”
CLR 07H ;位地址07H置为0(正常)
LCALL SMCL4 ;等待编码器或按键动作结束后延时2秒才退出
RET
;------------------------------------------------------------------------
;子程序：T0中断调用，时间计数及倒计时处理、状态切换
;------------------------------------------------------------------------
TIME:
LCALL TIME6 ;部分时间计数及倒计时处理
JB 02H,TIME1 ;如果位地址02H为1(暂停)就转移退出，停止计时
MOV A,DSSJHM ;装入定时时间(10)毫秒计数
JZ TIME2 ;如果是0就转移
DEC A ;DSSJHM不是0，减1
MOV DSSJHM,A ;DSSJHM不是0，减1
JNZ TIME1 ;减1后不为0就转移退出
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JNZ TIME1 ;如果(秒)不是0就转移退出
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JNZ TIME1 ;如果(分)不是0就转移退出
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ TIME1 ;如果(时)不是0就转移退出
LCALL ZTQH ;时、分、秒都是0了，状态切换
TIME1: RET
TIME2:
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JZ TIME3 ;如果是0就转移
DEC DSSJM ;不是0，减1秒
MOV DSSJHM,#99 ;重新放入(10)毫秒计数值
MOV HMJS,#99 ;重新放入(10)毫秒计数值，使DSSJHM与HMJS同步
RET
TIME3:
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JZ TIME4 ;如果是0就转移
DEC DSSJF ;不是0，减1分
MOV DSSJM,#59 ;把59放入定时时间(秒)
MOV DSSJHM,#99 ;重新放入(10)毫秒计数值
MOV HMJS,#99 ;重新放入(10)毫秒计数值
RET
TIME4:
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ TIME5 ;不是0就转移
LCALL ZTQH ;状态切换
RET
TIME5:
DEC DSSJS ;不是0，小时减1
MOV DSSJM,#59 ;把59放入定时时间(秒)
MOV DSSJF,#59 ;把59放入定时时间(分)
MOV DSSJHM,#99 ;重新放入(10)毫秒计数值
MOV HMJS,#99 ;重新放入(10)毫秒计数值
RET
TIME6:
MOV A,SHMJS ;装入(10)毫秒计数
JZ TIME7 ;如果是0就转移
DEC SHMJS ;每10毫秒减1，直到为0
TIME7:
MOV A,HMJS ;装入(10)毫秒计数2
JZ TIME9 ;如果是0就转移
DEC HMJS ;不是0，减1
CJNE A,#50,TIME8 ;如果不是50就转移退出
SETB 05H ;位地址第05位置为1，数字及冒号闪烁时用，每0.5秒变化一次
TIME8: RET
TIME9:
CLR 05H ;位地址第05位置为0，数字及冒号闪烁时用，每0.5秒变化一次
MOV HMJS,#99 ;重新放入计数值(1秒)
MOV A,MJS ;装入秒计数
JZ TIME10 ;如果是0就转移
DEC MJS ;每秒减1，直到为0
TIME10:
MOV A,YSXY ;装入“延时响应”秒计数
JZ TIME11 ;如果是0就转移
DEC YSXY ;每秒减1，直到为0
TIME11:
JNB 09H,TIME12 ;位地址09H不为1(允许恢复响应按键动作)就转移
JNB 08H,TIME12 ;位地址08H不为1(禁止响应按键动作)就转移
SETB KEY ;按键端口置为高电平
JNB KEY,TIME12 ;为0(低电平，按键为按下状态)就转移
CLR 08H ;位地址08H置为0（恢复响应按键动作）
CLR 09H ;位地址09H置为0（正常）
TIME12:
MOV A,SMJS ;装入睡眠模式处理计时
JZ TIME13 ;如果是0就转移
DEC SMJS ;不是0，减1秒
TIME13:
MOV A,SMJSM ;装入睡眠倒计时(秒)
JZ TIME14 ;如果是0就转移
DEC SMJSM ;(秒)减1
RET
TIME14:
MOV A,SMJSF ;装入睡眠倒计时(分)
JNZ TIME15 ;如果不是0就转移
RET
TIME15:
DEC SMJSF ;(分)减1
MOV SMJSM,#59 ;放入59(秒)
RET
ZTQH:
MOV A,DQZT ;装入“当前状态”，0=导通、1=断开，2=上电延时导通
CJNE A,#2,ZTQH2 ;不是“上电延时导通”状态就转移
MOV A,YSMS ;装入延时导通模式
JNZ ZTQH0 ;如果不是0(延时时间到后始终导通)就转移
SETB 07H ;位地址07H置为1，始终导通
RET
ZTQH0:
CJNE A,#1,ZTQH6 ;不是1(从“导通时间”继续运行)就转移,从“断开时间”继续运行
ZTQH1:
MOV DQZT,#0 ;切换到“导通时间”状态
MOV DSSJS,DTS ;把“导通时间”放入“定时时间”
MOV DSSJF,DTF ;把“导通时间”放入“定时时间”
MOV DSSJM,DTM ;把“导通时间”放入“定时时间”
MOV DSSJHM,DTHM ;把“导通时间”放入“定时时间”
RET
ZTQH2:
CLR 07H ;位地址07H置为0(正常)
JNZ ZTQH1 ;是1(断开时间)状态就转移，切换到“导通时间”状态
MOV A,XHDS ;是“导通时间”状态，装入循环模式
SETB 09H ;位地址09H置为1(允许恢复响应按键动作)
CJNE A,#1,ZTQH3 ;不是1(不循环)就转移，0=无限循环；1=不循环；2~99=导通次数
RET ;是不循环，退出
ZTQH3:
JZ ZTQH5 ;是0(无限循环)就转移
MOV A,XHJS ;装入导通次数计数
DEC A ;检查导通次数是否已到，不到就转移
JNZ ZTQH4 ;检查导通次数是否已到，不到就转移
RET
ZTQH4:
DEC XHJS ;导通次数减1
ZTQH5:
MOV A,DKS ;
JNZ ZTQH7 ;检查“断开时间”不为0才切换到“断开时间”
MOV A,DKF ;
JNZ ZTQH7 ;检查“断开时间”不为0才切换到“断开时间”
MOV A,DKM ;
JNZ ZTQH7 ;检查“断开时间”不为0才切换到“断开时间”
MOV A,DKHM ;
JNZ ZTQH7 ;检查“断开时间”不为0才切换到“断开时间”
RET
ZTQH6:
SETB 08H ;位地址08H置为1，不响应按键动作。
ZTQH7:
MOV DQZT,#1 ;切换到“断开时间”状态
MOV DSSJS,DKS ;把“断开时间”放入“定时时间”
MOV DSSJF,DKF ;把“断开时间”放入“定时时间”
MOV DSSJM,DKM ;把“断开时间”放入“定时时间”
MOV DSSJHM,DKHM ;把“断开时间”放入“定时时间”
RET
;-----------------------------------------------------------------------
;子程序：T0中断调用，显示定时时间及各项设置的内容
;-----------------------------------------------------------------------
DISPLAY:
JB 06H,DPYSZ1 ;如果位地址06H为1就转移退出，主程序显示88:88或E1
MOV A,DISPL ;装入要显示的目标(项目号)
JZ DISPL0 ;如果是0(显示定时时间)就转移
MOV B,#2
MUL AB ;项目号乘2
DEC A
DEC A ;把计算结果减2
PUSH ACC ;寄存器A的内容压入堆栈
MOV DPTR,#SEGTAB2 ;字形码首址
MOVC A,@A+DPTR ;查表获取字形码
MOV ZXM1,A ;项目字形码放到待发送TM1637区1
POP ACC ;弹出上面压入堆栈的内容到寄存器A
INC A ;地址加1
MOVC A,@A+DPTR ;查表获取字形码
MOV ZXM2,A ;项目字形码放到待发送TM1637区2
MOV A,DISPL ;装入项目号
DEC A ;减1
ADD A,#DTS ;加各项设置值始址，得出设置项目的实际地址
MOV R1,A ;地址放入R1
MOV A,@R1 ;装入设置值
MOV B,A ;放进寄存器B
CJNE A,XSHC1,DPYSZ3 ;当前设置值与显示缓存1不相同就转移，立即显示
MOV A,HMJS ;相同，装入(10)毫秒计数2
CJNE A,#99,DPYSZ2 ;不是99就转移，每0.5秒显示一次
LJMP DPYSZ3 ;是，显示
DPYSZ1: RET
DPYSZ2:
CJNE A,#49,DPYSZ1 ;不是49就转移退出，每0.5秒显示一次
DPYSZ3:
MOV XSHC1,B ;当前设置值放入显示缓存1
MOV A,B ;当前设置值放入A寄存器
MOV R0,#ZXM3 ;待发送TM1637区3地址
LCALL BCD ;转换并获取字形码放到待发送TM1637区3和4
JNB 04H,DPYSZ4 ;如果位地址04H为0(不闪烁)就转移
JNB 05H,DPYSZ4 ;为1，闪烁显示，如果位地址05H为0(显示)就转移
MOV ZXM3,#0 ;处于闪烁显示中的“不显示”状态，放入消隐码
MOV ZXM4,#0 ;处于闪烁显示中的“不显示”状态，放入消隐码
DPYSZ4:
LCALL disp ;发送4个字节数据到TM1637显示
RET
DISPL0:
MOV R1,#DSSJS ;把定时时间“时”的地址放入R1
MOV A,@R1 ;装入“时”
JZ DISPL1 ;如果“时”为0就转移
LJMP DISPL3
DISPL1:
CLR 05H ;“时”为0，把位地址05H置为0，始终显示冒号
INC R1 ;地址加1，指向“分”
MOV A,@R1 ;装入“分”
JZ DISPL2 ;如果“分”为0就转移
LJMP DISPL3
DISPL2:
INC R1 ;地址加1，指向“秒”
MOV A,@R1 ;装入“秒”
DISPL3:
CJNE A,XSHC1,DISPL6 ;寄存器A的数据与显示缓存1不相同就转移，立即显示
INC R1 ;地址加1
MOV A,@R1 ;装入
DEC R1 ;地址减1
CJNE A,XSHC2,DISPL6 ;寄存器A的数据与显示缓存2不相同就转移，立即显示
MOV A,HMJS ;都相同，装入(10)毫秒时间计数2
CJNE A,#99,DISPL5 ;不是99就转移
LJMP DISPL6 ;是，显示（每0.5秒显示一次）
DISPL4: RET
DISPL5:
CJNE A,#49,DISPL4 ;不是49就转移退出，每0.5秒显示一次
DISPL6:
INC R1 ;地址加1
MOV A,@R1 ;装入后面一位时间
MOV XSHC2,A ;放入缓存2
DEC R1 ;地址减1
MOV A,@R1 ;装入前面一位时间
MOV XSHC1,A ;放入缓存1
MOV R0,#ZXM1 ;待发送TM1637区1地址
LCALL BCD ;转换并获取字形码放到待发送TM1637区1、2
INC R1 ;地址加1
MOV R0,#ZXM3 ;待发送TM1637区3地址
MOV A,@R1 ;装入后面一位时间
LCALL BCD ;转换并获取字形码放到待发送TM1637区3、4
JB 02H,DISPL7 ;如果02H为1(暂停)就转移，始终显示冒号
JB 05H,DISPL8 ;如果05H为1就转移，不显示冒号
DISPL7:
ORL ZXM2,#10000000B ;把最高位置为1（最高位为1就显示冒号）
DISPL8:
LCALL disp ;发送4个字节数据到TM1637显示
RET
BCD:
MOV B,#10 ;转换为BCD码
DIV AB ;转换为BCD码
MOV DPTR,#SEGTAB ;查表获取字形码
MOVC A,@A+DPTR ;查表获取字形码
MOV @R0,A ;字形码放入待发送TM1637区
XCH A,B ;A、B寄存器内容交换
MOVC A,@A+DPTR ;查表获取字形码
INC R0 ;地址加1
MOV @R0,A ;字形码放入待发送TM1637区
RET
;------------------ 发送4个字节数据到TM1637显示，地址自动加1 ------------------
disp:
MOV A,SMMS ;装入设置的睡眠模式
JZ disp0 ;如果为0（始终显示）就转移
MOV A,SMJSF ;装入睡眠计时(分)
JNZ disp0 ;不为0(未进入睡眠状态)就转移
MOV A,SMJSM ;装入睡眠计时(秒)
JNZ disp0 ;不为0(未进入睡眠状态)就转移
CLR A ;已进入睡眠状态，放入消隐码（0）
MOV ZXM1,A ;放入消隐码
MOV ZXM2,A ;放入消隐码
MOV ZXM3,A ;放入消隐码
MOV ZXM4,A ;放入消隐码
disp0:
LCALL Srt
MOV A,#040H ;数据命令设置40H：地址自动加1，写数据到显示寄存器
LCALL Writebyte ;发送一个字节
LCALL Stop
NOP
LCALL Srt
MOV A,#0C0H ;地址命令设置C0H：初始地址为00H
LCALL Writebyte ;发送一个字节
MOV R6,#4 ;发送4个字节数据
MOV R1,#ZXM1 ;等待发送的字形码始址
disp1:
MOV A,@R1 ;装入要发送的字形码
LCALL Writebyte ;发送一个字节
INC R1 ;地址加1
DJNZ R6,disp1 ;如果还未发送完就继续
LCALL Stop
LCALL Srt
MOV A,SMGLD ;装入设置的数码管亮度(1~8)
ADD A,#087H ;加上87H后即为对应的亮度控制命令88H~8FH
LCALL Writebyte ;按设置的亮度开显示
LCALL Stop
RET
;------------------ 发送8bit(一个字节)数据到TM1637，A=要发送的数据，从低位开始 ------------------
Writebyte:
MOV R7,#8 ;发送8位数据
WBY1:
CLR CLK ;拉低CLK
JNB ACC.0,WBY2 ;A寄存器的低位（0位）如果为0就转移
SETB DIO ;为1，拉高DIO
SJMP WBY3
WBY2:
CLR DIO ;为0，拉低DIO
WBY3:
MOV R4,#13 ;延时
WBY4:
DJNZ R4,WBY4 ;延时
SETB CLK ;拉高CLK
CLR C ;进位标志清0
RRC A ;A寄存器内容带进位循环右移
DJNZ R7,WBY1 ;如果还未发送完8bit数据就继续
CLR CLK ;8位数据发送完了
MOV R7,#20 ;设置等待应答信号延时计数
WBY5:
JNB DIO,WBY6 ;判断TM1637发过来的ACK应答信号，应答就转移(0，低电平)
DJNZ R7,WBY5 ;
WBY6:
MOV R4,#13 ;延时
WBY7:
DJNZ R4,WBY7 ;延时
SETB CLK
MOV R4,#13 ;延时
WBY8:
DJNZ R4,WBY8 ;延时
RET
;------------------ Start子程序 ------------------
Srt:
SETB DIO ;拉高DIO
SETB CLK ;拉高CLK
MOV R4,#13 ;延时
SrtY1:
DJNZ R4,SrtY1 ;延时
SETB DIO ;拉高DIO
MOV R4,#13 ;延时
SrtY2:
DJNZ R4,SrtY2 ;延时
CLR DIO ;拉低DIO
MOV R4,#13 ;延时
SrtY3:
DJNZ R4,SrtY3 ;延时
CLR CLK ;拉低CLK
RET
;------------------ Stop子程序 ------------------
Stop:
CLR CLK
MOV R4,#30
StopY1:
DJNZ R4,StopY1
CLR DIO
MOV R4,#30
StopY2:
DJNZ R4,StopY2
SETB CLK
MOV R4,#40
StopY3:
DJNZ R4,StopY3
SETB DIO
MOV R4,#30
StopY4:
DJNZ R4,StopY4
CLR CLK
CLR DIO
RET
;********************** 以下为EEPROM操作子程序 **********************
;STC15F104W有1K字节的EEPROM，共2个扇区，第1扇区：0000H~01FFH；第2扇区：0200H~03FFH
;-------------------------------------------
;读一字节，A=读出的数据
Byte_Read:
MOV IAP_CONTR,#ENABLE_IAP ;打开IAP功能，设置Flash操作等待时间（83H）
MOV IAP_CMD,#01 ;设置为IAP/ISP/EEPROM字节读模式命令(1)
MOV IAP_TRIG,#05AH ;先送5AH
MOV IAP_TRIG,#0A5H ;再送A5H，ISP/IAP命令立即被触发起动
NOP
MOV A,IAP_DATA ;读出的数据在IAP_DATA单元中,送入累加器A
RET
;-------------------------------------------
;字节编程，A=需写入的数据
Byte_Program:
MOV IAP_CONTR,#ENABLE_IAP ;打开IAP功能，设置Flash操作等待时间（83H）
MOV IAP_CMD,#02 ;设置为IAP/ISP/EEPROM字节编程模式命令(2)
MOV IAP_DATA,A ;要编程的数据先送进IAP_DATA寄存器
MOV IAP_TRIG,#05AH ;先送5AH
MOV IAP_TRIG,#0A5H ;再送A5H，ISP/IAP命令立即被触发起动
RET
;-------------------------------------------
;擦除扇区
Sector_Erase:
MOV IAP_CONTR,#ENABLE_IAP ;打开IAP功能，设置Flash操作等待时间（83H）
MOV IAP_CMD,#03 ;设置为IAP/ISP/EEPROM扇区擦除模式命令(3)
MOV IAP_TRIG,#05AH ;先送5AH
MOV IAP_TRIG,#0A5H ;再送A5H，ISP/IAP命令立即被触发起动
NOP
RET
;---------- 读EEPROM保存的各项设置，如果没有就设置为默认值并保存 ------------
REEP:
LCALL RE00 ;读EEPROM保存的各项设置
MOV XHJS,XHDS ;循环定时
MOV SMJSF,SMMS ;睡眠模式
MOV A,SDYSS ;装入上电延时导通(时)
JNZ REYS ;不是0就转移
MOV A,SDYSF ;装入上电延时导通(分)
JNZ REYS ;不是0就转移
MOV A,SDYSM ;装入上电延时导通(秒)
JZ REEPR ;都为0就转移
REYS:
MOV DSSJS,SDYSS ;把“上电延时导通”时间放入“定时时间”
MOV DSSJF,SDYSF ;把“上电延时导通”时间放入“定时时间”
MOV DSSJM,SDYSM ;把“上电延时导通”时间放入“定时时间”
MOV DSSJHM,#0
MOV DQZT,#2 ;设置当前状态，0=导通、1=断开，2=上电延时导通
RET
REEPR:
MOV DSSJS,DTS ;把“导通时间”放入“定时时间”
MOV DSSJF,DTF ;把“导通时间”放入“定时时间”
MOV DSSJM,DTM ;把“导通时间”放入“定时时间”
MOV DSSJHM,DTHM ;把“导通时间”放入“定时时间”
MOV DQZT,#0 ;设置当前状态，0=导通、1=断开，2=上电延时导通
RET
RE00:
MOV IAP_ADDRH,#00H ;从第一个扇区开始搜索，地址的高8位
RE01:
MOV IAP_ADDRL,#00H ;从第一个扇区开始搜索，地址的低8位
LCALL Byte_Read ;读第一个字节，返回：A=读出的数据
CJNE A,FWBZ1,RE03 ;是否保存在当前扇区，不是就转移到RE03
INC IAP_ADDRL ;EEPROM字节地址增1
LCALL Byte_Read ;读第二个字节
CJNE A,FWBZ2,RE03 ;第二个字节是否相符
MOV R1,#FWBZ2 ;相符，从FWBZ2+1处开始放置读出的设置值
MOV R2,#17 ;再读出17个字节
RE02:
INC R1 ;RAM地址增1
INC IAP_ADDRL ;EEPROM字节地址增1
LCALL Byte_Read ;读一个字节，返回：A=读出的数据
MOV @R1,A ;放到R1指向的RAM地址
DJNZ R2,RE02 ;未读完就继续
RET ;读完了，退出
RE03:
MOV A,IAP_ADDRH ;装入扇区地址的高8位
ADD A,#2 ;扇区增1
MOV IAP_ADDRH,A ;放入IAP_ADDRH
CJNE A,#04H,RE01 ;如果未搜索完最后一个扇区+2(02H+2=04H)就转移，继续搜索
LCALL SZMRZ ;已经搜索全部扇区，未找到保存的内容，设置为默认值
MOV R0,#2 ;总扇区数量，共2个扇区
LJMP WSET3 ;跳转到WSET3保存设置
;------------------ 保存设置，不固定保存到某个扇区，各扇区轮流使用 ------------------
WSET:
MOV R0,#2 ;扇区总数量，共2个扇区
MOV IAP_ADDRH,#00H ;从第一个扇区开始搜索上次保存的设置
WSET1:
MOV IAP_ADDRL,#00H ;地址低位指向第一个字节
LCALL Byte_Read ;读第一个字节，返回：A=读出的数据
CJNE A,FWBZ1,WSET7 ;如果与EEPROM数据判断标志1不相同就转移
INC IAP_ADDRL ;第一个字节相同，EEPROM字节地址增1
LCALL Byte_Read ;读第二个字节
CJNE A,FWBZ2,WSET7 ;如果与EEPROM数据判断标志2不相同就转移
MOV IAP_ADDRL,#0 ;是在当前扇区，地址指向扇区第一个字节
LCALL Sector_Erase ;擦除当前扇区，另换一个扇区保存
WSET2:
MOV A,IAP_ADDRH ;装入扇区地址高位到寄存器A
CJNE A,#00H,WSET3 ;当前扇区地址高位如果不是00H(第一个扇区)就转移
MOV IAP_ADDRH,#04H ;是00H，把IAP_ADDRH设置为最后一个扇区+2(02H+2=04H)
WSET3:
DEC IAP_ADDRH ;减1
DEC IAP_ADDRH ;再减1，指向上一个扇区首址
MOV IAP_ADDRL,#0 ;低8位指向扇区第一个字节
LCALL Sector_Erase ;擦除整个扇区
MOV R1,#FWBZ1 ;要保存的内容始址
MOV R2,#19 ;共19个字节
WSET4:
MOV A,@R1 ;装入R1指向的RAM地址的内容到A
LCALL Byte_Program ;字节编程(写入EEPROM)
INC IAP_ADDRL ;EEPROM地址加1
INC R1 ;RAM地址增1
DJNZ R2,WSET4 ;未保存完就继续
MOV IAP_ADDRL,#0 ;保存完了，扇区地址低位指向0(当前扇区首址)
LCALL Byte_Read ;读出来检查看是否写入成功
CJNE A,FWBZ1,WSET5 ;如果与EEPROM数据判断标志1不相同就转移
INC IAP_ADDRL ;EEPROM地址加1
LCALL Byte_Read ;读第二个字节
CJNE A,FWBZ2,WSET5 ;如果与EEPROM数据判断标志2不相同就转移
RET ;成功了，退出
WSET5:
DJNZ R0,WSET2 ;如果未试完全部扇区就转移到WSET2继续往前一个扇区写
SETB 06H ;已经试完全部扇区，都失败了，位地址06H置为1
MOV MJS,#5 ;显示5秒E1
MOV ZXM1,#0 ;消隐码
MOV ZXM2,#079H ;E
MOV ZXM3,#006H ;1
MOV ZXM4,#0 ;消隐码
LCALL DISP ;显示
WSET6:
MOV A,MJS
LCALL WG ;喂狗
JNZ WSET6 ;等待MJS为0秒
CLR 06H ;显示结束，位地址06H置为0
RET
WSET7:
MOV A,IAP_ADDRH ;装入扇区地址高位
ADD A,#2 ;加2，指向下一个扇区首址
MOV IAP_ADDRH,A ;放回IAP_ADDRH
CJNE A,#04H,WSET1 ;如果未到最后一个扇区地址高位+2(02H+2=04H)就转移到WSET1继续搜索
LJMP WSET3 ;已经搜索完所有扇区，未找到上次保存的数据，跳转到WSET3保存当前设置
;**************************** 以上为EEPROM操作子程序 ****************************
;------------------ 字形表 ------------------
SEGTAB:
DB 00111111B ;0（3FH）
DB 00000110B ;1（06H）
DB 01011011B ;2（5BH）
DB 01001111B ;3（4FH）
DB 01100110B ;4（66H）
DB 01101101B ;5（6DH）
DB 01111101B ;6（7DH）
DB 00000111B ;7（07H）
DB 01111111B ;8（7FH）
DB 01101111B ;9（6FH）
SEGTAB2:
DB 00000110B,01110111B ;1A（06H,77H）
DB 00000110B,01111100B ;1b（06H,7CH）
DB 00000110B,00111001B ;1C（06H,39H）
DB 00000110B,01011110B ;1d（06H,5EH）
DB 01011100B,01000000B ;o-（5CH,40H）
DB 00111001B,01000000B ;C-（39H,40H）
DB 01111100B,00111001B ;bC（7CH,39H）
DB 00111000B,01011110B ;Ld（38H,5EH）
DB 01011011B,01110111B ;2A（5BH,77H）
DB 01011011B,01111100B ;2b（5BH,7CH）
DB 01011011B,00111001B ;2C（5BH,39H）
DB 01011011B,01011110B ;2d（5BH,5EH）
DB 01001111B,01110111B ;3A（4FH,77H）
DB 01001111B,01111100B ;3b（4FH,7CH）
DB 01001111B,00111001B ;3C（4FH,39H）
DB 01011110B,01000000B ;d-（5EH,40H）
DB 01111001B,01000000B ;E-（79H,40H）
;------------------------------------------------------------------------------------------
END

复制代码