【Arduino】168种传感器模块系列实验（158）---QMC5883L三轴罗盘

ID:937433 发表于 2021-6-14 18:13

very professionnel, thank you it's really useful

ID:418578 发表于 2021-3-18 16:18

准确度怎么样

ID:513258 发表于 2021-1-25 13:16

实验开源代码
项目四：通过串口实时绘制电子罗盘方位（12等分）的波形
说明：实时数值 0 = N，3 = E，6 = S，9 =W

/*
【Arduino】168种传感器模块系列实验（资料代码+图形编程+仿真编程）
实验一百五十八：QMC5883L电子指南针罗盘模块三轴磁场传感器GY-271
1、安装库：IDE--工具--管理库--搜索“QMC5883L”--安装QMC5883LCompass
2、项目四：通过串口实时绘制电子罗盘方位（12等分）的波形
3、实验接线：
QMC5883L-------------- UNO
VCC------------------- 5V
GND------------------- GND
SCL ------------------- A5
SDA------------------- A4
DRDY------------------ N/C
4、说明：实时数值 0 = N，3 = E，6 = S，9 =W
*/
#include <QMC5883LCompass.h>
QMC5883LCompass compass;
void setup() {
Serial.begin(9600);
compass.init();
}
void loop() {
compass.read();
byte a = compass.getAzimuth();
// 根据方位/方位角的方向，此处的输出将是介于0到11之间的值。
byte b = compass.getBearing(a);
Serial.print("指南针方位: ");
Serial.print(b);
Serial.println();
delay(800);
}

复制代码

ID:513258 发表于 2021-1-25 11:59

9、校准QMC5583L传感器
QMC5883LCompass库包含校准功能和实用程序大纲，可帮助您校准QMC5883L芯片。校准是一个两步过程。

步骤1：运行校准程序
a、确保已连接QMC5883L芯片。
b、在示例> QMC5883LCOMPASS>校准下找到随附的校准草图。
c、将校准草图上传到您的arduino，然后打开串行监视器。
d、校准过程开始时，通过移动传感器来伴随屏幕上的指示。
c、收集完所有校准数据后，复制副本的代码

compass.setCalibration(-1537, 1266, -1961, 958, -1342, 1492);

可能需要保存它以备将来参考。

步骤2：使用校正资料
a、项目的程序，将然后复制的代码行直接插入到compass.init()调用下方。
b、照常使用QMC5883LCompass库。

建议您使用提供的校准草图来生成传感器的预设和替代，但也可以使用该

compass.setCalibration(X_MIN, X_MAX, Y_MIN, Y_MAX, Z_MIN, Z_MAX);

函数添加自己的预设和替代。

ID:513258 发表于 2021-1-25 11:55

8、精细QMC5583L传感器输出
在传感器读数似乎反弹的情况下，平滑可以提供帮助。QMC5883L指南针库使用滚动平均值功能来存储（N）个传感器读数并返回每个轴的平均值。该平均还对方位角和方向输出进行平滑处理。

如果启用，该功能的第二部分将采用内部滚动逐步通过的当前替代和替代，将其从总体上中删除。这可以帮助消除在错误的读数中可能发生的替代的高点和低点。

应该注意的是，内置的平滑功能将导致额外的处理时间。

compass.setSmoothing(STEPS, ADVANCED);

在循环之前启用平滑调用。

步骤：int，使结果平滑的步骤数。1到10的有效值。更高的步长等于更平滑，但处理时间缩短。

*：启用此功能将使平滑效果更好，但处理时间缩短。*

void setup(){
compass.init();
compass.setSmoothing(10, true);
}

ID:513258 发表于 2021-1-25 11:11

4、获取方位角的数值
要获取计算出的方位角（罗盘度）值，只需调用getAzimuth();。
void loop(){
int a = compass.getAzimuth();
}
5、获取方向/方位
QMC5883L指南针库可计算传感器指向的方向范围和方向。您可以调用两个函数。
要获取传感器面向的方向的12点值，可以调用getBearing(azimuth)。这会将罗盘的360度范围划分为12个部分，并按顺时针顺序返回值0-12。在这种情况下，0 = N，4 = E，8 = S，12 =W。如果您希望滚动自己的方向输出功能而不需要计算，则此功能很有用。
void loop(){
azimuth = compass.getAzimuth();
byte b = compass.getBearing(azimuth);
}
要获取传感器指向方向的12点文字表示，可以致电getDirection(azimuth);。这将产生一个char数组[3]，其中的字母代表每个方向。由于我们无法返回数组，因此需要通过引用传递值。
void loop(){
azimuth = compass.getAzimuth();
char myArray[3];
getDirection(myArray, azimuth);
}
如果要打印这些值，可以这样：
void loop(){
azimuth = compass.getAzimuth();
char myArray[3];

getDirection(myArray, azimuth);

Serial.print(myArray[0]);
Serial.print(myArray[1]);
Serial.print(myArray[2]);
Serial.println();
}

