五旬老汉学编程:红外遥控电容调速风扇控制器制作附单片机程序 -

;========================================================================
;红外遥控电容调速风扇控制器
;STC8G1K08(DIP16或SOP16)+TM1637显示模块+EC11编码器+CBB电容
;杨小强，2022年8月
;内部R/C时钟，频率选择：11.0592MHz
;显示：(TM1637)4位数码管显示模块
;调整定时、档位：EC11带按键5脚旋转编码器。也可以用3只按键代替EC11编码器
;
;工作时先全功率驱动继电器，延时一定时间后转为PWM方式驱动，以降低功耗减少发热量，
;PWM周期25微秒*2=50微秒，频率20KHz占空比50%，继电器线圈并联一只104电容，驱动电流降低到50%左右
;保持吸合状态。
;如果使用可控硅控制就取消主程序中初始化部分的“SETB PWM”指令，或改为“CLR PWM”（禁止PWM驱动）
;
;EC11编码器按键、旋转动作：
; 1.旋转编码器：对当前显示的“定时时间”或“档位”作增(减)调整
; 2.短按1次：正常风与自然风(睡眠风)切换。自然风状态时LED指示灯亮，只显示定时时间。
; 3.短按2次：设置自然风(睡眠风)渐慢/渐快变化的上下限档位范围、各档位变化的间隔时间(秒)
; 4.长按10秒：显示“----”，红外遥控信号解码，遥控器按键功能定义。定义好后须长按10秒才保存
;
;短按编码器按键2次设置自然风(睡眠风)渐慢/渐快变化的上下限档位范围、档位变化的间隔时间(秒)：
; 1.显示：L-最低档位下限，旋转编码器加/减，上、下限档位之间最少间隔3档。
; 2.显示：H-最高档位上限，旋转编码器加/减，上、下限档位之间最少间隔3档。
; 3.显示：E-档位渐慢/渐快变化时的间隔时间(1~5秒)，旋转编码器加/减
;设置好一项，短按编码器按键或者闪烁5秒无操作，自动跳到下一项。
;短按2次编码器按键保存并退出，或在第3项时无操作闪烁5秒自动保存并退出。
;
;长按10秒显示“----”进入红外遥控器的按键定义：
;定义1“关”、2“开/风速”、3“定时”、4“自然风”、5“+”、6“－”六个功能键。
; 交替显示功能编号+遥控器客户码(不显示反码)和原来保存的按键值，按键值为数据码+数据码反码
;共4个十六进制数，按下遥控器按键收到信号解码成功并显示，即为新的按键值，遥控器客户码与原来保
;存的不相同时，自动删除旧的数据(保存才会生效)，短按跳到下一个功能编号，也可以旋转EC11编码器
;向前/后跳到任意编号，全部或部分定义好后，长按10秒编码器按键显示“----”保存并退出才生效，
;短按两次退出或60秒无操作自动退出，不保存，仍然还是原来的数据。
;
;1“关”键：定时时间清零，关风扇
;2“开/风速”键：当定时时间为零时，置上电默认定时时间，开风扇；定时时间不为零时，档位
; 加1，到最高档后又从1档开始循环，支持长按连续加；自然风(睡眠风)状态时
; 不能调整档位。
;3“定时”键：增加定时时间。风扇在关的状态时，增加定时时间立即开风扇。
;4“自然风”键：正常风与自然风(睡眠风)切换，自然风(睡眠风)状态时LED指示灯亮，只显示定时时间。
;5“+”键：对当前显示的“定时时间”或“档位”作增加调整，支持长按连续加。
;6“-”键：对当前显示的“定时时间”或“档位”作减少调整，支持长按连续减。
;
;保存失败显示5秒E1
;
;P3口接6只继电器（5只CBB电容，耐压400V或630V)、LED指示灯、红外接收头：
;P3.0----9脚，继电器，1uF
;P3.1----10脚，继电器，2.2uF
;P3.2----11脚，继电器，3.3uF
;P3.3----12脚，继电器，4.7uF
;P3.4----13脚，继电器，4.7uF
;P3.5----14脚，继电器，直通
;P3.6----15脚，自然风LED指示灯，低电平亮
;P3.7----16脚，红外接收头
;
;各档档位控制码及对应的电容容量：
;01档：控制码FEH，P3.0控制的继电器导通，电容容量1uF
;02档：控制码FDH，P3.1控制的继电器导通，电容容量2.2uF
;03档：控制码FBH，P3.2控制的继电器导通，电容容量3.3uF
;04档：控制码FAH，P3.0、P3.2控制的继电器导通，电容容量1uF+3.3uF=4.3uF
;05档：控制码F9H，P3.1、P3.2控制的继电器导通，电容容量2.2uF+3.3uF=5.5uF
;06档：控制码F8H，P3.0、P3.1、P3.2控制的继电器导通，电容容量1uF+2.2uF+3.3uF=6.5uF
;07档：控制码F4H，P3.0、P3.1、P3.3控制的继电器导通，电容容量1uF+2.2uF+4.7uF=7.9uF
;08档：控制码F2H，P3.0、P3.2、P3.3控制的继电器导通，电容容量1uF+3.3uF+4.7uF=9uF
;09档：控制码F1H，P3.1、P3.2、P3.3控制的继电器导通，电容容量2.2uF+3.3uF+4.7uF=10.2uF
;10档：控制码F0H，P3.0、P3.1、P3.2、P3.3控制的继电器导通，电容容量1uF+2.2uF+3.3uF+4.7uF=11.2uF
;11档：控制码E4H，P3.0、P3.1、P3.3、P3.4控制的继电器导通，电容容量1uF+2.2uF+4.7uF+4.7uF=12.6uF
;12档：控制码E2H，P3.0、P3.2、P3.3、P3.4控制的继电器导通，电容容量1uF+3.3uF+4.7uF+4.7uF=13.7uF
;13档：控制码E1H，P3.1、P3.2、P3.3、P3.4控制的继电器导通，电容容量2.2uF+3.3uF+4.7uF+4.7uF=14.9uF
;14档：控制码E0H，P3.0、P3.1、P3.2、P3.3、P3.4控制的继电器导通，电容容量1uF+2.2uF+3.3uF+4.7uF+4.7uF=15.9uF
;15档：控制码DFH，P3.5控制的继电器导通，直通。
;
;----------------------------- 端口定义 ------------------------------------
P5 DATA 0C8H ;P5口定义
P1M1 DATA 091H ;P1口配置寄存器1
P1M0 DATA 092H ;P1口配置寄存器0
P3M1 DATA 0B1H ;P3口配置寄存器1
P3M0 DATA 0B2H ;P3口配置寄存器0
P5M1 DATA 0C9H ;P5口配置寄存器1
P5M0 DATA 0CAH ;P5口配置寄存器0
CLK EQU P1.0 ;1脚，接显示模块TM1637的CLK
DIO EQU P1.1 ;2脚，接显示模块TM1637的DIO
EC11A EQU P1.6 ;3脚，接编码器的A引脚（+）
EC11B EQU P1.7 ;4脚，接编码器的B引脚（-）
EC11K EQU P5.4 ;5脚，接编码器的按键KEY
LED EQU P3.6 ;15脚，自然风状态LED指示灯，低电平亮
IR EQU P3.7 ;16脚，红外接收头
BUZZER EQU P5.5 ;7脚，无源蜂鸣器
;---------------------------- 位地址及RAM的使用 ----------------------------
BMQDZ BIT 20H.0 ;编码器动作，1=编码器有旋转动作；0=没有旋转动作
XZFX BIT 20H.1 ;旋转方向，1=编码器顺时针正转；0=编码器逆时针反转
FLQH BIT 20H.2 ;风类切换，1=自然风(睡眠风)；0=正常风
TSFX BIT 20H.3 ;调速方向，1=渐快；0=渐慢。自然风渐变控制时的调速方向。
YSBC BIT 20H.4 ;延时保存，1=在MJS倒计时结束时保存档位。
SSBZ BIT 20H.5 ;闪烁标志，1=不显示，0=显示，数字及冒号闪烁时用，每0.5秒变化一次。
XSNRXZ BIT 20H.6 ;显示内容选择，1=显示档位；0=显示定时时间。
XSKG BIT 20H.7 ;显示开关，1=关闭T1中断的显示功能，0=允许显示定时和档位等内容
XSQHY BIT 21H.0 ;显示切换1，1=显示自然风档位变化范围或红外解码显示；0=显示档位或定时。
XSQHE BIT 21H.1 ;显示切换2，1=显示自然风档位变化范围；0=红外遥控信号解码显示。设置时用
BMXSQH BIT 21H.2 ;编码显示切换，1=显示数据码+反码；0=显示功能编号+系统码。设置时用
PWM BIT 21H.3 ;1=使用PWM方式驱动；0=禁止PWM驱动
PWMBZ BIT 21H.4 ;PWM的电平状态标志，1=高电平，0=低电平。PWM周期25微秒*2=50微秒，20KHz占空比50%
EEPBC BIT 21H.5 ;EEPROM操作子程序调用标志，1=EEPROM操作子程序正在调用继电器控制程序
FWBZ0 EQU 022H ;闪烁显示时长(秒)。受干扰等原因导致复位时闪烁10秒
DSSJS EQU 023H ;定时时间，时
DSSJF EQU 024H ;定时时间，分
DSSJM EQU 025H ;定时时间，秒
SMGLD EQU 026H ;数码管亮度，1~8级
DSDWJG EQU 027H ;上电设置的定时与档位交替显示的间隔时间(秒)
DSDW EQU 028H ;运行时使用，定时与档位交替显示的间隔时间(秒)
SMFJG2 EQU 029H ;运行时使用，自然风(睡眠风)档位变化的间隔时间(秒)
DANGW EQU 02AH ;运行时使用，自然风(睡眠风)变化时的实时档位
XMBH EQU 02BH ;项目编号，设置时使用
HM EQU 02CH ;毫秒，每毫秒减1，为0后重新放入计数值。定时器1使用，时间、显示处理
SHMJS EQU 02DH ;(10)毫秒倒计时，每10毫秒减1，直到为0
HMJS EQU 02EH ;(10)毫秒计数，为0后重新放入99（1秒）
MJS EQU 02FH ;秒计数，每秒减1，直到为0，主程序使用
XSHC1 EQU 030H ;显示缓存1，与上次不同就立即显示，否则0.5秒显示一次
XSHC2 EQU 031H ;显示缓存2，与上次不同就立即显示，否则0.5秒显示一次
ZXM1 EQU 032H ;显示用，待发送到TM1637的字形码1
ZXM2 EQU 033H ;显示用，待发送到TM1637的字形码2
ZXM3 EQU 034H ;显示用，待发送到TM1637的字形码3
ZXM4 EQU 035H ;显示用，待发送到TM1637的字形码4
MA1 EQU 036H ;接收到的红外遥控系统码(客户码)
MA2 EQU 037H ;接收到的红外遥控系统码(客户码)反码
MA3 EQU 038H ;接收到的红外遥控数据码
MA4 EQU 039H ;接收到的红外遥控数据码反码
HWJS EQU 03AH ;每10毫秒减1，直到为0，为0时清除“接收到的红外遥控数据码”，防止接收到别的连续码产生误动作。
ZRFJG EQU 03BH ;1:自然风变化时的档位下限；2=档位上限；3=档位变化的间隔时间。设置时用
FENGMQ EQU 03CH ;蜂鸣器鸣响时长（*10毫秒），每10毫秒减1直到为0，0=蜂鸣器不响
ZDJS EQU 03DH ;中断计数，蜂鸣器处理用
YSPWM EQU 03EH ;延时PWM驱动（*10毫秒），先全功率驱动继电器，每10毫秒减1，为0时转为PWM方式驱动
FWBZ1 EQU 03FH ;复位判断标志1，也作EEPROM数据判断标志
FWBZ2 EQU 040H ;复位判断标志2，也作EEPROM数据判断标志
DANG_G EQU 041H ;自然风(睡眠风)变化时的档位上限
DANG_D EQU 042H ;自然风(睡眠风)变化时的档位下限
SMFJG EQU 043H ;自然风(睡眠风)档位变化的间隔时间(秒)
DANG EQU 044H ;正常风档位
ANJZ EQU 045H ;红外遥控编码首地址，系统码(客户码)，6个键的数据码+数据码反码使用此地址后面12个字节
;--------------- 辅助寄存器、EEPROM寄存器地址 ---------------
AUXR EQU 08EH ;辅助寄存器
IAP_DATA EQU 0C2H ;数据寄存器，读出、写入的数据放在此处
IAP_ADDRH EQU 0C3H ;地址寄存器高八位
IAP_ADDRL EQU 0C4H ;地址寄存器低八位
IAP_CMD EQU 0C5H ;命令寄存器，0=关闭，1=读，2=写，3=擦除
IAP_TRIG EQU 0C6H ;命令触发寄存器
IAP_CONTR EQU 0C7H ;控制寄存器
IAP_TPS EQU 0F5H ;等待时间控制寄存器
;======================= 程序代码开始 =======================
ORG 0000H
LJMP START
ORG 000BH ;定时器0中断
LJMP INTT0 ;定时器0中断
ORG 001BH ;定时器1中断
LJMP INTT1 ;定时器1中断
ORG 0100H ;程序代码从0100H开始
;--------------- 定时器0，25微秒产生一次中断，控制继电器、LED指示灯、蜂鸣器 ---------------
INTT0:
PUSH ACC
PUSH PSW
LCALL Control ;控制继电器
JNB FLQH,INTT01 ;如果“风类切换”是0（正常风）就转移
CLR LED ;是自然风状态，点亮LED指示灯
INTT01:
CPL PWMBZ ;“PWM电平状态标志”取反。PWM周期25微秒*2=50微秒，20KHz占空比50%
MOV A,ZDJS ;中断计数
JZ INTT02 ;为0就转移，每5次（25微秒*5=125微秒）执行一次蜂鸣器处理。
DEC ZDJS ;减1
LJMP INTT04 ;
INTT02:
MOV ZDJS,#4 ;重新放入计数（5次）
MOV A,FENGMQ ;蜂鸣器鸣响时长
JZ INTT03 ;如果是0（不响）就转移
CPL BUZZER ;取反，驱动无源蜂鸣器发声。周期125微秒*2=250微秒，4KHz占空比50%
LJMP INTT04
INTT03:
SETB BUZZER ;置蜂鸣器控制端口为高电平（不响）
INTT04:
POP PSW
POP ACC
RETI
;--------------- 定时器1，1毫秒产生一次中断，时间、显示处理 ---------------
INTT1:
PUSH ACC
PUSH B
PUSH PSW
SETB RS1 ;RS1、RS0组合为11，选择03组工作寄存器(R0~R7地址为18H~1FH)，退
SETB RS0 ;出中断时会自动恢复原默认的第0组工作寄存器(R0~R7地址为00H~07H)
MOV A,HM ;毫秒计数
JZ INTT10 ;如果是0就转移，每10毫秒执行一次显示、时间处理子程序
DEC HM ;减1
LJMP INTT11
INTT10:
MOV HM,#9 ;重新放入计数值（10毫秒）
LCALL TIME ;时间处理
LCALL DISPLAY ;显示处理
INTT11:
POP PSW
POP B
POP ACC
RETI
;--------------- 定时器T0、T1设置 ----------------
SETINT:
ORL AUXR,#0C0H ;定时器T0、T1时钟1T模式
ANL TMOD,#00H ;设置定时器T0、T1模式为16位自动重载
MOV TL0,#0ECH ;设置定时0初始值（25微秒）
MOV TH0,#0FEH ;设置定时0初始值（25微秒）
MOV TL1,#0CDH ;设置定时1初始值（1毫秒）
MOV TH1,#0D4H ;设置定时1初始值（1毫秒）
CLR TF1 ;清除TF1标志
SETB TR1 ;定时器1开始计时
SETB ET1 ;允许定时器1中断
CLR TF0 ;清除TF0标志
SETB TR0 ;定时器0开始计时
SETB ET0 ;允许定时器0中断
SETB PT0 ;设置定时器0中断为最高优先级
SETB EA ;允许全局中断
RET
;*********************************** 主程序开始 ***********************************
START:
MOV P1M0,#00H ;设置P1为双向口模式
MOV P1M1,#00H ;
MOV P3M0,#00H ;设置P3为双向口模式
MOV P3M1,#00H ;
MOV P5M0,#00H ;设置P5为双向口模式
MOV P5M1,#00H ;
MOV SP,#0C0H ;设置堆栈指针
MOV A,FWBZ1 ;检查复位判断标志，RAM数据不变就跳过初始化继续运行
CJNE A,#0C8H,START1 ;检查复位判断标志，RAM数据不变就跳过初始化继续运行
MOV A,FWBZ2 ;检查复位判断标志，RAM数据不变就跳过初始化继续运行
CJNE A,#0D9H,START1 ;检查复位判断标志，RAM数据不变就跳过初始化继续运行
MOV FWBZ0,#10 ;放入复位提示，闪烁显示时长（秒）
LCALL SETINT ;定时器设置
LJMP START3 ;跳过初始化继续运行
START1:
CLR A ;初始化，RAM从20H开始清零50H个字节
MOV R0,#50H ;初始化，RAM从20H开始清零50H个字节
MOV R1,#20H ;初始化，RAM从20H开始清零50H个字节
START2:
MOV @R1,A ;初始化，RAM从20H开始清零50H个字节
INC R1 ;初始化，RAM从20H开始清零50H个字节
DJNZ R0,START2 ;
SETB PWM ;PWM标志置为1，使用PWM方式驱动，如果用可控硅控制就取消这条指令或改为“CLR PWM”(禁止PWM驱动)
MOV FWBZ1,#0C8H ;初始化，放入复位及EEPROM判断标志1到RAM
MOV FWBZ2,#0D9H ;初始化，放入复位及EEPROM判断标志2到RAM
MOV FENGMQ,#12 ;上电蜂鸣器响一声，鸣响时长12*10毫秒=120毫秒
LCALL SDMRDS ;置上电默认定时时间
MOV SMGLD,#3 ;置数码管亮度为3级（8级亮度最高）
MOV DSDWJG,#3 ;定时与档位交替显示的间隔时间(秒)
MOV SMFJG,#2 ;睡眠风(自然风)渐慢/渐快档位变化的间隔时间(秒)，如果EEPROM保存有设置值，将替换此默认设置
MOV DANG,#15 ;正常风档位（1~15），如果EEPROM保存有设置值，将替换此默认设置
MOV DANG_G,#5 ;自然风变化时最高档位上限（4~15），如果EEPROM保存有设置值，将替换此默认设置
MOV DANG_D,#1 ;自然风变化时最低档位下限（1~12），如果EEPROM保存有设置值，将替换此默认设置
LCALL SETINT ;初始化，定时器设置
LCALL REEP ;读EEPROM保存的各项设置，没有就保存当前的设置值
START3:
CLR XSKG ;“显示开关”置为0，允许T1中断的显示功能
CLR XSQHY ;“显示切换1”置为0，显示档位、定时时间
LCALL HWYKCL ;调用红外遥控处理子程序
LCALL SKEY ;扫描编码器按键
JC START4 ;有按键动作（C=1）就转移
LCALL Scan1 ;扫描编码器
JNB BMQDZ,START5 ;编码器没有动作（BMQDZ=0）就转移
LCALL BMQCL ;调用编码器旋转动作处理子程序
LJMP START3
START4:
LCALL AJDZCL ;调用按键动作处理子程序
LJMP START3
START5:
JNB YSBC,START3 ;如果“延时保存”为0（不需保存当前档位值）就转移
MOV A,MJS ;装入倒计时
JNZ START3 ;不是0就转移
CLR YSBC ;时间到，“延时保存”置为0
LCALL WEEP ;保存当前档位值
LJMP START3
;*********************************** 主程序结束 ***********************************
;
;--------------- 设置上电默认定时 ---------------
SDMRDS:
MOV DSSJS,#8 ;小时
RET
;--------------- 设置“延时PWM驱动”时间 ---------------
;先全功率驱动继电器，延时结束后转为PWM方式驱动，降低功耗减少继电器发热量。
;继电器吸合速度正常为几毫秒至几十毫秒。PWM方式驱动改为禁止后，“延时PWM驱动”无意义
SETPWM:
MOV YSPWM,#10 ;延时时间（*10毫秒），10*10=100毫秒
RET
;-------------------------------------------------------------------------------
;红外遥控处理子程序
;1“关”键：定时时间清零，关风扇
;2“开/风速”键：定时时间为零时，置上电默认定时时间，开风扇；定时时间不为零时，档位
; 加1，到最高档后又从1档开始循环，支持长按连续加；
; 自然风(睡眠风)状态时不能调整档位。
;3“定时”键：增加定时时间。在关的状态时，增加定时时间立即开风扇。支持长按连续加。
;4“睡眠”键：正常风与自然风(睡眠风)切换，自然风状态时LED指示灯亮，只显示定时时间。
;5“+”键：对当前显示的“定时时间”或“档位”作增加调整，支持长按连续加。
;6“-”键：对当前显示的“定时时间”或“档位”作减少调整，支持长按连续减。
;-------------------------------------------------------------------------------
HWYKCL:
LCALL JIEMA ;调用红外遥控解码子程序
JC YKCL1 ;解码成功（C=1）就转移
YKCL0:
RET
YKCL1:
MOV R5,A ;解码子程序返回的参数暂时放到R5
MOV A,MA1 ;装入当前接收到的系统码到A
MOV B,ANJZ ;装入原来保存的系统码到B
CJNE A,B,YKCL0 ;不同就转移退出
MOV R0,#ANJZ ;按键值首地址
INC R0 ;地址加1
MOV R3,#6 ;共搜索6个按键值
MOV R7,#1 ;功能编号
YKCL2:
MOV A,MA3 ;装入数据码
MOV B,@R0 ;装入原来的数据码
CJNE A,B,YKCL3 ;不同就转移，检查下一个
INC R0 ;相同，地址加1，检查反码是否相同
MOV A,MA4 ;装入数据码反码
MOV B,@R0 ;装入数据码反码
DEC R0 ;地址减1
CJNE A,B,YKCL3 ;不同就转移，检查下一个
LJMP YKCL4 ;搜索到了
YKCL3:
INC R0 ;地址加1
INC R0 ;地址加1
INC R7 ;功能编号加1
DJNZ R3,YKCL2 ;如果未检查完就转移继续
RET ;未搜索到，退出
YKCL4:
LCALL SETPWM ;设置“延时PWM驱动”时间
MOV A,R5 ;解码子程序返回的参数
JNZ YKCL41 ;如果是连续码（1）就转移
MOV FENGMQ,#12 ;蜂鸣器响一声，12*10毫秒=120毫秒
YKCL41:
MOV A,R7 ;功能编号放入A
CJNE A,#1,YKCL5 ;不是1（关）就转移
LCALL DSSJQL ;定时时间清零，关风扇
CLR XSNRXZ ;“显示内容选择”置为0，显示定时时间
RET
YKCL5:
CJNE A,#2,YKCL8 ;不是2（开/风速）就转移
MOV A,DSSJS ;检查定时时间是否为0
JNZ YKCL6 ;不为0就转移
MOV A,DSSJF ;检查定时时间是否为0
JNZ YKCL6 ;不为0就转移
MOV A,DSSJM ;检查定时时间是否为0
JNZ YKCL6 ;不为0就转移
LCALL SDMRDS ;是0，放入上电默认定时时间，开风扇
MOV SHMJS,#150 ;设置持续按下“开/风速”等待1.5秒才响应连续码
RET
YKCL6:
JB FLQH,YKCL12 ;如果“风类切换”为1睡眠风(自然风)就转移退出
MOV A,SHMJS
JNZ YKCL12 ;如果时间未到就转移退出，不响应
MOV SHMJS,#30 ;设置响应连续码间隔时间(×10毫秒)
SETB XSNRXZ ;“显示内容选择”置为1，显示档位
MOV A,DANG ;装入当前档位值
CJNE A,#15,YKCL7 ;不是最高档（15）就转移
MOV DANG,#0 ;是，改为0
YKCL7:
SETB XZFX ;“旋转方向”置为1（+）
LCALL BMQCL ;加
RET
YKCL8:
CJNE A,#3,YKCL9 ;不是3（定时）就转移
MOV A,SHMJS
JNZ YKCL12 ;如果时间未到就转移退出，不响应
MOV SHMJS,#30 ;设置响应连续码的间隔时间(×10毫秒)
CLR XSNRXZ ;“显示内容选择”置为0，显示定时时间
LJMP YKCL7
YKCL9:
CJNE A,#4,YKCL10 ;不是4睡眠风(自然风)就转移
MOV A,SHMJS
JNZ YKCL12 ;如果时间未到就转移退出，不响应
MOV SHMJS,#100 ;设置响应连续码的间隔时间，1秒
CPL FLQH ;“风类切换”取反，正常风/自然风切换
RET
YKCL10:
CJNE A,#5,YKCL11 ;不是5(加+)就转移
MOV A,SHMJS
JNZ YKCL12 ;如果时间未到就转移退出，不响应
MOV SHMJS,#20 ;设置响应连续码的间隔时间(×10毫秒)
SETB XZFX ;“旋转方向”置为1（+）
LCALL BMQCL ;加
RET
YKCL11:
MOV A,SHMJS ;
JNZ YKCL12 ;如果时间未到就转移退出，不响应
MOV SHMJS,#20 ;设置响应连续码的间隔时间(×10毫秒)
CLR XZFX ;“旋转方向”置为0（-）
LCALL BMQCL ;减
YKCL12:
RET
;--------------------------------------------------------------------------------------------
;子程序：红外遥控解码
;出口参数：
;C=1、A=0：解码成功。
;C=1、A=1：连续码。
;系统码(客户码)放在MA1，系统码(客户码)反码放在MA2
;数据码(按键值)放在MA3，数据码(按键值)反码放在MA4
;
;红外接收头实际输出的NEC编码格式：
;引导码：9ms低电平+4.5ms高电平
;码0：0.56ms低电平+0.56ms高电平
;码1：0.56ms低电平+1.68ms高电平
;结束位：0.56ms低电平
;单键码：引导码+8位系统码+8位系统码反码+8位数据码+8位数据码反码+结束位
;连续码：引导码9ms低电平+2.25ms高电平+结束位0.56ms低电平
;
;有个别红外遥控器并不是8位系统码+8位系统码反码+8位数据码+8位数据码反码的数据格式，
;而是这两种情况：
;一、16位固定的系统码(客户码)+8位数据码+8位数据码反码
;二、24位固定的系统码(客户码)+8位数据码
;所以对解码结果不作反码检验
;
;43微秒延时子程序的数值是156，因T0中断频率高占用资源，使延时变长，修改为127才能正确解码，
;如果移植到别的程序，没有过高频率的中断，数值要改回156
;--------------------------------------------------------------------------------------------
JIEMA:
JB IR,JMerr ;IR为1(高电平)就转移退出，无信号
MOV R7,#200 ;检测200次×43微秒＝8600微秒(8.6毫秒)
JIEMA1:
LCALL DELAY43US ;延时43微秒
JB IR,JMerr ;如果出现高电平(IR为1)就转移退出，不是有效信号
DJNZ R7,JIEMA1 ;重复200次
MOV R7,#20 ;未出现高电平，视为有效9毫秒引导码，再检测20次
JIEMA2:
LCALL DELAY43US ;延时43微秒
JB IR,JIEMA3 ;如果出现高电平(IR=1)就转移
DJNZ R7,JIEMA2 ;重复20次×43微秒＝860微秒(0.86毫秒)
LJMP JMerr ;超时，退出，不是有效信号
JIEMA3:
MOV HWJS,#50 ;500毫秒计数，为0时清除“接收到的红外遥控数据码”，防止接收到别的连续码产生误动作。
MOV R7,#70 ;已变为高电平，9毫秒引导码结束，检测70次共3010微秒
JIEMA4:
LCALL DELAY43US ;延时43微秒
JNB IR,LXM ;出现低电平(IR=0)就视为是2.25毫秒连续码
DJNZ R7,JIEMA4
MOV R7,#50 ;3.01毫秒内未出现低电平，不是连续码，再检测50次
JIEMA5:
LCALL DELAY43US ;延时43微秒
JNB IR,JIEMA6 ;出现低电平(IR=0)就转移，4.5毫秒引导码高电平结束
DJNZ R7,JIEMA5 ;重复50次共2150微秒
LJMP JMerr ;超时，退出，不是有效信号
LXM:
SETB C ;是连续码，把C置为1
MOV A,#1 ;是连续码，把1放入A
RET
JIEMA6:
;--- 引导码9ms低电平+4.5ms高电平结束 ---
MOV R1,#MA1 ;存放编码的首地址放入R1
MOV R5,#4 ;共4个字节数据
JIEMA7:
MOV R6,#8 ;每个字节为8位
JIEMA8:
MOV R7,#20 ;检测20次×43微秒＝860微秒(0.86毫秒)，要大于0.56毫秒
JIEMA9:
LCALL DELAY43US ;延时43微秒
JB IR,JIEMA10 ;如果IR是1(高电平)就转移
DJNZ R7,JIEMA9 ;时间未到就继续检测，等待低电平信号结束
LJMP JMerr ;超时，退出
JIEMA10:
MOV R7,#20 ;变为高电平了，延时20次共860微秒(0.86毫秒)
JIEMA11:
LCALL DELAY43US
DJNZ R7,JIEMA11 ;延时0.86毫秒
MOV C,IR ;延时结束IR的电平就是数据信号(0或1)，移入C中
JNB IR,JIEMA13 ;如果IR是0(低电平)就转移
MOV R7,#50 ;是高电平，检测50次×43微秒＝2150微秒(2.15毫秒)
JIEMA12:
LCALL DELAY43US ;
JNB IR,JIEMA13 ;如果IR是0(低电平)就转移，
DJNZ R7,JIEMA12 ;时间未到就继续检测，等待高电平信号结束
LJMP JMerr ;超时，退出
JIEMA13:
MOV A,@R1 ;装入R1指向的RAM地址的数据到A寄存器
RRC A ;将C中的值（0或1）移入A中的最低位
MOV @R1,A ;把A中的数据放回R1指向的RAM
DJNZ R6,JIEMA8 ;如果未接收完8位就转移继续
INC R1 ;接收完8位了，地址加1
DJNZ R5,JIEMA7 ;如果4个字节数据未接收完就转移继续
JMok:
SETB C ;把C置为1，解码成功
CLR A ;把A置为0，解码成功
RET
JMerr:
CLR C ;把C置为0，解码不成功
RET
;------------ 延时43微秒 ------------
DELAY43US: ;@11.0592MHz
PUSH 12H
MOV 12H,#127 ;延时43微秒的数值是156，因T0中断频率高占用资源，使延时变长，修改为此数
NEXT43: ;值才能正确解码，如果移植到别的程序，没有过高频率的中断，此数值要改回156
DJNZ 12H,NEXT43
POP 12H
RET
;------------------------------------------------------------------------------------------------
;子程序：EC11编码器按键动作处理
; 1.短按1次：正常风与睡眠风(自然风)切换。睡眠风状态时LED指示灯亮，只显示定时时间。
; 2.短按2次：设置睡眠风(自然风)渐慢/渐快变化的上下限档位范围、档位变化时的间隔时间(秒)
; 3.长按10秒：显示“----”，红外线遥控信号解码，遥控器按键的功能定义，定义好后须长按10秒才保存
;
;红外遥控器的按键定义：
;定义1“关”、2“开/风速”、3“定时”、4“睡眠”、5“+”、6“－”六个功能键。
; 交替显示功能编号+遥控器客户码和原来保存的按键值，按键值为数据码+数据码反码4个十
;六进制数，按下遥控器按键收到信号解码成功并显示，即为新的按键值，遥控器客户码与原来保
;存的不相同时，自动删除旧的数据(保存才会生效)，短按跳到下一个功能编号，也可以旋转EC11
;编码器向前/后跳到任意功能编号，全部或部分定义好后，长按10秒显示“----”保存并退出才生
;效，短按两次退出或60秒无操作自动退出，不保存，仍然还是原来的数据。
;-------------------------------------------------------------------------------------------------
AJDZCL:
LCALL KEY ;调用编码器按键开关处理子程序
CJNE A,#1,AJDZ2 ;如果不是按下1次就转移
CPL FLQH ;“风类切换”取反，正常风/自然风切换
RET
AJDZ2:
CJNE A,#2,AJDZ3 ;如果不是按下2次就转移
LCALL ZRFFW ;调用自然风变化档位上下限范围、档位变化间隔时间设置子程序
RET
AJDZ3:
SETB XSQHY ;是长按10秒，“显示切换1”置为1，显示红外解码或自然风档位变化范围
CLR XSQHE ;“显示切换2”置为0，红外遥控信号解码显示
MOV XMBH,#1 ;先放入项目编号1（关）
LCALL HENGX ;关闭T0中断的显示功能，显示“----”
LCALL KEYEX ;等待按键释放
CLR XSKG ;“显示开关”置为0，恢复T1中断的显示功能
AJDZ4:
CLR BMXSQH ;“编码显示切换”置为0，先显示功能编号+系统码
AJDZ5:
MOV MJS,#60 ;设置无信号等待时间（秒）
MOV DSDW,#2 ;设置系统码和数据码交替显示间隔时间（秒）
AJDZ6:
MOV FWBZ0,#0 ;把0放入到FWBZ0，不闪烁显示
AJDZ7:
LCALL JIEMA ;调用红外遥控解码子程序
JC LXMPD ;解码成功（C=1）就转移
LCALL SKEY ;扫描编码器按键
JNC AJDZ11 ;没有按键动作(C=0)就转移
MOV FWBZ0,#0 ;把0放入到FWBZ0，不闪烁显示
LCALL KEY ;有按键动作，调用编码器按键处理子程序
CJNE A,#3,AJDZ9 ;如果不是3（长按10秒）就转移
AJDZ8:
LCALL WEEP ;保存当前设置
LCALL HENGX ;关闭T0中断的显示功能，显示“----”
LCALL KEYEX ;等待按键释放
CLR XSKG ;“显示开关”置为0，恢复T1中断的显示功能
RET
LXMPD:
JZ AJDZ17 ;如果A=0（不是连续码）就转移
LJMP AJDZ5
AJDZ9:
CJNE A,#1,AJDZ_Q ;如果不是1（短按1次）就转移退出，不保存
AJDZ90:
MOV A,XMBH ;装入项目编号
CJNE A,#6,AJDZ10 ;如果不是最后一项就转移
MOV XMBH,#0
AJDZ10:
INC XMBH ;加1，跳到下一个功能编号
LJMP AJDZ4
AJDZ11:
LCALL Scan1 ;扫描编码器（有方向标志）
JB BMQDZ,AJDZ15 ;编码器有动作(1)就转移
MOV A,DSDW ;没有转动，装入交替显示间隔时间（秒）到寄存器A
JNZ AJDZ12 ;不为0就转移
CPL BMXSQH ;为0，“编码显示切换”取反，显示另一项
MOV DSDW,#1 ;设置系统码和数据码交替显示间隔时间（秒）
AJDZ12:
MOV A,MJS ;装入无信号等待时间到寄存器A
JNZ AJDZ13 ;不为0就转移
AJDZ_Q:
LCALL RE00 ;读EEPROM保存的数据
MOV FWBZ0,#0 ;把0放入到FWBZ0，不闪烁显示，退出，不保存
RET
AJDZ13:
CJNE A,#6,AJDZ14 ;检查剩余时间
AJDZ14:
JNC AJDZ6 ;等于或大于就转移，不闪烁显示
MOV FWBZ0,A ;剩余时间放到FWBZ0，闪烁显示
LJMP AJDZ7
AJDZ15:
LCALL Scan2 ;扫描编码器（无方向标志）
JB BMQDZ,AJDZ15 ;旋转动作未结束(1)就转移继续等待
JB XZFX,AJDZ90 ;顺时针正转(1）就转移
MOV A,XMBH ;反转，装入项目编号
DEC A ;减1
JNZ AJDZ16 ;不为0就转移
MOV A,#6 ;跳到第6项
AJDZ16:
MOV XMBH,A
LJMP AJDZ4
;
AJDZ17:
SETB BMXSQH ;“编码显示切换”置为1（显示数据码+反码）
MOV A,MA1 ;装入当前接收到的系统码到A
MOV B,ANJZ ;装入原来保存的系统码到B
CJNE A,B,AJDZ20 ;不同就转移
MOV R0,#ANJZ ;遥控编码首地址
INC R0 ;地址加1
MOV R3,#6 ;检查6个按键值，发现有相同的就删除（清零）
AJDZ18:
MOV A,MA3 ;装入数据码
MOV B,@R0 ;装入原来的数据码
CJNE A,B,AJDZ19 ;不同就转移，检查下一个
INC R0 ;相同，地址加1，检查反码看是否也相同
MOV A,MA4 ;装入数据码反码
MOV B,@R0 ;装入数据码反码
DEC R0 ;地址减1
CJNE A,B,AJDZ19 ;不同就转移，检查下一个
MOV @R0,#0 ;也相同，数据码位置放入0
INC R0 ;地址加1
MOV @R0,#0 ;反码位置放入0
DEC R0 ;地址减1
AJDZ19:
INC R0 ;地址加1
INC R0 ;地址加1
DJNZ R3,AJDZ18 ;如果未检查完就转移继续
LJMP AJDZ22
AJDZ20:
MOV ANJZ,MA1 ;移入新的系统码
MOV R0,#ANJZ ;原来的数据全部清零
MOV R3,#12 ;原来的数据全部清零
AJDZ21:
INC R0 ;原来的数据全部清零
MOV @R0,#0 ;原来的数据全部清零
DJNZ R3,AJDZ21 ;原来的数据全部清零
AJDZ22:
MOV A,XMBH ;装入项目编号
MOV B,#2 ;项目编号乘2
MUL AB ;项目编号乘2
DEC A ;计算结果减1
ADD A,#ANJZ ;加遥控编码首地址
MOV R0,A ;得出数据码的实际地址
MOV @R0,MA3 ;把接收到的数据移到对应的按键值RAM地址
INC R0 ;把接收到的数据移到对应的按键值RAM地址
MOV @R0,MA4 ;把接收到的数据移到对应的按键值RAM地址
LJMP AJDZ5
;---------------------------------------------------------------------------------
;子程序：设置调整睡眠风(自然风)变化的档位上下限范围、变化时的间隔时间(秒)
; 1.显示：L-最低档位下限
; 2.显示：H-最高档位上限
; 3.显示：E-档位变化时的间隔时间(秒)
;短按编码器按键，跳到另一项；短按2次编码器按键保存并退出；无操作5秒后开始闪烁显示，
;闪烁显示5秒跳到下一项，如果在第3项，闪烁显示5秒无操作则保存并退出。
;上、下限档位之间最少间隔3档。自然风档位变化的间隔时间为1~5秒
;---------------------------------------------------------------------------------
ZRFFW:
SETB XSQHY ;“显示切换1”置为1，显示红外解码或自然风档位变化范围
SETB XSQHE ;“显示切换2”置为1，显示自然风档位变化范围
MOV ZRFJG,#1 ;先设为第一项，档位下限
ZRFFW1:
MOV A,ZRFJG ;装入项目号
DEC A ;减1
JNZ ZRFFW2 ;不为0就转移
LCALL ZRFXX ;是1，设置下限档位调整时的最大和最小值、调整对象的地址
LJMP SZTZ
ZRFFW2:
DEC A ;减1
JNZ ZRFFW3 ;不为0就转移
LCALL ZRFSX ;是2，设置上限档位调整时的最大和最小值、调整对象的地址
LJMP SZTZ
ZRFFW3:
MOV R5,#1 ;是3，档位变化的间隔时间(秒)，调整时的最小值
MOV R6,#5 ;是3，档位变化的间隔时间(秒)，调整时的最大值
MOV R0,#SMFJG ;档位变化的间隔时间(秒)地址
SZTZ:
MOV MJS,#10 ;无操作等待时间10秒
SZTZ1:
MOV FWBZ0,#0 ;把0放入到FWBZ0，不闪烁显示
SZTZ2:
LCALL SKEY ;扫描编码器按键开关
JNC SZTZ5 ;没有按键动作(C=0)就转移
LCALL KEY ;有按键动作，调用编码器按键处理子程序
CJNE A,#2,SZTZ3
SZTZ3:
JNC SZTZ4 ;如果是按下2次及以上就转移
SZTZ30:
INC ZRFJG ;是按下1次，项目号加1（跳到下一项）
MOV A,ZRFJG ;装入项目号
CJNE A,#4,SZTZ31 ;是否小于4
SZTZ31: JC ZRFFW1 ;小于就转移
LJMP ZRFFW ;等于或大于，转移，设为第一项
SZTZ4:
LCALL WEEP ;保存
MOV FWBZ0,#0 ;把0放入到FWBZ0，不闪烁显示
LCALL KEYEX ;等待按键释放
RET
SZTZ5:
LCALL Scan1 ;扫描编码器（有方向标志）
JB BMQDZ,SZTZ8 ;编码器已经转动（1）就转移
MOV A,MJS ;没有转动，装入秒计数到寄存器A
JZ SZTZ7 ;如果秒计数为0(10秒无操作)就转移
CJNE A,#6,SZTZ6 ;检查剩余时间
SZTZ6:
JNC SZTZ1 ;等于或大于就转移，不闪烁显示
MOV FWBZ0,A ;剩余时间放到FWBZ0，闪烁显示
LJMP SZTZ2
SZTZ7:
MOV A,ZRFJG ;时间到，装入项目号
CJNE A,#3,SZTZ30 ;不是最后一项就转移，跳到下一项
LJMP SZTZ4 ;转移，保存并退出
SZTZ8:
LCALL Scan2 ;扫描编码器（无方向标志）
JB BMQDZ,SZTZ8 ;旋转动作未结束（1）就转移继续等待
JB XZFX,SZTZ11 ;是顺时针正转（1）就转移
MOV B,R5 ;是反转，装入最小值到B寄存器
MOV A,@R0 ;装入R0指向的RAM地址的调整对象数值
DEC A ;减1
CJNE A,B,SZTZ9 ;与最小比较
SZTZ9:
JC SZTZ10 ;如果小于就转移
MOV @R0,A ;等于或大于，把减1后的结果放回去
LJMP SZTZ
SZTZ10:
MOV @R0,B ;直接放入最小值
LJMP SZTZ
SZTZ11:
MOV B,R6 ;装入最大值到B寄存器
MOV A,@R0 ;装入R0指向的RAM地址的调整对象数值
INC A ;加1
CJNE A,B,SZTZ12 ;加完后与最大值比较
SZTZ12:
JC SZTZ13 ;如果小于就转移
MOV @R0,B ;等于或大于，直接放入最大值
LJMP SZTZ
SZTZ13:
MOV @R0,A ;小于最大值，把加1后的结果放回去
LJMP SZTZ
;---------------------------------------------------------------------------
;设置睡眠风(自然风)变化范围的上限档位，最大为15档，最小为下限档位加3档
;---------------------------------------------------------------------------
ZRFSX:
MOV B,#15 ;调整时的最大值
MOV A,DANG_D ;装入当前档位下限
ADD A,#3 ;加3档
CJNE A,B,ZRFSX1 ;是否等于或大于上限
ZRFSX1:
JC ZRFSX2 ;小于就转移
MOV A,B
PUSH ACC
SUBB A,#3 ;等于或大于，把档位下限改为最大值减3档
MOV DANG_D,A ;等于或大于，把档位下限改为最大值减3档
POP ACC
ZRFSX2:
MOV R5,A ;调整时的最小值
MOV R6,B ;调整时的最大值
MOV R0,#DANG_G ;自然风档位上限地址
RET
;---------------------------------------------------------------------------
;设置睡眠风(自然风)变化范围的下限档位，最小为1档，最大为上限档位减3档
;---------------------------------------------------------------------------
ZRFXX:
MOV B,#4 ;调整时的最小值1加3档
MOV A,DANG_G ;装入当前自然风档位上限
CJNE A,B,ZRFXX1
ZRFXX1:
JC ZRFXX2 ;小于就转移
SUBB A,#3 ;等于或大于，档位上限减3档即为调整时的最大值
MOV B,A ;等于或大于，档位上限减3档即为调整时的最大值
LJMP ZRFXX3
ZRFXX2:
MOV DANG_G,B ;小于最小值+3档，把上限档位改为最小值加3档
MOV B,#1
ZRFXX3:
MOV R5,#1 ;调整时的最小值
MOV R6,B ;调整时的最大值
MOV R0,#DANG_D ;自然风档位下限地址
RET

复制代码

;------------------------------------------------------------------------------------
;子程序：编码器按键开关处理，间隔时间不超过0.6秒的2次短按，为有效按键动作
;出口参数：A=1(按了1次)；A=2(按了2次)；A=3(长按达到了10秒)
;------------------------------------------------------------------------------------
KEY:
MOV MJS,#10 ;放入等待时间(秒)
MOV FENGMQ,#12 ;蜂鸣器响一声，12*10毫秒=120毫秒
KEY1:
MOV A,MJS ;装入等待时间
JNZ KEY2 ;如果不为0就转移，时间未到
MOV A,#3 ;时间到了
RET
KEY2:
LCALL SKEY ;扫描按键
JC KEY1 ;如果C=1(按键还没松开)，就继续扫描
LCALL KEYA ;扫描按键600毫秒
JZ KEY3 ;如果600毫秒内有按键动作就转移
MOV A,#1 ;600毫秒内没有按键动作，置A=1(按了1次)
RET
KEY3:
MOV FENGMQ,#12 ;蜂鸣器响一声，12*10毫秒=120毫秒
LCALL KEYEX ;等待第二次按键松开
MOV A,#2 ;置A=2(按了2次)
RET
;----------- 扫描按键600毫秒，有按键动作A=0，无按键动作A=1 -----------
KEYA:
MOV SHMJS,#60 ;等待600毫秒
KEYB:
MOV A,SHMJS ;装入(10)毫秒计数
JZ KEYC ;为0（时间到）就转移
LCALL SKEY ;扫描按键
JNC KEYB ;没有按键动作(C=0)就转移
CLR A ;有按键动作A=0
RET
KEYC:
MOV A,#1 ;等待时间已到，A=1没有按键动作
RET
;-------------- 按键开关扫描，未按C=0，已按下C=1 --------------
SKEY:
SETB EC11K ;按键端口置为高电平
JNB EC11K,SKEY1 ;为0(低电平)就转移
CLR C ;C置为0，没有按键动作
RET
SKEY1:
LCALL DELAY20 ;延时20毫秒
SETB EC11K ;延时结束后再次把按键端口置为高电平
JNB EC11K,SKEY2 ;为0(低电平)就转移
CLR C ;C置为0，没有按键动作
RET ;按键未被有效按下，退出
SKEY2:
SETB C ;C置为1，按键已有效按下
LCALL SETPWM ;有按键动作就重新放置“延时PWM驱动”时间
RET
;------------------ 等待按键释放 ------------------
KEYEX:
LCALL SKEY ;扫描按键
JC KEYEX ;如果C=1(按键还没释放)就继续扫描
RET
;------------------ 延时20毫秒 ------------------
DELAY20: ;@11.0592MHz
PUSH 15H
PUSH 16H
PUSH 17H
MOV 15H,#2
MOV 16H,#32
MOV 17H,#58
NEXT20:
DJNZ 17H,NEXT20
DJNZ 16H,NEXT20
DJNZ 15H,NEXT20
POP 17H
POP 16H
POP 15H
RET
;---------------------------------------------------------------------------------------------
;子程序：编码器旋转动作处理，根据旋转方向增(减)定时时间、档位
;10小时以下每次增(减)30分钟；10小时及以上每次增(减)1个小时；20小时以上每次增(减)2个小时
;---------------------------------------------------------------------------------------------
BMQCL:
LCALL Scan2 ;扫描编码器（无方向标志）
MOV DSDW,DSDWJG ;置交替显示间隔时间
JB BMQDZ,BMQCL ;“编码器动作”为1(动作未结束)就转移继续等待
BMQCL0:
JNB XSNRXZ,BMQCL5 ;“显示内容选择”为0(显示定时时间)就转移
SETB YSBC ;“延时保存”置为1
MOV MJS,#10 ;“延时保存”时长（秒）。延时结束后才保存，避免频繁的EEPROM操作
MOV A,DANG ;装入当前档位值
JB XZFX,BMQCL2 ;“旋转方向”为1（顺时针正转）就转移
DEC A ;是反转，减1档
JNZ BMQCL1 ;减1后不为0就转移
RET
BMQCL1:
MOV DANG,A
RET
BMQCL2:
CJNE A,#15,BMQCL3 ;是否已到最高15档
BMQCL3:
JC BMQCL4 ;小于就转移
MOV DANG,#15 ;等于或大于，放入最高档位15
RET
BMQCL4:
INC DANG ;还未到上限，增1档
RET
BMQCL5:
CLR SSBZ ;“闪烁标志”置为0（数字及冒号状态为“显示”）
MOV A,DSSJS ;装入定时时间（时）
CJNE A,#20,BMQCL6 ;当前“时”是否等于或大于20
BMQCL6:
JC BMQCL7 ;小于就转移
MOV R5,#2 ;等于或大于20，加减2个小时
LJMP BMQCL9
BMQCL7:
CJNE A,#10,BMQCL8 ;当前“时”是否等于或大于10
BMQCL8:
JC BMQCL13 ;小于就转移
MOV R5,#1 ;等于或大于10，加减1个小时
BMQCL9:
JNB XZFX,BMQCL11 ;“旋转方向”为0（逆时针反转）就转移
ADD A,R5 ;是正转，加
CJNE A,#100,BMQCL10 ;加完后是否等于或大于100
BMQCL10:
JC BMQCL12 ;如果小于就转移，把A放回到DSSJS
MOV DSSJS,#99 ;已经大于99了，直接设置为99:59:59+HMJS(1秒)，100小时
MOV DSSJF,#59 ;已经大于99了，直接设置为99:59:59+HMJS(1秒)，100小时
MOV DSSJM,#59 ;已经大于99了，直接设置为99:59:59+HMJS(1秒)，100小时
RET
BMQCL11:
SUBB A,R5 ;是反转，减
BMQCL12:
MOV DSSJS,A ;把计算结果放入DSSJS
RET
BMQCL13:
MOV A,DSSJF ;小于10小时，装入定时时间（分）
JNB XZFX,BMQCL16 ;“旋转方向”为0（逆时针反转）就转移
ADD A,#30 ;是正转，当前“分”加30
CJNE A,#60,BMQCL14 ;加完后“分”是否等于或大于60
BMQCL14:
JC BMQCL15 ;小于60就转移，把A放入定时时间（分）
SUBB A,#60 ;等于或大于60，就减60，然后小时加1
INC DSSJS ;小时加1
BMQCL15:
MOV DSSJF,A ;把A放入定时时间（分）
RET
BMQCL16:
CJNE A,#30,BMQCL17 ;是逆时针反转，当前“分”是否等于或大于30
BMQCL17:
JC BMQCL18 ;小于就转移
SUBB A,#30 ;定时时间（分）减30
MOV DSSJF,A ;把计算结果放入定时时间（分）
RET
BMQCL18:
MOV A,#30 ;“分”小于30，把30放入寄存器A
CLR C ;进位标志清0
SUBB A,DSSJF ;减“定时时间（分）”
MOV DSSJF,A ;减完后的结果暂时放入DSSJF
MOV A,#60
SUBB A,DSSJF ;60减上面的计算结果，得出定时时间（分），然后小时减1
MOV DSSJF,A ;得出的数放入定时时间（分）
MOV A,DSSJS ;装入定时时间（时）
JZ DSSJQL ;如果“时”为0就转移（不够减了，把定时时间清零）
DEC DSSJS ;“时”不为0，减1
RET
DSSJQL:
MOV DSSJS,#0 ;定时时间清零
MOV DSSJF,#0 ;定时时间清零
MOV DSSJM,#0 ;定时时间清零
RET
;----------------------------------------------------------------------------------------------
;子程序：扫描编码器是否有旋转动作并设置好方向标志
;出口参数：“编码器动作”=1已经转动，=0没有转动；“旋转方向”=1顺时针正转，=0逆时针反转
;----------------------------------------------------------------------------------------------
Scan1:
SETB EC11A ;拉高编码器A引脚电平
SETB EC11B ;拉高编码器B引脚电平
JNB EC11A,Scan11 ;如果为0(低电平)就转移，编码器有旋转动作，顺时针正转
JNB EC11B,Scan12 ;如果为0(低电平)就转移，编码器有旋转动作，逆时针反转
CLR BMQDZ ;没有旋转动作，把“编码器动作”置为0
RET
Scan11:
SETB XZFX ;顺时针正转，把“旋转方向”置为1
SETB BMQDZ ;有旋转动作，把“编码器动作”置为1
LCALL SETPWM ;有动作就重新放置“延时PWM驱动”时间
RET
Scan12:
CLR XZFX ;逆时针反转，把“旋转方向”置为0
SETB BMQDZ ;有旋转动作，把“编码器动作”置为1
LCALL SETPWM ;有动作就重新放置“延时PWM驱动”时间
RET
;-------------------------------------------------------------
;子程序：扫描编码器是否有旋转动作，不设置方向标志
;出口参数：“编码器动作”BMQDZ=1已经转动，=0没有转动
;-------------------------------------------------------------
Scan2:
SETB EC11A ;拉高编码器A引脚电平
SETB EC11B ;拉高编码器B引脚电平
JNB EC11A,Scan21 ;如果为0(低电平)就转移，编码器有旋转动作
JNB EC11B,Scan21 ;如果为0(低电平)就转移，编码器有旋转动作
CLR BMQDZ ;没有旋转动作，把“编码器动作”置为0
RET
Scan21:
SETB BMQDZ ;有旋转动作，把“编码器动作”置为1
LCALL SETPWM ;有动作就重新放置“延时PWM驱动”时间
RET
;--------------------------------------------------------------
;子程序：继电器控制，T0中断、EEPROM操作子程序调用
;--------------------------------------------------------------
Control:
JNB EEPBC,CTL00 ;EEPBC标志为0就转移。为1表示EEPROM操作子程序正在调用下面的继电器控制程序
RET
CTL00:
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JNZ CTL02 ;不是0就转移
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JNZ CTL02 ;不是0就转移
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ CTL02 ;不是0就转移
CTL01:
MOV P3,#0FFH ;置P3端口为高电平，断电
RET
CTL02:
JNB PWM,CTL03 ;PWM标志为0就转移。0=禁止PWM驱动，1=使用PWM方式驱动
MOV A,YSPWM ;装入“延时PWM驱动”，为0时使用PWM驱动方式
JNZ CTL03 ;不是0就转移
JB PWMBZ,CTL01 ;“PWM电平状态标志”为1(高电平)就转移。PWM周期25微秒*2=50微秒，20KHz占空比50%
CTL03:
JB FLQH,CTL05 ;“风类切换”为1自然风(睡眠风)就转移
MOV A,DANG ;装入档位值
CTL04:
PUSH DPL
PUSH DPH
MOV DPTR,#DAB1 ;档位控制码地址
DEC A ;档位值减1后为正确地址
MOVC A,@A+DPTR ;装入档位控制码
MOV P3,A ;置P3口控制继电器
POP DPH
POP DPL
RET
CTL05:
MOV A,SMFJG2 ;装入自然风(睡眠风)档位变化时的间隔时间(秒)
JZ CTL06 ;是0就转移
MOV A,DANGW ;装入自然风当前档位
LJMP CTL04
CTL06:
MOV SMFJG2,SMFJG ;重新放入设置的档位变化间隔时间
LCALL SETPWM ;设置“延时PWM驱动”时间
MOV A,DANGW ;装入当前档位值
JNB TSFX,CTL09 ;如果“调速方向”为0（渐慢降档）就转移
CJNE A,DANG_G,CTL07 ;当前档位值是否等于或大于设置的最高上限
CTL07:
JC CTL08 ;小于就转移
MOV A,DANG_G ;等于或大于，装入最高上限
CLR TSFX ;“调速方向”改为0（渐慢降档）
LJMP CTL09
CTL08:
INC A ;增1档
MOV DANGW,A
LJMP CTL04
CTL09:
CJNE A,DANG_D,CTL10 ;当前档位值不是设置的最低下限就转移
SETB TSFX ;是，“调速方向”改为1（渐快增档）
LJMP CTL04
CTL10:
JC CTL13 ;小于就转移
CJNE A,DANG_G,CTL11 ;是否大于设置的最高上限
CTL11:
JC CTL12 ;小于就转移
MOV A,DANG_G ;等于或大于，装入最高上限
CTL12:
DEC A ;减1档
MOV DANGW,A
LJMP CTL04
CTL13:
MOV A,DANG_D ;小于最低下限，装入最低下限
MOV DANGW,A
LJMP CTL04
;--------------------------------------------------------------
;子程序：T1中断调用，时间计数及倒计时处理。10毫秒执行一次
;--------------------------------------------------------------
TIME:
MOV A,YSPWM ;延时PWM驱动
JZ TIME0
DEC YSPWM ;每10毫秒减1，直到为0
TIME0:
MOV A,FENGMQ ;蜂鸣器鸣响时长
JZ TIME1
DEC FENGMQ ;每10毫秒减1，直到为0
TIME1:
MOV A,SHMJS ;装入(10)毫秒计数
JZ TIME2 ;如果是0就转移
DEC SHMJS ;每10毫秒减1，直到为0
TIME2:
MOV A,HWJS ;每10毫秒减1，为0时清除“接收到的红外遥控数据码”
JZ TIME3 ;是0就转移
DEC HWJS ;减1
LJMP TIME4
TIME3:
MOV MA1,FWBZ1 ;用“复位及EEPROM判断标志”填充“接收到的红外遥控数据码”
MOV MA2,FWBZ2 ;用“复位及EEPROM判断标志”填充“接收到的红外遥控数据码”
TIME4:
MOV A,HMJS ;装入(10)毫秒计数2
JZ TIME6 ;如果是0就转移
DEC HMJS ;不是0，减1
CJNE A,#50,TIME5 ;如果不是50就转移退出
SETB SSBZ ;“闪烁标志”置为1，数字及冒号闪烁时用，每0.5秒变化一次
TIME5:
RET
TIME6:
CLR SSBZ ;“闪烁标志”置为0，数字及冒号闪烁时用，每0.5秒变化一次
MOV HMJS,#99 ;重新放入计数值（1秒）
MOV A,SMFJG2 ;装入运行时使用的“睡眠风(自然风)档位变化时的间隔时间(秒)”
JZ TIME7 ;如果是0就转移
DEC SMFJG2 ;每秒减1，直到为0
TIME7:
MOV A,MJS ;秒计数
JZ TIME8 ;如果是0就转移
DEC MJS ;每秒减1，直到为0
TIME8:
MOV A,FWBZ0 ;装入复位提示(闪烁显示)秒计数
JZ TIME9 ;如果是0就转移
DEC FWBZ0 ;每秒减1，直到为0
TIME9:
MOV A,DSDW ;装入定时与档位交替显示的间隔时间(秒)
JNZ TIME10 ;如果不是0就转移
MOV DSDW,DSDWJG ;重新放入设置值
CPL XSNRXZ ;“显示内容选择”取反，交替显示
TIME10:
DEC DSDW ;每秒减1，直到为0
MOV A,DSSJM ;装入定时时间(秒)到寄存器A
JZ TIME11 ;如果是0就转移
DEC DSSJM ;减1秒
RET
TIME11:
MOV A,DSSJF ;装入定时时间(分)到寄存器A
JZ TIME12 ;如果是0就转移
DEC DSSJF ;不是0，减1分
MOV DSSJM,#59 ;把59放入定时时间(秒)
RET
TIME12:
MOV A,DSSJS ;装入定时时间(时)到寄存器A
JNZ TIME13 ;不是0就转移
CLR XSNRXZ ;定时结束，“显示内容选择”置为0，不显示档位
RET
TIME13:
DEC DSSJS ;不是0，小时减1
MOV DSSJM,#59 ;把59放入定时时间(秒)
MOV DSSJF,#59 ;把59放入定时时间(分)
RET
;---------------------------------------------------------------------------
;子程序：T1中断调用，显示定时时间及档位、红外遥控解码等。10毫秒执行一次
;---------------------------------------------------------------------------
DISPLAY:
JB XSKG,DPYSZ1 ;如果“显示开关”为1(禁止T1显示功能)就转移，退出
JNB XSQHY,DPYSZ0 ;如果“显示切换1”为0(显示定时或档位)就转移
LJMP DSZ
DPYSZ0:
JB FLQH,DISPL0 ;如果“风类切换”为1睡眠风(自然风)就转移，显示定时时间
JNB XSNRXZ,DISPL0 ;如果“显示内容选择”为0(显示定时时间)就转移
MOV A,DANG ;显示档位，装入档位值
CJNE A,XSHC1,DPYSZ3 ;当前档位值与缓存1不相同就转移，立即显示
MOV A,HMJS ;相同，装入(10)毫秒计数2
CJNE A,#99,DPYSZ2 ;不是99就转移，每0.5秒显示一次
LJMP DPYSZ3 ;是，显示
DPYSZ1: RET
DPYSZ2:
CJNE A,#49,DPYSZ1 ;不是49就转移退出，每0.5秒显示一次
DPYSZ3:
MOV XSHC1,DANG ;当前档位值放入缓存1
MOV ZXM1,#0 ;放入消隐码到待发送TM1637区1
MOV ZXM4,#0 ;放入消隐码到待发送TM1637区4
MOV R0,#ZXM2 ;装入待发送TM1637区2地址
MOV A,DANG ;装入档位值
LCALL BCD ;转换并获取字形码放到待发送TM1637区2和3
LCALL disp ;发送4个字节数据到TM1637显示
RET
;--------------------------------
DISPL0:
CLR XSNRXZ ;“显示内容选择”置为0，显示定时时间
MOV R1,#DSSJS ;把定时时间“时”的地址放入R1
MOV A,@R1 ;装入“时”
JZ DISPL1 ;如果“时”为0就转移
LJMP DISPL3
DISPL1:
CLR SSBZ ;“时”为0，把“闪烁标志”置为0，始终显示冒号
INC R1 ;地址加1，指向“分”
MOV A,@R1 ;装入“分”
DISPL3:
CJNE A,XSHC1,DISPL6 ;寄存器A的数据与显示缓存1不相同就转移，立即显示
INC R1 ;地址加1
MOV A,@R1 ;装入下一个时间数值
DEC R1 ;地址减1
CJNE A,XSHC2,DISPL6 ;寄存器A的数据与显示缓存2不相同就转移，立即显示
MOV A,HMJS ;都相同，装入(10)毫秒时间计数2
CJNE A,#99,DISPL5 ;不是99就转移
LJMP DISPL6 ;是，显示（每0.5秒显示一次）
DISPL4: RET
DISPL5:
CJNE A,#49,DISPL4 ;不是49就转移退出，每0.5秒显示一次
DISPL6:
INC R1 ;地址加1
MOV A,@R1 ;装入后面一位时间数值
MOV XSHC2,A ;放入缓存2
DEC R1 ;地址减1
MOV A,@R1 ;装入前面一位时间数值
MOV XSHC1,A ;放入缓存1
MOV R0,#ZXM1 ;待发送TM1637区1地址
LCALL BCD ;转换并获取字形码放到待发送TM1637区1、2
INC R1 ;地址加1
MOV R0,#ZXM3 ;待发送TM1637区3地址
MOV A,@R1 ;装入后面一位时间数值
LCALL BCD ;转换并获取字形码放到待发送TM1637区3、4
JB SSBZ,DISPL8 ;如果“闪烁标志”为1就转移，不显示冒号
DISPL7:
ORL ZXM2,#10000000B ;把最高位置为1（最高位为1就显示冒号）
DISPL8:
LCALL disp ;发送4个字节数据到TM1637显示
RET
;--------------------------------
DSZ:
JNB XSQHE,DHW ;如果“显示切换2”为0(显示红外遥控信号解码)就转移
MOV A,ZRFJG ;装入当前要显示的项目号，1:档位下限；2=档位上限；3=档位变化的间隔时间(秒)
DEC A ;减1
JNZ DSZ1 ;不为0就转移
MOV A,DANG_D ;是1，显示档位下限
MOV ZXM1,#038H ;放入“L”到待发送TM1637区1
LJMP DSZ3
DSZ1:
DEC A ;减1
JNZ DSZ2 ;不为0就转移
MOV A,DANG_G ;是2，显示档位上限
MOV ZXM1,#076H ;放入“H”到待发送TM1637区1
LJMP DSZ3
DSZ2:
MOV A,SMFJG ;是3，显示档位变化的间隔时间(秒)
MOV ZXM1,#079H ;放入“E”到待发送TM1637区1
DSZ3:
MOV ZXM2,#040H ;放入“-”到待发送TM1637区2
MOV R0,#ZXM3 ;待发送TM1637区3地址
LCALL BCD ;转换并获取字形码放到待发送TM1637区2和3
LCALL disp ;显示
RET
;---------------------------------
DHW:
JB BMXSQH,DHW4 ;如果“编码显示切换”为1(显示数据码+反码)就转移
MOV A,XMBH ;装入功能编号
CJNE A,XSHC1,DHW3 ;与显示缓存1不相同就转移，立即显示
MOV A,HMJS ;相同，装入(10)毫秒计数
CJNE A,#99,DHW2 ;不是99就转移，每0.5秒显示一次
LJMP DHW3 ;是，显示
DHW1: RET
DHW2:
CJNE A,#49,DHW1 ;不是49就转移退出，每0.5秒显示一次
DHW3:
MOV XSHC1,XMBH ;功能编号放入缓存1
MOV R0,#ZXM1 ;显示功能编号+系统码，待发送TM1637区1
MOV A,XMBH ;装入功能编号
LCALL BCD1 ;获取字形码放到待发送TM1637区
MOV ZXM2,#040H ;放入“-”到待发送TM1637区2
MOV A,ANJZ ;装入系统码
MOV R0,#ZXM3 ;待发送TM1637区3
LCALL HEX ;显示十六进制系统码
LCALL disp ;显示十六进制系统码
RET
DHW4:
MOV A,XMBH ;装入功能编号
MOV B,#2 ;功能编号乘2
MUL AB ;功能编号乘2
DEC A ;计算结果减1
ADD A,#ANJZ ;加遥控按键值首地址，得出数据码的实际地址
MOV R1,A ;地址放入R1
MOV A,@R1 ;装入数据码
CJNE A,XSHC1,DHW7 ;与显示缓存1不相同就转移，立即显示
INC R1 ;地址加1
MOV A,@R1 ;装入装入数据码反码
DEC R1 ;地址减1
CJNE A,XSHC2,DHW7 ;与显示缓存2不相同就转移，立即显示
MOV A,HMJS ;都相同，装入(10)毫秒时间计数
CJNE A,#99,DHW6 ;不是99就转移
LJMP DHW7 ;是，显示（每0.5秒显示一次）
DHW5: RET
DHW6:
CJNE A,#49,DHW5 ;不是49就转移退出，每0.5秒显示一次
DHW7:
INC R1 ;地址加1
MOV A,@R1 ;装入数据码反码
MOV XSHC2,A ;放入缓存2
DEC R1 ;地址减1
MOV A,@R1 ;装入数据码码
MOV XSHC1,A ;放入缓存1
MOV R0,#ZXM1 ;待发送TM1637区1
LCALL HEX ;查表获取字形码
MOV A,@R1 ;装入数据码反码
LCALL HEX ;查表获取字形码
LCALL disp ;显示
RET
;---------------------------------
HEX:
PUSH ACC
SWAP A ;高低半字节交换
ANL A,#0FH ;逻辑与运算
LCALL BCD1 ;查表获取字形码放到待发送TM1637区
INC R0 ;地址加1
POP ACC
ANL A,#0FH ;逻辑与运算
LCALL BCD1 ;查表获取字形码放到待发送TM1637区
INC R0 ;地址加1
INC R1 ;地址加1
RET
;---------------------------------
BCD:
MOV B,#10 ;转换为BCD码
DIV AB ;转换为BCD码
PUSH DPL
PUSH DPH
MOV DPTR,#SEGTAB ;查表获取字形码
MOVC A,@A+DPTR ;查表获取字形码
POP DPH
POP DPL
MOV @R0,A ;字形码放入待发送TM1637区
INC R0 ;地址加1
XCH A,B ;A、B寄存器内容交换
BCD1:
PUSH DPL
PUSH DPH
MOV DPTR,#SEGTAB ;查表获取字形码
MOVC A,@A+DPTR ;查表获取字形码
POP DPH
POP DPL
MOV @R0,A ;字形码放入待发送TM1637区
RET
;************** 关闭T1中断的显示功能，显示“----”**************
HENGX:
SETB XSKG ;“显示开关”置为1，关闭T1中断的显示功能
MOV ZXM1,#40H ;显示“----”
MOV ZXM2,#40H
MOV ZXM3,#40H ;显示“----”
MOV ZXM4,#40H
LJMP disp0
;---------- 发送4个字节数据到TM1637显示，地址自动加1 ----------
disp:
MOV A,FWBZ0 ;装入复位提示(闪烁显示)秒计数
JZ disp0 ;如果是0(未发生复位)就转移
JNB SSBZ,disp0 ;已经发生复位，“闪烁标志”为0(闪烁显示中的“显示”状态)就转移
CLR A ;处于闪烁显示中的“不显示”状态，放入消隐码（0）
MOV ZXM1,A ;放入消隐码
MOV ZXM2,A ;放入消隐码
MOV ZXM3,A ;放入消隐码
MOV ZXM4,A ;放入消隐码
disp0:
LCALL Srt
MOV A,#040H ;数据命令设置40H：地址自动加1，写数据到显示寄存器
LCALL Writebyte ;发送一个字节
LCALL Stop
NOP
LCALL Srt
MOV A,#0C0H ;地址命令设置C0H：初始地址为00H
LCALL Writebyte ;发送一个字节
MOV R6,#4 ;发送4个字节数据
MOV R1,#ZXM1 ;等待发送的字形码始址
disp1:
MOV A,@R1 ;装入要发送的字形码
LCALL Writebyte ;发送一个字节
INC R1 ;地址加1
DJNZ R6,disp1 ;如果还未发送完就继续
LCALL Stop
LCALL Srt
MOV A,SMGLD ;装入设置的数码管亮度(1~8)
ADD A,#087H ;加上87H后即为对应的亮度控制命令88H~8FH
LCALL Writebyte ;按设置的亮度开显示
LCALL Stop
RET
;----- 发送8bit(一个字节)数据到TM1637，A=要发送的数据，从低位开始 -----
Writebyte:
MOV R7,#8 ;发送8位数据
WBY1:
CLR CLK ;拉低CLK
JNB ACC.0,WBY2 ;A寄存器的低位（0位）如果为0就转移
SETB DIO ;为1，拉高DIO
SJMP WBY3
WBY2:
CLR DIO ;为0，拉低DIO
WBY3:
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
SETB CLK ;拉高CLK
CLR C ;进位标志清0
RRC A ;A寄存器内容带进位循环右移
DJNZ R7,WBY1 ;如果还未发送完8bit数据就继续
CLR CLK ;8位数据发送完了
MOV R7,#20 ;设置等待应答信号延时计数
WBY5:
JNB DIO,WBY6 ;判断TM1637发过来的ACK应答信号，应答就转移(0，低电平)
DJNZ R7,WBY5 ;
WBY6:
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
SETB CLK ;拉高CLK
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
RET
;------------------ Start子程序 ------------------
Srt:
SETB DIO ;拉高DIO
SETB CLK ;拉高CLK
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
SETB DIO ;拉高DIO
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
CLR DIO ;拉低DIO
MOV R4,#13 ;延时
DJNZ R4,$ ;延时
CLR CLK ;拉低CLK
RET
;------------------ Stop子程序 ------------------
Stop:
CLR CLK
MOV R4,#30
DJNZ R4,$
CLR DIO
MOV R4,#30
DJNZ R4,$
SETB CLK
MOV R4,#40
DJNZ R4,$
SETB DIO
MOV R4,#30
DJNZ R4,$
CLR CLK
CLR DIO
RET
;********************** 以下为EEPROM操作子程序 **********************
;STC8G1K08有4K的EEPROM，共8个扇区，
;第1扇区：0000H~01FFH；第2扇区：0200H~03FFH……
;----------------------------------------------------
;
;------- 读EEPROM保存的各项设置，如果没有就保存当前的设置值 ---------
REEP:
LCALL RE00 ;读EEPROM
JNC WEEP ;无数据(C=0)就转移，保存当前的设置值
RET
WEEP:
LCALL BCJDQ ;全功率驱动继电器保持至EEPROM操作结束，防止PWM驱动方式时可能断开无法吸合
MOV IAP_ADDRH,#00H ;第一个扇区地址的高8位
MOV IAP_ADDRL,#00H ;第一个扇区地址的低8位
LCALL Sector_Erase ;擦除整个扇区
MOV R1,#FWBZ1 ;首地址
MOV R2,#30 ;共写入20个字节
WEEP1:
MOV A,@R1 ;装入R1指向的RAM地址的内容到A
LCALL Byte_Program ;写入EEPROM
INC IAP_ADDRL ;EEPROM地址加1
INC R1 ;RAM地址增1
DJNZ R2,WEEP1 ;未保存完就转移继续
MOV IAP_ADDRL,#0 ;保存完了，扇区地址低位指向0(当前扇区首址)
LCALL Byte_Read ;读出来检查看是否写入成功
CJNE A,FWBZ1,WEEP3 ;如果与EEPROM数据判断标志1不相同就转移
INC IAP_ADDRL ;EEPROM地址加1
LCALL Byte_Read ;读第二个字节
CJNE A,FWBZ2,WEEP3 ;如果与EEPROM数据判断标志2不相同就转移
RET ;成功了，退出
WEEP3:
SETB XSKG ;“显示开关”置为1，关闭T1中断的显示功能
MOV MJS,#5 ;显示5秒E1
MOV ZXM1,#0 ;消隐码
MOV ZXM2,#079H ;E
MOV ZXM3,#006H ;1
MOV ZXM4,#0 ;消隐码
LCALL DISP ;显示
WEEP4:
MOV A,MJS
JNZ WEEP4 ;等待MJS为0秒
RET
;;---------- 读EEPROM保存的各项设置 ----------
RE00:
LCALL BCJDQ ;全功率驱动继电器保持至EEPROM操作结束，防止PWM驱动方式时可能断开无法吸合
MOV IAP_ADDRH,#00H ;第一个扇区地址的高8位
MOV IAP_ADDRL,#00H ;第一个扇区地址的低8位
LCALL Byte_Read ;读第一个字节，返回：A=读出的数据
CJNE A,FWBZ1,RE02 ;如果不是原来保存的数据就转移
INC IAP_ADDRL ;EEPROM字节地址增1
LCALL Byte_Read ;读第二个字节
CJNE A,FWBZ2,RE02 ;如果不是原来保存的数据就转移
MOV R1,#FWBZ2 ;从FWBZ2+1处开始放置读出的设置值
MOV R2,#28 ;再读出28个字节
RE01:
INC R1 ;RAM地址增1
INC IAP_ADDRL ;EEPROM字节地址增1
LCALL Byte_Read ;读一个字节，返回：A=读出的数据
MOV @R1,A ;放到R1指向的RAM地址
DJNZ R2,RE01 ;未读完就继续
SETB C ;把C置为1，读取成功
RET
RE02:
CLR C ;把C置为0，没有数据
RET
;-------------------------------
;EEPROM操作需要数毫秒以上，期间MCU会暂停，PWM停止。
;全功率驱动使继电器保持吸合状态至EEPROM操作结束，防止PWM驱动方式时可能断开无法吸合
BCJDQ:
LCALL SETPWM ;设置“延时PWM驱动”时间
SETB EEPBC ;“EEPROM操作子程序调用”标志置为1，使T0中断暂停执行继电器控制程序
LCALL CTL00 ;控制继电器
CLR EEPBC ;标志置为0
RET
;-------------------------------
;读一个字节，A=读出的数据
Byte_Read:
MOV IAP_CONTR,#80H ;打开IAP功能
MOV IAP_TPS,#12 ;设置等待参数
MOV IAP_CMD,#01 ;设置IAP读命令
MOV IAP_TRIG,#05AH ;触发命令
MOV IAP_TRIG,#0A5H ;触发命令
NOP
MOV A,IAP_DATA ;读出的数据在IAP_DATA，送入累加器A
RET
;-------------------------------
;字节编程，A=需写入的数据
Byte_Program:
MOV IAP_CONTR,#80H ;打开IAP功能
MOV IAP_TPS,#12 ;设置等待参数
MOV IAP_CMD,#02 ;设置IAP写命令
MOV IAP_DATA,A ;要写入的数据先送进IAP_DATA寄存器
MOV IAP_TRIG,#05AH ;触发命令
MOV IAP_TRIG,#0A5H ;触发命令
RET
;-------------------------------
;擦除扇区
Sector_Erase:
MOV IAP_CONTR,#80H ;打开IAP功能
MOV IAP_TPS,#12 ;设置等待参数
MOV IAP_CMD,#03 ;设置IAP擦除命令
MOV IAP_TRIG,#05AH ;触发命令
MOV IAP_TRIG,#0A5H ;触发命令
RET
;************************* 以上为EEPROM操作子程序 ***************************
;
;1~15档控制码：
DAB1: DB 0FEH,0FDH,0FBH,0FAH,0F9H,0F8H,0F4H,0F2H,0F1H,0F0H,0E4H,0E2H,0E1H,0E0H,0DFH
;
;------------------ 字形表 ------------------
SEGTAB:
DB 00111111B ;0（3FH）
DB 00000110B ;1（06H）
DB 01011011B ;2（5BH）
DB 01001111B ;3（4FH）
DB 01100110B ;4（66H）
DB 01101101B ;5（6DH）
DB 01111101B ;6（7DH）
DB 00000111B ;7（07H）
DB 01111111B ;8（7FH）
DB 01101111B ;9（6FH）
DB 01110111B ;A（77H）
DB 01111100B ;B（7CH）
DB 00111001B ;C（39H）
DB 01011110B ;D（5EH）
DB 01111001B ;E（79H）
DB 01110001B ;F（71H）
;---------------------------------------------
END

复制代码