设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › 单片机DIY制作 › 我制作的电动车充电保护器 含单片机源码与电路原理图
返回列表 发新帖
查看: 14027|回复: 9
收起左侧

我制作的电动车充电保护器 含单片机源码与电路原理图

  [复制链接]
ID:286600 发表于 2018-3-2 10:08 | 显示全部楼层 |阅读模式
下面是此电瓶车充电保护器作品的外观图：
IMG_20180301_095151.jpg
这是一个电瓶车充电器的附加装置，不对充电器做任何变动，而是将充电器插在该保护器上连成一体代替原充电器进行电瓶车的充电。
功能：1、充电达到设定的电压，自动断电停充，防过充。
      2、满十小时自动停充电，电瓶有故障充不到设定电压，经十小时也停充。
      3、能根据气温设定充电电压档次，能记忆设定的档次，无须每次设定。
      4、用二进制数循环显示电压的十位个位小数位值。
用法：将充电器插在该保护器上连成一体，代替原充电器进行电瓶车的充电。插上220V交流后在15秒内左右慢摇保护器，使内置水银开关接通又断开（按键作用），温度档次依次增加，共分1~8档，对应环境温度是5℃－40℃。水银开关断开15秒后进入充电程序，水银开关不再起作用。
       充足电的断充电指示可从原充电器指示灯看出，不另加指示灯。
读电压：显示过程是－－四灯全亮（提示开始）、灭、十位、灭、个位、灭、小数一位、灭，循环不断。用四位二进制数表示0到9，读出数不难，记得四灯分别代表8、4、2、1，将亮灯的数相加就是了。0也显示为灭，可从时间上判别出来。
例：54.9显示为
       ○○○○  开始
　　●○●○  5
       ●○●●  4
       ○●●○  9
为省事没用数码管，自己用的东西，简单实用为好。四个发光管也合用一个限流电阻，单片机复位用的电容电阻也省了，晶振也省了。

工作原理：用手机充电器拆来的电路板为装置提供5V电源。单片机AD转换测电压，每15秒进行一次。测得的电压与设定的终止电压比较，达到了就给继电器模块送一信号，收到信号继电器就断开充电器电源。单片机同时计时，满十时也发出停充电信号，满十天自动重启单片机进行充电管理（暑假长时间人不在家也没问题了）。
    为避免单片机工作电压变动对电压测量的影响，用TL431提供一个基准电压，P1.1对其进行AD转换。电瓶电压1/15分压后用P1.0进行AD转换，然后用下式算出电瓶电压。
         十五分之一电瓶电压:基准电压＝电瓶AD值:基准电压的AD值
