标题: 单片机电子时钟汇编语言程序(可调节时间)附Proteus文件 [打印本页]
作者: gfgFUKGUG    时间: 2023-1-20 14:38
标题: 单片机电子时钟汇编语言程序(可调节时间)附Proteus文件
采用的单片机是89C52，用了两个锁存器74HC573来接入数码管的位选和段码引脚。
部分源码：

Proteus工程图：（下面的4*4按钮、最上面的128*64LCD显示屏和左边的发光二极管非本次内容的必要部分，可以删除）
三个按钮分别对应的功能：按钮1：在”调节时“和”调节分“中间轮换
按钮2：时间数值+1
按钮3：时间数值 -1

仿真原理图如下（proteus仿真工程文件可到本帖附件中下载）


单片机汇编语言源程序如下:
  1. ORG  0000H
  2.         LJMP  MAIN
  3.                 ORG  000BH     
  4.                         LJMP  INTT0

  6. MAIN:                        
  7.                                 MOV  R0,#70H                ;70后面的12位地址清零
  8.                 MOV  R7,#0CH
  9. INIT:                          MOV  @R0,#00H
  10.                 INC  R0
  11.                 DJNZ  R7,INIT
  12.                                 
  13.                 MOV  72H,#0AH
  14.                 MOV  75H,#0AH
  15.                                 
  16.                 MOV  TMOD,#01H
  17.                 MOV  TL0,#00H
  18.                 MOV  TH0,#4CH                                
  19.                 SETB  EA
  20.                 SETB  ET0
  21.                 SETB  TR0
  22.                                 
  23. START1:                        LCALL  SCAN
  24.                                 LCALL  KEYSCAN
  25.                 SJMP  START1
  26.                                 
  27. ;延时1MS子程序
  28. DL1MS:                         MOV  R6,#14H                ;20*25*2us
  29. DL1:                        MOV  R7,#19H
  30. DL2:                        DJNZ  R7,DL2
  31.                                 DJNZ  R6,DL1
  32.                                 RET
  33. ;延时20MS子程序
  34. DL20MS:                        MOV A,R2
  35.                                 PUSH Acc
  36.                                 MOV R2,#40
  37.                         DLY:MOV R4,#250
  38.                                 DJNZ R4,$
  39.                                 DJNZ R2,DLY
  40.                                 POP Acc
  41.                                 MOV R2,A
  42.                                 RET
  43. ;数码管显示程序
  44. SCAN:                MOV  A,78H       ;时间存入显示缓冲区相应位置
  45.                 MOV  B,#0AH
  46.                 DIV  AB
  47.                 MOV  71H,A                ;秒
  48.                 MOV  70H,B
  49.                 MOV  A,79H
  50.                 MOV  B,#0AH
  51.                 DIV  AB
  52.                 MOV  74H,A                ;分
  53.                 MOV  73H,B
  54.                                 MOV  A,7AH
  55.                 MOV  B,#0AH
  56.                 DIV  AB
  57.                 MOV  77H,A                ;时
  58.                                 MOV  76H,B
  59.                                 
  60.                                 MOV  R1,#70H                     ;循环扫描显示
  61.                 MOV  R5,#7FH
  62.                 MOV  R3,#08H
  63.                                 
  64.                                 
  65. SCAN1:                         MOV  A,R5
  66.                 MOV  P0,A                ;位选信号
  67.                                 SETB P2.7
  68.                                 CLR  P2.7
  69.                 MOV  A,@R1
  70.                 MOV  DPTR,#TAB
  71.                 MOVC  A,@A+DPTR
  72.                                 
  73.                 MOV  P0,A
  74.                                 SETB P2.6
  75.                                 CLR  P2.6
  76.                                 LCALL  DL1MS

  78.                 INC R1
  79.                 MOV A,R5
  80.                 RR A
  81.                 MOV R5,A
  82.                 DJNZ  R3,SCAN1
  83.                                 
  84.                                 
  85.                 MOV  P0,#00H                ;消影
  86.                                 SETB P2.6
  87.                                 CLR  P2.6
  88.                                 
  89.                                 MOV  P0,#0FFH
  90.                                 SETB P2.7
  91.                                 CLR  P2.7
  92.                 RET
  93. TAB:DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH,40H                                 ;“0~9”，“-,_”的共阴极字段码
  94.         

  96. ;定时器/计数器T0中断服务程序
  97. INTT0:               PUSH  Acc
  98.                 PUSH  PSW
  99.                 CLR  ET0
  100.                 CLR  TR0
  101.                 MOV  TL0,#00H
  102.                 MOV  TH0,#4CH
  103.                 SETB  TR0
  104.                 INC  7BH
  105.                 MOV  A,7BH
  106.                 CJNE  A,#14H,OUTT0                ;20*50=1s
  107.                 MOV  7BH,#00H
  108.                 INC  78H
  109.                 MOV  A,78H
  110.                 CJNE  A,#3CH,OUTT0                ;1s*60=1min
  111.                 MOV  78H,#00H                        ;秒计数器清零
  112.                                 INC  79H                                ;分计数器+1
  113.                                 MOV  A,79H
  114.                 CJNE  A,#3CH,OUTT0
  115.                 MOV  79H,#00H
  116.                                 INC  7AH                                ;时计数器+1
  117.                                 MOV  A,7AH
  118.                 CJNE  A,#18H,OUTT0
  119.                 MOV  7AH,#00H                        ;计到24后时计数器清零
  120. OUTT0:               
  121.                                 SETB  ET0               
  122.                                 POP  PSW
  123.                                 POP  Acc
  124.                 RETI
  125.                                 
  126. ;按键处理程序
  127. KEYSCAN:                CLR  EA
  128.                 JNB  P2.0,KEYSCAN0
  129.                 JNB  P2.1,KEYSCAN1
  130.                 JNB  P2.2,KEYSCAN2
  131. KEYOUT:                        SETB  EA
  132.                                 RET
  133. KEYSCAN0:                LCALL  DL20MS
  134.                                 JB  P2.0,KEYOUT
  135. WAIT0:                        JNB  P2.0,WAIT0
  136.                 INC  7CH
  137.                 MOV  A,7CH
  138.                 CLR  ET0
  139.                 CLR  TR0
  140.                 CJNE  A,#03H,KEYOUT
  141.                 MOV  7CH,#00H
  142.                 SETB  ET0
  143.                 SETB  TR0
  144.                 SJMP  KEYOUT
  145. KEYSCAN1:                LCALL  DL20MS
  146.                                 JB  P2.1,KEYOUT
  147. WAIT1:                        JNB  P2.1,WAIT1
  148.                 MOV  A,7CH
  149.                 CJNE  A,#02H,KSCAN11
  150.                 INC  79H
  151.                                 MOV  A,79H
  152.                                 CJNE  A,#3CH,KEYOUT
  153.                 MOV  79H,#00
  154.                                 SJMP  KEYOUT
  155. KSCAN11:                INC  7AH
  156.                                 MOV  A,7AH
  157.                                 CJNE  A,#18H,KEYOUT
  158.                 MOV  7AH,#00
  159.                                 SJMP  KEYOUT
  160. KEYSCAN2:                LCALL  DL20MS
  161.                                 JB  P2.2,KEYOUT
  162. WAIT2:                        JNB  P2.2,WAIT2
  163.                 MOV  A,7CH
  164.                 CJNE  A,#02H,KSCAN21
  165.                 DEC  79H
  166.                                 MOV  A,79H
  167.                                 CJNE  A,#0FFH,KEYOUT
  168.                 MOV  79H,#3BH
  169.                                 SJMP  KEYOUT
  170. KSCAN21:                DEC  7AH
  171.                                 MOV  A,7AH
  172.                                 CJNE  A,#0FFH,KEYOUT
  173.                 MOV  7AH,#17H
  174.                                 SJMP  KEYOUT
  175. END  
复制代码

所有资料51hei附件下载:
Proteus仿真8.13和汇编程序.7z (64.52 KB, 下载次数: 32)




欢迎光临 (http://www.51hei.com/bbs/) Powered by Discuz! X3.1