ID:513258 发表于 2021-1-25 11:07

QMC5883L Compass库函数的几个使用要点

1、QMC5883L与Arduino Uno / Nano的连接

VCC  O ---- O +5v
GND  O ---- O GND
SCL  O ---- O A5
SDA  O ---- O A4
DRDY O ---- X NOT CONNECTED

2、入门
首先，在程序顶部包括QMC5883L指南针库。

#include <QMC5883LCompass.h>
QMC5883LCompass compass;

然后在setup（）函数中添加：

void setup(){
compass.init();
}

3、获取X，Y或Z轴的数值

要获取X，Y或Z传感器的读数，只需调用所需的功能。

void loop(){
int x = compass.getX();
int y = compass.getY();
int z = compass.getZ();
}

ID:513258 发表于 2021-1-25 10:12

实验开源代码，

项目三：通过串口实时绘制电子罗盘方位角的波形

/*
【Arduino】168种传感器模块系列实验（资料代码+图形编程+仿真编程）
实验一百五十八：QMC5883L电子指南针罗盘模块三轴磁场传感器GY-271
1、安装库：IDE--工具--管理库--搜索“QMC5883L”--安装QMC5883LCompass
2、项目三：通过串口实时绘制电子罗盘方位角的波形
3、实验接线：
QMC5883L-------------- UNO
VCC------------------- 5V
GND------------------- GND
SCL ------------------- A5
SDA------------------- A4
DRDY------------------ N/C
*/
#include <QMC5883LCompass.h>
QMC5883LCompass compass;
void setup() {
Serial.begin(9600);
compass.init();
}
void loop() {
int a;
// 读取罗盘值
compass.read();
// 返回方位角读数
a = compass.getAzimuth();
Serial.print("电子罗盘方位角: ");
Serial.print(a);
Serial.println();
delay(800);
}

复制代码

ID:513258 发表于 2021-1-24 21:07

QMC5883LCompass.h 库文件

#ifndef QMC5883L_Compass
#define QMC5883L_Compass
#include "Arduino.h"
#include "Wire.h"
class QMC5883LCompass{
public:
QMC5883LCompass();
void init();
void setADDR(byte b);
void setMode(byte mode, byte odr, byte rng, byte osr);
void setSmoothing(byte steps, bool adv);
void setCalibration(int x_min, int x_max, int y_min, int y_max, int z_min, int z_max);
void setReset();
void read();
int getX();
int getY();
int getZ();
int getAzimuth();
byte getBearing(int azimuth);
void getDirection(char* myArray, int azimuth);
private:
void _writeReg(byte reg,byte val);
int _get(int index);
bool _smoothUse = false;
byte _smoothSteps = 5;
bool _smoothAdvanced = false;
byte _ADDR = 0x0D;
int _vRaw[3] = {0,0,0};
int _vHistory[10][3];
int _vScan = 0;
long _vTotals[3] = {0,0,0};
int _vSmooth[3] = {0,0,0};
void _smoothing();
bool _calibrationUse = false;
int _vCalibration[3][2];
int _vCalibrated[3];
void _applyCalibration();
const char _bearings[16][3] = {
{' ', ' ', 'N'},
{'N', 'N', 'E'},
{' ', 'N', 'E'},
{'E', 'N', 'E'},
{' ', ' ', 'E'},
{'E', 'S', 'E'},
{' ', 'S', 'E'},
{'S', 'S', 'E'},
{' ', ' ', 'S'},
{'S', 'S', 'W'},
{' ', 'S', 'W'},
{'W', 'S', 'W'},
{' ', ' ', 'W'},
{'W', 'N', 'W'},
{' ', 'N', 'W'},
{'N', 'N', 'W'},
};
};
#endif

复制代码