实测TL431稳压后是2.524伏，程序中采用的具体算法是：
      电瓶电压伏特数＝(电瓶AD值×37+电瓶AD值×86÷100）÷基准电压AD值   
被除数是两个8位，除数是一个8位，我是用循环做减法的办法来求商。具体见源码。
      分压电阻的调整，借助万用表反复细心调精密可调电阻，使阻值之比为14:1。
材料：单片机STC12C5204AD  继电器模块，手机充电器，交流插座等。

电路原理图：

单片机电路图

单片机电路图

接线示意图：

组装接线示意图

组装接线示意图

制作过程：

装饰边角料做的外壳

装饰边角料做的外壳 IMG_2.jpg

拆解手机充电器

拆解手机充电器

继电器模块

继电器模块 IMG_5.jpg IMG_6.jpg IMG_7.jpg IMG_9.jpg

单片机正面

单片机正面

单片机背面

单片机背面

组装好

组装好 IMG_20180301_095125.jpg

单片机编程源码如下:
  1.                                                                  ;1/15取样，单片机工作电压约5V，能测电压达75V。
  2. ;改成最多充电10小时。十天后重启。
  3. ;使用EEPROM保存温度档。                                                                                                                                                                                                ;2016年7月6日修改：
  4. ;使用汞开关设定温度档，使用EEPROM保存温度档。
  5. ;开机16秒内（大约）按键设定温度档数，若不按键，则默认上次的档数。有1，2，3，4，5，6，7，8共八档。
  6. ;设温度档后接通220V
  7. ;从温度5度起为第1档，10度为第2档，15度为第3档，……35度为第7档，40度为第8 档，0档同第8档。停下不按键约15秒自动进入下一环节。

  9. ;显示电瓶伏特数，按四灯亮、黑、十位、黑、个位、黑、小数位、黑，循环显示。四灯亮和黑是半秒，数字是1秒
  10. ;20H.0设置温度档[WENDU]子程序控制位，初值赋1，在等待按键的子程序[xunhuan]中清0.仅在开机初用一次。
  11. ;20H.2 显示控制位.走时置1，显示后清0，使得半秒进行一次显示。
  12. ;20H.3 秒标志
  13. ;21H.0
  14. ;21H.2 [Tuoliu]程序控制位，使程序只运行一次。
  15. ;21H.3
  16. ;21H.4是电瓶正常标志，初值赋1（正常），检测到电瓶充满或不正常将其清0，清0后要重启才能置1.
  17. ;21H.6充电10小时标志，初值为1，充电达10小时将其清0.清0后要重启才能置1.
  18. ;22H.0 走时用的20ms标志，在中断置1，走时中清0。
  19. ;22H.3 时标志
  20. ;22H.5 每15秒运行一次的标志位，走时置1.
  21. ;22H.7
  22. ;用检测到的电压AD值与设定的终止电压AD值进行比较，确定电瓶满或不正常（电压太低或无电瓶）关断220V供电。
  23. ;开机接通220V，电瓶充满（或不正常）关断，充电10小时关断，十天后单片机重启。

  25. ;P1.0--A/D转换
  26. ;P1.1--A/D转换测TL431电压
  27. ;P1.2--键，每按一次温度档数加1，在0－－8之中循环，停下不按键约15秒自动进入下一环节。
  28. ;P1.7,P1.6,P1.5,P1.4接LED做温度档显示，点亮分别表示8,4，2，1，二进制数。
  29. ;P3.2--通过光耦控制220V通断 0－通  1－断
  30. ;***************

  32. ;***
  33. U_zhongzhixiao  EQU 5EH  ;终止电压小数寄存器
  34. U_zhongzhizheng EQU 5FH  ;终止电压整数寄存器
  35. JSHQ_WEI EQU 65H        ;显示第几位计数器
  36. XUN_JSHQ EQU 67H        ;循环次数
  37. wendudang  EQU  68H     ;温度档数
  38. v_ZH   EQU 5DH         ;电瓶伏特整数寄存器
  39. V_XAO  EQU 5CH         ;电瓶伏特小数寄存器
  40. TL431_AD   EQU  5BH     ;TL431的AD值
  41. TL431_AD1  EQU  5AH     ;TL431的AD值(第一次）
  42. jiace_adzhi1 EQU 58H    ;第一次检测到的AD值
  43. ;xiu_adzhi  EQU  6CH     ;(修)终止电压AD值
  44. Jiace_ADzhi EQU 59H     ;检测AD值  检测到的AD值
  45. JSHQ_15   EQU  6EH      ;15秒计数器
  46. JSHQ_20mS  EQU  70H     ;20mS计数器  计20mS的个数
  47. JSHQ_S     EQU  71H     ;半秒计数器
  48. JSHQ_M     EQU  72H     ;分计数器
  49. JSHQ_H     EQU  73H     ;时计数器
  50. ;60H,61H,62H,63H,64H 用在显缓中
  51. beichushugao  equ  75h     ;被除数高位
  52. beichushudi  EQU  76H    ;被除数低位
  53. chushu     EQU  77H     ;除数
  54. zhengshang  EQU 78H     ;整数商
  55. XIAOSHUSHANG  EQU 79H    ;小数商
  56. YUSHU      EQU  7AH     ;余数
  57. LSSHU     EQU  7BH     ;临时存
  58. DISHU  EQU 7CH         ;低数 第二次的被除数的低位
  59. GAOSHU  EQU 7DH        ;高数 第二次的被除数的高位

  61. ADC_CONTR EQU 0BCH     ;ADC控制寄存器
  62. ADC_RES   EQU 0BDH     ;A/D转换结果寄存器
  63. P1ASF  EQU 09DH       ;p1口模拟功能控制寄存器
  64. WDT_CONTR EQU 0C1H    ;看门狗
  65. ;AUXR DATA 8EH         ;选择1T与12T的寄存器

  67. IAP_CONTR EQU 0C7H      ;下载/复位控制器

  69. jian  EQU  p1.2         ;鍵
  70. kong  EQU  p3.2         ;控 220V   0－通  1－断
  71. p1m1  equ  91h
  72. p1m0  equ  92h
  73. ;EEPROM有关的寄存器
  74. dat       equ     0C2H               
  75. drh       equ     0C3H               
  76. drl       equ     0C4H                  
  77. cmd       equ     0C5H               
  78. trig      equ     0C6H               
  79. contr     equ     0C7H
  80. ;****************

  82.         ORG   0000H
  83.         AJMP  START
  84.         ORG          000BH
  85.         LJMP  TIME_0
  86. ;        ORG   001BH

  88.         ORG   0030H
  89. START:
  90. ;其它初始化写在此     
  91.    MOV P1M1,#00000011B
  92.    MOV P1M0,#00000000B    ;P1.0 P1.1两个高阻输入做AD     
  93.    MOV P1,#00001111B
  94.     setb kong          ;断220V交流 设温度档后接通

  96.         MOV 22H,#00100000B    ;检测标志 1－检 0－不检 每15秒检测AD一次和处理显缓一次的标志位，走时置1，处理显缓后清0
  97.         MOV 21H,#01010000B   ;21h.4 电瓶 1－能充  0－不能充电（含无、充满）  
  98.                                ;21H.6  初值1，充电10小时清0 。

  100. ;*用计数器0  初步设置定时中断    20MS中断  20毫秒@10.911MHz
  101.     MOV SP,#80H                     ;设置堆栈区域
  102. ;           ANL AUXR,#7FH                ;定时器时钟12T模式  默认是12T模式 省略本句
  103.         MOV        TMOD,#00010001B         ;定时器0定时器1都是 16位
  104.         MOV        TL0,#0F7H
  105.         MOV        TH0,#0B8H               

  107.         SETB EA
  108.         SETB        ET0
  109.         SETB        TR0              ;开放中断
  110.         
  111.         setb 20h.0          ;控制设置温度档程序的循环用
  112. ;*****************
  113. ;设置温度档   从EEPROM中读出保存值，一段时间内不按键，则使用该档值；如按键则改之，停下不动，过会儿保存并启用。
  114.      LCALL  DOUEEPROM    ;读EEPROM中的保存值
  115. WENDU:
  116.      jnb 20H.0,WENDUret       ;0－跳

  118.      LCALL  doujian       ;读键和健值处理
  119.      LCALL  XIANSHI       ;显示
  120.      LCALL  xunhuan       ;循环 次数
  121.      AJMP WENDU
  122. WENDUret:
  123.      LCALL clear_write     ;先擦除EEPROM再写EEPROM保存温度档，然后关闭EEPROM
  124.      nop
  125. ;********************
  126. ;设AD档  据wendudang中数字，设定终止电压
  127. ADdang:
  128.      MOV A,wendudang
  129.      cjne a,#1,ADdang1
  130.      MOV U_zhongzhizheng,57
  131.      mov U_zhongzhixiao,1      ;对应是57.11V   5度以下
  132.         JMP ADdangRET     
  133. ADdang1:
  134.      cjne a,#2,ADdang2
  135.      MOV U_zhongzhizheng,56
  136.      mov U_zhongzhixiao,6        ;对应是56.64V   10度以下
  137.         JMP ADdangRET
  138. ADdang2:
  139.      cjne a,#3,ADdang3
  140.      MOV U_zhongzhizheng,56
  141.      mov U_zhongzhixiao,1        ;对应是56.16V   15度以下
  142.         JMP ADdangRET        
  143. ADdang3:
  144.      cjne a,#4,ADdang4
  145.      MOV U_zhongzhizheng,55
  146.      mov U_zhongzhixiao,6        ;对应是55.68V   20度以下
  147.         JMP ADdangRET        
  148. ADdang4:
  149.      cjne a,#5,ADdang5
  150.      MOV U_zhongzhizheng,55
  151.      mov U_zhongzhixiao,2        ;对应是55.20V   25度以下
  152.         JMP ADdangRET        
  153. ADdang5:
  154.      cjne a,#6,ADdang6
  155.      MOV U_zhongzhizheng,54
  156.      mov U_zhongzhixiao,7         ;对应是54.72V   30度以下
  157.         JMP ADdangRET
  158. ADdang6:
  159.      cjne a,#7,ADdang7
  160.      MOV U_zhongzhizheng,54
  161.      mov U_zhongzhixiao,2         ;对应是54.24V   35度以下
  162.         JMP ADdangRET
  163. ADdang7:
  164.      cjne a,#8,ADdang8
  165.      MOV U_zhongzhizheng,53
  166.      mov U_zhongzhixiao,7          ;对应是53.76V   40度以下
  167.         JMP ADdangRET
  168. ADdang8:             ;剩下的就是 a=0了    同a=8 档           
  169.      MOV U_zhongzhizheng,53
  170.      mov U_zhongzhixiao,7          ;对应是53.76V   40度以下

  172. ADdangRET:
  173.      clr kong     ;接通220V
  174.         nop
  175.         NOP
  176.     ;进入主程序之前不能有RET，否则运行到此止。
  177. ;*****************
  178. ;主程序
  179. ZhuPRO:
  180.      LCALL PRO_ZOUSHI         ;走时   统计20mS的个数，计时，设立半秒标志、分标志、时标志 检测标志
  181.      LCALL  KAIJISHISHU   ;开机时数   开机10小时停充电，开机240小时重新启动单片机。
  182. jnb 22h.5,zhu_a
  183.         clr 22h.5             ;每15秒一次的标志位，走时置1，在此清0
  184.      lcall  jiaceTL431       ;检测TL431做基准电压的AD值
  185.       LCALL  jiacesheding   ;检测(电瓶）设定      测出电瓶AD
  186.      LCALL  JISUAN         ;计算 电瓶电压伏特数＝(电瓶AD值×37+电瓶AD值×0.5）÷基准电压AD值 求出伏特整数和小数
  187.      LCALL  probijiao    ;比较     电瓶电压与基准电压做比较 标记是否充满电
  188.      lcall XIANhuan           ;显缓 存放好要显示的十位、个位、小数位
  189. zhu_a:
  190.      LCALL  xiu_V      ;显示电瓶电压
  191.      
  192.      lcall  PROKongZhi     ;控制      充满断电 十小时断电
  193.      mov WDT_CONTR,#00111110B      ;喂狗
  194.      jmp  ZhuPRO

  196. ;*************************** WENDU 温度 设温度档 *********************************
  197. ;DOUEEPROM    ;读EEPROM中0000H处的保存值
  198. DOUEEPROM:
  199.                     mov     contr,#84h ;设定操作时间
  200.                     mov     cmd,#01h   ;设定读操作
  201.                     mov     drl,#00h     ;设定存储单元地址低四位
  202.                     mov     drh,#00h    ;设定存储单元地址高四位 这里设0000h，也可选用其他单元
  203.                     mov     trig,#5Ah  ;准备触发
  204.                     mov     trig,#0A5h  ;触发
  205.                     nop
  206.                     mov     wendudang,dat         ;读数据写到RAM指定处
  207. ;                    mov     wendudang,A        ;读数据写到RAM指定处

  209. DOUEEPROMret:
  210.         ret
  211. ;*************
  212. ;doujian       ;读键
  213. doujian:
  214.          setb jian
  215.          nop
  216.          nop
  217.          lcall DELAY         
  218.          JB jian,doujianret          ;未按下(p1.2),  1-跳
  219.          lcall DELAY                ;延时
  220.          JB jian,doujianret
  221.          inc wendudang               ;温度档加1
  222.          mov XUN_JSHQ,#0            ;循环计数清0
  223.          mov a,#9
  224.          cjne a,wendudang,doujian_1  ; 分0，1，2，3，4，5，6，7,8九档，最高8档
  225.          mov wendudang,#0

  227. doujian_1:
  228.          nop
  229.          jb jian,doujian_1       ;1-跳 等待释放键
  230.          lcall DELAY
  231.          lcall DELAY
  232. doujianret:
  233.    ret

  235. ;****************
  236. ;XIANSHI    ;显示
  237. XIANSHI:
  238.         mov a,wendudang
  239.         cpl a          ;取反
  240.         swap a         ;高低四位交换
  241.         ANL A,#11110000B   ;获高四位
  242.         mov R0,a

  244.         mov a,p1
  245.         anl a,#00001111B   ;获低四位
  246.         orl a,R0           ;整合高低八位
  247.         mov p1,a           ;驱动LED
  248. XIANSHIret:
  249.     ret
  250. ;****************   
  251. ;xunhuan       ;循环 次数
  252. xunhuan:
  253.       lcall DELAY      ;延时
  254.       INC XUN_JSHQ     ;循环计数加1
  255.       mov a,XUN_JSHQ
  256.       cjne a,#200,xunhuanret
  257.       mov XUN_JSHQ,#0
  258.       clr 20h.0         ;停止按键后循环200次约？？秒，结束设温度档程序

  260. xunhuanret:
  261.      RET
  262. ;******************
  263. ;延时 0.04秒
  264.     DELAY:
  265.             MOV     R7,#250
  266.     D1:     MOV     R6,#250
  267.                     DJNZ    R6,$
  268.                     DJNZ    R7,D1
  269.             RET
  270. ;*****************
  271. ;先擦除再写入，然后关闭
  272. clear_write:
  273.               mov    contr,#84h  ;设定操作时间
  274.               mov    cmd,#03h    ;设定擦除操作
  275.               mov    drl,#00h    ;设定存储单元地址低四位
  276.               mov    drh,#00h    ;设定存储单元地址高四位 这里设0000h

  278.               mov    trig,#5AH   ;准备触发      
  279.               mov    trig,#0A5h   ;触发
  280.               nop
  281.               nop
  282. ;---------写-------------------
  283. write:
  284.                    mov     contr,#84h   ;设定操作时间
  285.                    mov     cmd,#02h     ;设定写操作
  286.                    mov     drl,#00h     ;设定存储单元地址低四位
  287.                    mov     drh,#00h     ;设定存储单元地址高四位 这里设0000h
  288. ;      MOV A,wendudang
  289.                    mov     dat,wendudang         ;wendudang中为准备写入的数据
  290.                    mov     trig,#5AH    ;准备触发
  291.                    mov     trig,#0A5H   ;触发
  292.                    nop
  293.                    nop
  294. ;=========关闭EEPROM====================
  295. off:  
  296.           mov     contr,#0     ;禁止操作
  297.           mov     cmd,#0   ;去除操作命令
  298.           mov     trig,#0   ;防止命令误触发
  299.           mov    drl,#0         ;指向非EEPROM区
  300.           mov    drh,#80H        ;指向非EEPROM区
  301.            ret
  302.    
  303. ;*********************************** 充电有关的计时 ******************************



  307. ;****************
  308. ;走时   统计20mS的个数，计时，设立半秒标志、分标志、时标志
  309. PRO_ZOUSHI:
  310.      JNB 22H.0,PROARET     ;20mS标志位
  311.      INC JSHQ_20MS
  312.      CLR 22H.0   
  313.      mov A,#25             ;25个20mS为半秒
  314.      CJNE A,JSHQ_20mS,PROARET
  315.      MOV JSHQ_20mS,#0
  316.      inc jshq_S
  317.      setb 20h.2         ;控制显示的半秒标志
  318. PROA_1:
  319.   MOV A,#30
  320.   CJNE A,JSHQ_S,PROARET
  321.        MOV JSHQ_S,#0
  322.   SETB 22H.5   ;15秒检测一次
  323.   INC JSHQ_15
  324.   MOV A,#4
  325.   CJNE A,JSHQ_15,PROARET
  326.      MOV JSHQ_15,#0
  327.      INC JSHQ_M
  328.      MOV A,#60             ;60分为1小时
  329.      CJNE A,JSHQ_M,PROARET
  330.      MOV JSHQ_M,#0
  331.      setb 22h.3       ;时标志

  333. PROARET:
  334.      RET

  336. ;********************
  337. ;开机时数   开机10小时停充电，开机240小时重新启动单片机。
  338. KAIJISHISHU:
  339.     JNB 22H.3,KAIJISHISHURET
  340.     clr 22h.3
  341.     INC JSHQ_H
  342.     MOV A,#10         ;最多充电10小时
  343.     CJNE A,JSHQ_H,KAIJISHISHU_1
  344.     CLR 21H.6        ;初值1，充电10小时清0。
  345.     setb kong          ;断220V交流
  346.     JMP KAIJISHISHURET
  347. KAIJISHISHU_1:
  348.     mov a,#240         ;十天重启
  349.     cjne a,jshq_h,KAIJISHISHURET
  350.     MOV IAP_CONTR,#00100000B  ;热重启
  351. KAIJISHISHURET:
  352.      RET
  353. ;*******************
  354. ;检测设定    每15秒进行一次     两次测电压相同 确定占空比  温度检测没使用
  355. jiacesheding:
  356. ;          MOV P1,#11111111B           ;关显示 再延时 防止电压波动对AD转换的影响
  357. ;          LCALL DELAY                 ;延时0.4秒
  358. dianya:
  359.       lcall PRO_ad   ;AD转换测电瓶电压
  360.       MOV jiace_adzhi1,jiace_adzhi
  361.       mov jiace_adzhi,#0
  362.       lcall PRO_ad  ;AD转换测电瓶电压  
  363. BiJiao:                 ;比较两次测电压结果 同－进入下一步 不同－重测
  364.       mov a,jiace_adzhi1
  365.       cjne a,jiace_adzhi,dianya
  366.       
  367. jiaceshedingret:
  368.      ret

  370. ;********************
  371. ;AD转换测电瓶电压
  372. PRO_ad:
  373.       MOV P1ASF,#0000001B   ;P1.0做AD检测
  374.      MOV ADC_RES,#0                ;转换结果寄存器清零
  375.      MOV ADC_CONTR,#11100000B  
  376.      nop
  377.      nop
  378.      nop
  379.      nop
  380.      mov a,#11101000b
  381.      MOV ADC_CONTR,A            ;开始A/D转换
  382.       NOP                        ;在质询之前一定等候
  383.       NOP
  384.       NOP
  385.       NOP
  386. WAIT:      
  387.     MOV        A,ADC_CONTR        ;等候完成的标志
  388.     JNB        ACC.4,WAIT        ;转换完成标志位 不是1就转           
  389.     MOV        ADC_CONTR,#01100000B                ;关转换 清标志位  
  390.    
  391.     MOV jiace_adzhi,ADC_RES       ;读出AD值保存

  393. PRO_adRET:
  394.       RET

  396. ;********************
  397. jiaceTL431:
  398. ;          MOV P1,#11111111B           ;关显示 再延时 防止电压波动对AD转换的影响
  399. ;          LCALL DELAY                 ;延时0.4秒
  400. dianyaTL:
  401.       lcall prTL431_ad   ;AD转换测TL431的AD
  402.       MOV TL431_AD1,TL431_AD
  403.       mov TL431_AD,#0
  404.       lcall prTL431_ad  ;AD转换测TL431的AD
  405. BiJiaoTL:                 ;比较两次测电压结果 同－进入下一步 不同－重测
  406.       mov a,TL431_AD1
  407.       cjne a,TL431_AD,dianyaTL

  409. jiaceTL431ret:
  410.      ret
  411. ;******************
  412. ;AD转换测TL431
  413. prTL431_ad:
  414.       MOV P1ASF,#0000010B   ;P1.1做AD检测
  415.      MOV ADC_RES,#0                ;转换结果寄存器清零
  416.      MOV ADC_CONTR,#11100001B  
  417.      nop
  418.      nop
  419.      nop
  420.      nop
  421.      mov a,#11101001b
  422.      MOV ADC_CONTR,A            ;开始A/D转换
  423.       NOP                        ;在质询之前一定等候
  424.       NOP
  425.       NOP
  426.       NOP
  427. TL431WAIT:      
  428.     MOV        A,ADC_CONTR        ;等候完成的标志
  429.     JNB        ACC.4,TL431WAIT        ;转换完成标志位 不是1就转           
  430.     MOV        ADC_CONTR,#11100001B                ;关转换 清标志位  
  431.    
  432.     MOV TL431_AD,ADC_RES       ;读出AD值保存

  434. TL431_adRET:
  435.       RET

  437. ;*******************
  438. ;比较 ;通过电瓶电压整数与终止电压整数比较，电瓶电压小数与终止电压小数比较，确定并标记电瓶有无充满.
  439. probijiao:
  440.       clr c
  441.       mov a,v_ZH   ;电瓶电压整数
  442.       CJNE A,U_zhongzhizheng,bijiao_1     ;电瓶电压整数与终止电压整数比较
  443.       MOV A,V_XAO
  444.       CJNE A,U_zhongzhixiao,bijiao_1     ;电瓶电压小数与终止电压小数比较
  445.       
  446. bijiao_0:      
  447.        clr 21h.4     ;电瓶正常标志位  1--正常  0－－充满（或不能充电）   
  448.        JMP bijiao_ret
  449. bijiao_1:
  450.       JC bijiao_0  ;超过终止电压 C=1
  451.       
  452. bijiao_ret:
  453.       ret      
  454.       
  455. ;******************
  456. ; ;控制充断电
  457. PROKongZhi:
  458.       jb 21h.4,pro_a     ;电瓶正常标志 1－正常 0－不正常 无电瓶 或充满
  459.       setb kong      ;通过光耦控制220V通断 0－通  1－断
  460. pro_a:
  461.       JB 21H.6,PROKongZhiRET                     
  462.       setb kong      ;通过光耦控制220V通断 0－通  1－断      
  463. PROKongZhiRET:
  464.       RET
  465. ;****************
  466. ;显缓
  467. XIANhuan:
  468.        MOV A,v_ZH    ;电瓶伏特整数
  469.        MOV B,#10
  470.        DIV AB
  471.        MOV 61H,B            ;个位
  472.        MOV 60H,A            ;十位
  473.        MOV 62H,V_XAO        ;小数
  474.       
  475.        MOV 63H,#0          ;黑屏的数字
  476.        mov 64h,#00001111B   ;四灯全亮

  478. XIANhuan_ret:
  479.        ret

  481. ;***************  
  482. ; xiu_V 显伏特数 十、个位、小数位分别显示，每位显示2秒，黑屏1秒，三位显示完黑屏3秒。
  483. xiu_V:
  484.        JNB 20H.2,XianZ   ;每秒运行一次
  485.        CLR 20H.2

  487.       INC JSHQ_WEI
  488.        MOV A,#11
  489.        CJNE A,JSHQ_WEI,xiu_V_1
  490.        MOV JSHQ_WEI,#0      
  491.         mov R1,60H           ;显十位
  492.         LCALL PROXIAN
  493.       JMP xiu_VRET
  494. xiu_V_1:  
  495.         MOV A,#1            ;显示十位
  496.        CJNE A,JSHQ_WEI,xiu_V_2
  497.        nop                  ;保持原显示就行了
  498.         ;mov R1,60H
  499.         ;LCALL PROXIAN
  500. XianZ:  jmp  xiu_VRET           ;中间跳板
  501. xiu_V_2:  
  502.         MOV A,#2     ;黑屏
  503.        CJNE A,JSHQ_WEI,xiu_V_3      
  504.         mov R1,63H
  505.         LCALL PROXIAN
  506.       JMP xiu_VRET        
  507. xiu_V_3:  
  508.         MOV A,#3     ;显示个位
  509.        CJNE A,JSHQ_WEI,xiu_V_4     
  510.         mov R1,61H
  511.         LCALL PROXIAN
  512.       JMP xiu_VRET        
  513. xiu_V_4:  
  514.         MOV A,#4     ;显示个位
  515.        CJNE A,JSHQ_WEI,xiu_V_5     
  516.         nop                  ;保持原显示就行了
  517.         ;mov R1,61H
  518.         ;LCALL PROXIAN
  519.       JMP xiu_VRET        
  520. xiu_V_5:  
  521.         MOV A,#5     ;黑屏
  522.        CJNE A,JSHQ_WEI,xiu_V_6      
  523.         mov R1,63H
  524.         LCALL PROXIAN
  525.       JMP xiu_VRET        
  526. xiu_V_6:  
  527.         MOV A,#6    ;显示小数位
  528.        CJNE A,JSHQ_WEI,xiu_V_7     
  529.         mov R1,62H
  530.         LCALL PROXIAN
  531.       JMP xiu_VRET        
  532. xiu_V_7:  
  533.         MOV A,#7     ;显示小数位
  534.        CJNE A,JSHQ_WEI,xiu_V_8     
  535.         nop                  ;保持原显示就行了
  536.         ;mov R1,62H
  537.         ;LCALL PROXIAN
  538.       JMP xiu_VRET        
  539. xiu_V_8:  
  540.         MOV A,#8     ;黑屏
  541.        CJNE A,JSHQ_WEI,xiu_V_9      
  542.         mov R1,63H
  543.         LCALL PROXIAN
  544.       JMP xiu_VRET        
  545. xiu_V_9:  
  546.         MOV A,#9     ;四灯全亮
  547.        CJNE A,JSHQ_WEI,xiu_V_10     
  548.         mov R1,64H
  549.         LCALL PROXIAN
  550.        JMP xiu_VRET      
  551. xiu_V_10:
  552.        nop                   ;保持原显示就行了
  553.         ;mov R1,63H     ;黑屏
  554.         ;LCALL PROXIAN

  556. xiu_VRET:
  557.        RET
  558. ;***************

  560. ;显示     
  561. PROXIAN:
  562.         MOV A,R1
  563.         cpl a          ;取反
  564.         swap a         ;高低四位交换
  565.         ANL A,#11110000B   ;获高四位
  566.         mov R0,a

  568.         mov a,p1
  569.         anl a,#00001111B   ;获低四位
  570.         orl a,R0           ;整合高低八位
  571.         mov p1,a           ;驱动LED     
  572.         RET
  573. ;*******************************
  574. ;计算 jì suàn   电瓶电压伏特数＝(电瓶AD值×37+电瓶AD值×0.86）÷基准电压AD值   TL431稳压后是2.524伏
  575. ;求出伏特整数和一位小数
  576. JISUAN:
  577.       MOV v_ZH,#0        ;存伏特整数 先清0
  578.       mov V_XAO,#0       ;伏特小数 先清0   
  579.       mov r2,#0
  580.       mov r3,#0
  581. ;电瓶AD值×37      
  582.       MOV A,Jiace_ADzhi  ;电瓶AD值
  583.       MOV B,#37
  584.       MUL AB
  585.       MOV R2,A          ;37倍的积的低8位 存R2
  586.       MOV R3,B          ;37倍的积的高8位 存R3
  587. ;电瓶AD值×86     
  588.       MOV A,Jiace_ADzhi
  589.       mov b,#86        ;
  590.       MUL AB           ;86倍的积高位在B低位在A 高位在B
  591. ;除以100
  592.       MOV beichushugao,B     ;被除数高位
  593.       MOV beichushudi,A      ;被除数低位
  594.       MOV chushu,#100        ;除数
  595.       mov zhengshang,#0      ;整数商
  596.       mov XIAOSHUSHANG,#0    ;小数商
  597.       mov YUSHU,#0           ;余数
  598.       
  599.   LCALL PROCHU
  600.       ;电瓶AD值×0.86的整数部分已经在zhengshang
  601. ;电瓶AD值×37与电瓶AD值×0.86两积之和
  602.       mov a,zhengshang
  603.       ADD A,R2                 
  604.       MOV R2,A
  605.       JNC  JISUAN_1     ;0-跳
  606.       INC R3
  607.       clr c            ;以上完成了(电瓶AD值×37+电瓶AD值×0.86）  值的高位在R3，低位在R2
  608. JISUAN_1:            
  609. ;下面用减法代除法做[÷基准电压AD值]部分
  610.       MOV beichushugao,R3     ;被除数高位
  611.       MOV beichushudi,R2     ;被除数低位
  612.       MOV chushu,TL431_AD        ;除数
  613.       mov zhengshang,#0
  614.       mov XIAOSHUSHANG,#0
  615.       mov YUSHU,#0      
  616.       
  617. LCALL PROCHU
  618.       MOV v_ZH,zhengshang     ;伏特整数
  619.       MOV V_XAO,XIAOSHUSHANG  ;伏特小数  
  620. RET
  621. ;*********************
  622. ;除法 被除数有高8位低8位，除数只有8位，商有8位整数1位小数
  623. ;beichushugao     ;被除数高位
  624. ;beichushudi      ;被除数低位
  625. ;chushu        ;除数
  626. ;zhengshang  EQU 78H     ;整数商
  627. ;XIAOSHUSHANG  EQU 79H    ;小数商
  628. ;YUSHU      EQU  7AH     ;余数
  629. ;LSSHU     EQU  7BH     ;临时存
  630. ; DISHU   低位 第二次的被除数低位
  631. ;GAOSHU   高位 第二次的被除数高位
  632. PROCHU:
  633.       MOV A,#0
  634.       CJNE A,beichushugao,PROCHU_0   ;高位不是0 跳
  635.       MOV A,beichushudi
  636.       jmp PROCHU_A        ;跳到高位是0，求低位的商
  637. PROCHU_0:              ;求高位不是0部分的商
  638.       MOV A,beichushudi
  639. PROCHU_01:      
  640.       SUBB A,chushu
  641.       INC zhengshang
  642.       JNC PROCHU_01      
  643.       DJNZ beichushugao,PROCHU_01
  644. PROCHU_A:            ;高位是0，求低位的商
  645.     ;  MOV  LSSHU,A    ;备份
  646.       SUBB A,chushu
  647.       INC zhengshang
  648.       JNC PROCHU_A     ;c=0 循环再减
  649.       CLR C            ;有借位，表示多减了一次
  650.    ;   DEC zhengshang   ;恢复
  651.    ;   MOV A,LSSHU      ;恢复
  652.      ;*************求小数**********
  653.       MOV B,#10        ;求小数，先将被除数乘10
  654.       MUL AB
  655.       MOV GAOSHU,B       ;高位
  656.       MOV DISHU,A      ;低位
  657. PROCHU_B:
  658.       MOV A,#0
  659.       CJNE A,GAOSHU,PROCHU_B0
  660.       MOV A,DISHU
  661.       JMP PROCHU_C   ;跳到高位是0 求低位商
  662. PROCHU_B0:
  663.       MOV A,DISHU
  664. PROCHU_B01:
  665.       SUBB A,chushu
  666.       INC XIAOSHUSHANG
  667.       JNC PROCHU_B01      
  668.       DJNZ GAOSHU,PROCHU_B01
  669. PROCHU_C:    ;高位是0 求低位商           
  670.       MOV  LSSHU,A
  671.       SUBB A,chushu
  672.       INC XIAOSHUSHANG
  673.       JNC PROCHU_C     ;c=0 循环再减
  674.       CLR C            ;有借位，表示多减了一次
  675. ;      DEC XIAOSHUSHANG   ;恢复   实测显示数据偏小所以删此句
  676.       MOV A,LSSHU      ;恢复
  677.       MOV YUSHU,A    ;余数
  678. ret
  679. ;****************      
  680.       
  681. ;**********************************************************************
  682. TIME_0:   ;20毫秒@10.911MHz
  683.         PUSH        ACC
  684.         PUSH        PSW
  685.         MOV        TL0,#0F7H        
  686.         MOV        TH0,#0B8H
  687.         SETB 22H.0          ;20mS标志  专供走时用
  688.         POP        PSW
  689.         POP        ACC
  690.         RETI
  691. ;************************
  692. pppuuu:
  693. nop
  694. nop
  695. nop
  696. nop
  697. nop
  698. nop
  699. nop
  700. nop
  701.   nop
  702. nop
  703. nop
  704. nop
  705.   nop
  706. nop
  707. nop
  708. nop
  709.   nop
  710. nop
  711. nop
  712. nop
  713.   nop
  714. nop
  715. nop
  716. nop
  717.   nop
  718. nop
  719. nop
  720. nop
  721.   nop
  722. nop
  723. nop
  724. nop
  725.   nop
  726. nop
  727. nop
  728. nop
  729.   nop
  730. nop
  731. nop
  732. nop
  733.   nop
  734. nop
  735. nop
  736. nop
  737.   nop
  738. nop
  739. nop
  740. nop
  741.   nop
  742. nop
  743. nop
  744. nop
  745. lcall START
  746. nop
  747. nop
  748. nop

  750. ……………………

  752. …………限于本文篇幅 余下代码请从51黑下载附件…………
复制代码
0.png
所有资料51hei提供下载:
源码和hex.rar (8.02 KB, 下载次数: 41)

评分

参与人数 1黑币 +100 收起 理由
admin + 100 共享资料的黑币奖励！

查看全部评分

回复

使用道具 举报

ID:286600 发表于 2018-3-3 10:34 | 显示全部楼层
若配个脉冲电源对电瓶充电，这是个很好的配件。普通充电器用的是开关电源无脉冲。老式变压器整流不滤波是脉冲，但要注意变压器输出电压不要太高了，据我的经验48V电瓶不要超过46伏，45V比较合适，46×1.41已经超过普通充电器转灯前的电压了。（有的说法是变压器次级输出电压要比电瓶标称值高1到2V，我不认可。）
      普通充电器转灯后电压是55.6V左右，冬天不用此保护也可。夏天环境温度高，电瓶充到55.6V就过充了。此保护器第8档，充到53.7V就停充电，可有效地进行保护。
     铅电瓶有负温度系数，冬天充电终止电压高些，夏天低些。
回复

使用道具 举报

ID:265635 发表于 2018-3-3 15:12 | 显示全部楼层
全汇编，赞一下！
回复

使用道具 举报

ID:286600 发表于 2018-3-8 10:39 | 显示全部楼层
少有人关注本贴。
1、看来群里人真富，都开汽车没人骑电动车了。
2、用汇编的人也越来越少了。
回复

使用道具 举报

ID:162136 发表于 2018-3-21 16:04 | 显示全部楼层
看到全是汇编，我赞一个。
回复

使用道具 举报

ID:295097 发表于 2018-3-21 16:26 | 显示全部楼层
什么时候才能变成你这么厉害

回复

使用道具 举报

ID:91721 发表于 2019-6-25 11:57 | 显示全部楼层
全汇编，赞一下！
回复

使用道具 举报

ID:165363 发表于 2019-6-26 09:43 | 显示全部楼层
汇编的啊，有点难看懂。
回复

使用道具 举报

ID:159857 发表于 2020-5-14 21:49 | 显示全部楼层

全汇编，赞一下！楼主厉害！
回复

使用道具 举报

ID:733231 发表于 2020-5-18 19:53 | 显示全部楼层


全汇编，赞一下！楼主厉害！向你学习~~~
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表