ID:513258 发表于 2021-1-24 21:05

QMC5883L Compass是一个Arduino库，用于将QMC5583L系列模块使用指南针（电子罗盘）功能。支持：

1、获取XYZ轴的值。
2、计算方位角。
3、获得16点方位角轴承方向（0-15）。
4、获取16点方位角轴承名称（N，NNE，NE，ENE，E，ESE，SE，SSE，S，SSW，SW，WSW，W，WNW，NW，NNW）
5、通过滚动平均和最小/最大消除来平滑XYZ读数。
6、任选的芯片组模式。

QMC5883LCompass.cpp 库文件

/*
===============================================================================================================
QMC5883LCompass.h
Library for using QMC5583L series chip boards as a compass.
Learn more at [https://github.com/mprograms/QMC5883LCompass]
Supports:
- Getting values of XYZ axis.
- Calculating Azimuth.
- Getting 16 point Azimuth bearing direction (0 - 15).
- Getting 16 point Azimuth bearing Names (N, NNE, NE, ENE, E, ESE, SE, SSE, S, SSW, SW, WSW, W, WNW, NW, NNW)
- Smoothing of XYZ readings via rolling averaging and min / max removal.
- Optional chipset modes (see below)
===============================================================================================================
v1.0 - June 13, 2019
Written by MRPrograms
Github: [https://github.com/mprograms/]
Release under the GNU General Public License v3
[https://www.gnu.org/licenses/gpl-3.0.en.html]
===============================================================================================================
FROM QST QMC5883L Datasheet [https://nettigo.pl/attachments/440]
-----------------------------------------------
MODE CONTROL (MODE)
Standby 0x00
Continuous 0x01
OUTPUT DATA RATE (ODR)
10Hz 0x00
50Hz 0x04
100Hz 0x08
200Hz 0x0C
FULL SCALE (RNG)
2G 0x00
8G 0x10
OVER SAMPLE RATIO (OSR)
512 0x00
256 0x40
128 0x80
64 0xC0
*/
#include "Arduino.h"
#include "QMC5883LCompass.h"
#include <Wire.h>
QMC5883LCompass::QMC5883LCompass() {
}
/**
INIT
Initialize Chip - This needs to be called in the sketch setup() function.
@since v0.1;
**/
void QMC5883LCompass::init(){
Wire.begin();
_writeReg(0x0B,0x01);
setMode(0x01,0x0C,0x10,0X00);
}
/**
SET ADDRESS
Set the I2C Address of the chip. This needs to be called in the sketch setup() function.
@since v0.1;
**/
// Set I2C Address if different then default.
void QMC5883LCompass::setADDR(byte b){
_ADDR = b;
}
/**
REGISTER
Write the register to the chip.
@since v0.1;
**/
// Write register values to chip
void QMC5883LCompass::_writeReg(byte r, byte v){
Wire.beginTransmission(_ADDR);
Wire.write(r);
Wire.write(v);
Wire.endTransmission();
}
/**
CHIP MODE
Set the chip mode.
@since v0.1;
**/
// Set chip mode
void QMC5883LCompass::setMode(byte mode, byte odr, byte rng, byte osr){
_writeReg(0x09,mode|odr|rng|osr);
}
/**
RESET
Reset the chip.
@since v0.1;
**/
// Reset the chip
void QMC5883LCompass::setReset(){
_writeReg(0x0A,0x80);
}
// 1 = Basic 2 = Advanced
void QMC5883LCompass::setSmoothing(byte steps, bool adv){
_smoothUse = true;
_smoothSteps = ( steps > 10) ? 10 : steps;
_smoothAdvanced = (adv == true) ? true : false;
}
/**
SET CALIBRATION
Set calibration values for more accurate readings
@author Claus Näveke - TheNitek [https://github.com/TheNitek]
@since v1.1.0
**/
void QMC5883LCompass::setCalibration(int x_min, int x_max, int y_min, int y_max, int z_min, int z_max){
_calibrationUse = true;
_vCalibration[0][0] = x_min;
_vCalibration[0][1] = x_max;
_vCalibration[1][0] = y_min;
_vCalibration[1][1] = y_max;
_vCalibration[2][0] = z_min;
_vCalibration[2][1] = z_max;
}
/**
READ
Read the XYZ axis and save the values in an array.
@since v0.1;
**/
void QMC5883LCompass::read(){
Wire.beginTransmission(_ADDR);
Wire.write(0x00);
int err = Wire.endTransmission();
if (!err) {
Wire.requestFrom(_ADDR, (byte)6);
_vRaw[0] = (int)(int16_t)(Wire.read() | Wire.read() << 8);
_vRaw[1] = (int)(int16_t)(Wire.read() | Wire.read() << 8);
_vRaw[2] = (int)(int16_t)(Wire.read() | Wire.read() << 8);
if ( _calibrationUse ) {
_applyCalibration();
}
if ( _smoothUse ) {
_smoothing();
}
//byte overflow = Wire.read() & 0x02;
//return overflow << 2;
}
}
/**
APPLY CALIBRATION
This function uses the calibration data provided via @see setCalibration() to calculate more
accurate readings
@author Claus Näveke - TheNitek [https://github.com/TheNitek]
Based on this awesome article:
https://appelsiini.net/2018/calibrate-magnetometer/
@since v1.1.0
**/
void QMC5883LCompass::_applyCalibration(){
int x_offset = (_vCalibration[0][0] + _vCalibration[0][1])/2;
int y_offset = (_vCalibration[1][0] + _vCalibration[1][1])/2;
int z_offset = (_vCalibration[2][0] + _vCalibration[2][1])/2;
int x_avg_delta = (_vCalibration[0][1] - _vCalibration[0][0])/2;
int y_avg_delta = (_vCalibration[1][1] - _vCalibration[1][0])/2;
int z_avg_delta = (_vCalibration[2][1] - _vCalibration[2][0])/2;
int avg_delta = (x_avg_delta + y_avg_delta + z_avg_delta) / 3;
float x_scale = (float)avg_delta / x_avg_delta;
float y_scale = (float)avg_delta / y_avg_delta;
float z_scale = (float)avg_delta / z_avg_delta;
_vCalibrated[0] = (_vRaw[0] - x_offset) * x_scale;
_vCalibrated[1] = (_vRaw[1] - y_offset) * y_scale;
_vCalibrated[2] = (_vRaw[2] - z_offset) * z_scale;
}
/**
SMOOTH OUTPUT
This function smooths the output for the XYZ axis. Depending on the options set in
@see setSmoothing(), we can run multiple methods of smoothing the sensor readings.
First we store (n) samples of sensor readings for each axis and store them in a rolling array.
As each new sensor reading comes in we replace it with a new reading. Then we average the total
of all (n) readings.
Advanced Smoothing
If you turn advanced smoothing on, we will select the min and max values from our array
of (n) samples. We then subtract both the min and max from the total and average the total of all
(n - 2) readings.
NOTE: This function does several calculations and can cause your sketch to run slower.
@since v0.3;
**/
void QMC5883LCompass::_smoothing(){
byte max = 0;
byte min = 0;
if ( _vScan > _smoothSteps - 1 ) { _vScan = 0; }
for ( int i = 0; i < 3; i++ ) {
if ( _vTotals[i] != 0 ) {
_vTotals[i] = _vTotals[i] - _vHistory[_vScan][i];
}
_vHistory[_vScan][i] = ( _calibrationUse ) ? _vCalibrated[i] : _vRaw[i];
_vTotals[i] = _vTotals[i] + _vHistory[_vScan][i];
if ( _smoothAdvanced ) {
max = 0;
for (int j = 0; j < _smoothSteps - 1; j++) {
max = ( _vHistory[j][i] > _vHistory[max][i] ) ? j : max;
}
min = 0;
for (int k = 0; k < _smoothSteps - 1; k++) {
min = ( _vHistory[k][i] < _vHistory[min][i] ) ? k : min;
}
_vSmooth[i] = ( _vTotals[i] - (_vHistory[max][i] + _vHistory[min][i]) ) / (_smoothSteps - 2);
} else {
_vSmooth[i] = _vTotals[i] / _smoothSteps;
}
}
_vScan++;
}
/**
GET X AXIS
Read the X axis
@since v0.1;
@return int x axis
**/
int QMC5883LCompass::getX(){
return _get(0);
}
/**
GET Y AXIS
Read the Y axis
@since v0.1;
@return int y axis
**/
int QMC5883LCompass::getY(){
return _get(1);
}
/**
GET Z AXIS
Read the Z axis
@since v0.1;
@return int z axis
**/
int QMC5883LCompass::getZ(){
return _get(2);
}
/**
GET SENSOR AXIS READING
Get the smoothed, calibration, or raw data from a given sensor axis
@since v1.1.0
@return int sensor axis value
**/
int QMC5883LCompass::_get(int i){
if ( _smoothUse )
return _vSmooth[i];
if ( _calibrationUse )
return _vCalibrated[i];
return _vRaw[i];
}
/**
GET AZIMUTH
Calculate the azimuth (in degrees);
@since v0.1;
@return int azimuth
**/
int QMC5883LCompass::getAzimuth(){
int a = atan2( getY(), getX() ) * 180.0 / PI;
return a < 0 ? 360 + a : a;
}
/**
GET BEARING
Divide the 360 degree circle into 16 equal parts and then return the a value of 0-15
based on where the azimuth is currently pointing.
@since v1.0.1 - function now requires azimuth parameter.
@since v0.2.0 - initial creation
@return byte direction of bearing
*/
byte QMC5883LCompass::getBearing(int azimuth){
unsigned long a = azimuth / 22.5;
unsigned long r = a - (int)a;
byte sexdec = 0;
sexdec = ( r >= .5 ) ? ceil(a) : floor(a);
return sexdec;
}
/**
This will take the location of the azimuth as calculated in getBearing() and then
produce an array of chars as a text representation of the direction.
NOTE: This function does not return anything since it is not possible to return an array.
Values must be passed by reference back to your sketch.
Example:
( if direction is in 1 / NNE)
char myArray[3];
compass.getDirection(myArray, azimuth);
Serial.print(myArray[0]); // N
Serial.print(myArray[1]); // N
Serial.print(myArray[2]); // E
@see getBearing();
@since v1.0.1 - function now requires azimuth parameter.
@since v0.2.0 - initial creation
*/
void QMC5883LCompass::getDirection(char* myArray, int azimuth){
int d = getBearing(azimuth);
myArray[0] = _bearings[d][0];
myArray[1] = _bearings[d][1];
myArray[2] = _bearings[d][2];
}

复制代码

ID:513258 发表于 2021-1-24 20:14

项目二：简易测量方位角度的实验开源代码（数值在0-11之间，每个数值间隔30度）

/*
【Arduino】168种传感器模块系列实验（资料代码+图形编程+仿真编程）
实验一百五十八：QMC5883L电子指南针罗盘模块三轴磁场传感器GY-271
1、安装库：IDE--工具--管理库--搜索“QMC5883L”--安装QMC5883LCompass
2、项目二：简易测量方位角度（数值在0-11之间，每个数值间隔30度）
3、实验接线：
QMC5883L-------------- UNO
VCC------------------- 5V
GND------------------- GND
SCL ------------------- A5
SDA------------------- A4
DRDY------------------ N/C
*/
#include <QMC5883LCompass.h>
QMC5883LCompass compass;
void setup() {
Serial.begin(9600);
compass.init();
}
void loop() {
compass.read();
byte a = compass.getAzimuth();
// 根据方位/方位角的方向，此处的输出将是介于0到11之间的值。
byte b = compass.getBearing(a);
Serial.print("B: ");
Serial.print(b);
Serial.println();
delay(250);
}

复制代码

ID:513258 发表于 2021-1-24 19:05

项目一：简易测量方位角度的实验开源代码

/*
【Arduino】168种传感器模块系列实验（资料代码+图形编程+仿真编程）
实验一百五十八：QMC5883L电子指南针罗盘模块三轴磁场传感器GY-271
1、安装库：IDE--工具--管理库--搜索“QMC5883L”--安装QMC5883LCompass
2、项目一：简易测量方位角度
3、实验接线：
QMC5883L-------------- UNO
VCC------------------- 5V
GND------------------- GND
SCL ------------------- A5
SDA------------------- A4
DRDY------------------ N/C
*/
#include <QMC5883LCompass.h>
QMC5883LCompass compass;
void setup() {
Serial.begin(9600);
compass.init();
}
void loop() {
int a;
// 读取罗盘值
compass.read();
// 返回方位角读数
a = compass.getAzimuth();
Serial.print("A: ");
Serial.print(a);
Serial.println();
delay(500);
}

复制代码

帐号		自动登录	找回密码
密码			立即注册

【Arduino】168种传感器模块系列实验（158）---QMC5883L三轴罗盘

正文摘要:

回复