1.时钟电路硬件设计: 图1 89S51电路图 图 2 8位共阴极数码管与锁存器的连接 图3 独立键盘与矩阵键盘[1]
本实验用到前6个数码管(P2.2~P2.0取000~101)和第一个按钮开关(P3.0)。P0口输出数码管数据,锁存器直通[2]。
2.系统主要程序设计: (1).主程序 本设计中的计时采用定时器T0中断完成,其余状态循环调用显示子程序,当P3.0开关按下时,转入调时功能程序。系统主程序流程图如图4所示: (2).显示子程序 数码管显示的数据存放在内存单元70H~75H中,其中70H~71H存放的秒数据,72H~73H存放的分数据,74H~75H存放的时数据,每一地址单元内均为十进制BCD码。由于采用软件动态扫描实现数据显示功能,显示用十进制BCD码数据的对应段码数据存放在ROM表中。显示时,先取出70H~75H某一地址中的数据,然后查得对应的显示用段码从P0口输出。P2口将对应的数码管选中,就能显示该地址单元的数据值。 (3).定时器T0中断服务程序 定时器T0用于时间计时。定时溢出中断周期设为50ms,中断累计20次(即1s)时对秒计数单元进行加1操作。时间计数单元地址分别在70H~71H(s)、76H~77H(min)、78H~79H(h),7AH单元中存放“熄灭符”数据(#0AH)。在计数单元中采用十进制BCD码计数,满60进位。T0中断服务程序流程图见图5所示。 (4).T1中断服务程序 T1中断服务程序用于指示调整单元数字的亮闪。在时间调整状态下,每过0.3s,将对应单元的数据换成“熄灭符”数据(#0AH)。这样,在调整时间时,对应调整单元的显示数据就会间隔闪亮。 (5).调时功能程序 调时功能程序的设计方法是:按下按键,若按下时间小于1s,进入省电状态(数码管不亮,时钟不停),否则进入调分状态,等待操作,此时定时器停止走动。当再次按下按钮时,若按下时间小于0.5s,则时间加1min;若按下时间大于0.5s,则进入小时调整状态。在小时调整状态下,当按键按下的时间大于0.5s时退出调整状态,时钟继续走动。 图4 主程序流程图 图5 T0中断服务程序 4.实验总结:
1.实验中使用的是12MHz晶振;
2.数码管使用动态扫描显示;
3.操作都要先等待按键释放后才做相应;
4.按键按下时间长短判断:在两次监测键是否按下语句中间夹一条延时语句(类似于按键消抖动)。
5.按键释放等待时应一直调用显示子程序,防止键按下时无时钟显示。
6.适当设置标志位对程序的设计很重要。例如:本例中设置了20H做标志位,其中00H、01H、02H(即20H.0、20H.1、20H.2)分别做调分标志、调时标志、闪烁标志;只要监测标志位既能方便对应出不同响应。
7.本例中ADD1子程序(即BCD码加1子程序)。其入口参数是R0,它作为指针指向待加1的两位BCD码的高位;出口参数为R3,存放着加1后的BCD码值。 3.数码管时钟电路源程序代码: - ORG 0000H ;程序执行开始地址
- LJMP START ;跳到标号START执行
- ORG 0003H ;外中断0中断程序入口
- RETI ;外中断0中断返回
- ORG 000BH ;定时器T0中断程序入口
- LJMP INTT0 ;跳至INTTO执行
- ORG 0013H ;外中断1中断程序入口
- RETI ;外中断1中断返回
- ORG 001BH ;定时器T1中断程序入口
- LJMP INTT1 ;跳至INTT1执行
- ORG 0023H ;串行中断程序入口地址
- RETI ;串行中断程序返回
- ;*******************************************************
- START: MOV SP,#30H
- MOV PSW,#00H
- MOV R0,#70H ;清70H-7AH共11个内存单元
- MOV R7,#0BH ;
- CLEAR: MOV @R0,#00H ;
- INC R0 ;
- DJNZ R7,CLEAR ;
- MOV 20H,#00H ;标志位
- MOV 7AH,#0AH ;放入"熄灭符"数据
- MOV TMOD,#11H ;设T0、T1为16位定时器
- MOV TL0,#0B0H ;50MS定时初值(T0计时用)
- MOV TH0,#3CH ;50MS定时初值
- MOV TL1,#0B0H ;50MS定时初值(T1闪烁定时用)
- MOV TH1,#3CH ;50MS定时初值
- SETB EA ;总中断开放
- SETB ET0 ;允许T0中断
- SETB TR0 ;开启T0定时器
- MOV R4,#14H ;1秒定时用初值(50MS×20)
- START1: LCALL DISPLAY ;调用显示子程序
- JNB P3.0,SETMM1 ;P3.0口为0时转时间调整程序
- SJMP START1 ;
- SETMM1: LJMP SETMM ;转到时间调整程序SETMM
- ;*********************************************************
- INTT0: PUSH ACC ;累加器入栈保护
- PUSH PSW ;状态字入栈保护
- CLR ET0 ;关T0中断允许
- CLR TR0 ;关闭定时器T0
- MOV A,#0B7H ;中断响应时间同步修正
- ADD A,TL0 ;低8位初值修正
- MOV TL0,A ;重装初值(低8位修正值)
- MOV A,#3CH ;高8位初值修正
- ADDC A,TH0 ;
- MOV TH0,A ;重装初值(高8位修正值)
- SETB TR0 ;开启定时器T0,后面再开放中断允许
- DJNZ R4, OUTT0 ;20次中断未到中断退出
- ADDSS: MOV R4,#14H ;20次中断到(1秒)重赋初值
- MOV R0,#71H ;指向秒计时单元(71H-72H)
- ACALL ADD1 ;调用加1程序(加1秒操作)
- MOV A,R3 ;秒数据放入A(R3为2位十进制数组合)
- CLR C ;清进位标志
- CJNE A,#60H,ADDMM ;
- ADDMM: JC OUTT0 ;小于60秒时中断退出
- ACALL CLR0 ;大于或等于60秒时对秒计时单元清0
- MOV R0,#77H ;指向分计时单元(76H-77H)
- ACALL ADD1 ;分计时单元加1分钟
- MOV A,R3 ;分数据放入A
- CLR C ;清进位标志
- CJNE A,#60H,ADDHH ;
- ADDHH: JC OUTT0 ;小于60分时中断退出
- ACALL CLR0 ;大于或等于60分时分计时单元清0
- MOV R0,#79H ;指向小时计时单元(78H-79H)
- ACALL ADD1 ;小时计时单元加1小时
- MOV A,R3 ;时数据放入A
- CLR C ;清进位标志
- CJNE A,#24H,HOUR ;
- HOUR: JC OUTT0 ;小于24小时中断退出
- ACALL CLR0 ;大于或等于24小时小时计时单元清0
- OUTT0: MOV 72H,76H ;中断退出时将分、时计时单元数据移
- MOV 73H,77H ;入对应显示单元
- MOV 74H,78H ;
- MOV 75H,79H ;
- POP PSW ;恢复状态字(出栈)
- POP ACC ;恢复累加器
- SETB ET0 ;开放T0中断
- RETI ;中断返回
- ;*******************************************************
- INTT1: PUSH ACC ;中断现场保护
- PUSH PSW ;
- MOV TL1, #0B0H ;装定时器T1定时初值
- MOV TH1, #3CH ;
- DJNZ R2,INTT1OUT ;0.3秒未到退出中断(50MS中断6次)
- MOV R2,#06H ;重装0.3秒定时用初值
- CPL 02H ;0.3秒定时到对闪烁标志取反
- JB 02H,FLASH1 ;02H位为1时显示单元"熄灭"
- MOV 72H,76H ;02H位为0时正常显示
- MOV 73H,77H ;
- MOV 74H,78H ;
- MOV 75H,79H ;
- INTT1OUT: POP PSW ;恢复现场
- POP ACC ;
- RETI ;中断退出
- FLASH1: JB 01H,FLASH2 ;01H位为1时,转小时熄灭控制
- MOV 72H,7AH ;01H位为0时,"熄灭符"数据放入分
- MOV 73H,7AH ;显示单元(72H-73H),将不显示分数据
- MOV 74H,78H ;
- MOV 75H,79H ;
- AJMP INTT1OUT ;转中断退出
- FLASH2: MOV 72H,76H ;01H位为1时,"熄灭符"数据放入小时
- MOV 73H,77H ;显示单元(74H-75H),小时数据将不显示
- MOV 74H,7AH ;
- MOV 75H,7AH ;
- AJMP INTT1OUT ;转中断退出
- ;**************************************************
- DISPLAY:MOV R1,#75H ;指向显示数据首址
- MOV R5,#00H ;扫描控制字初值
- PLAY: MOV A,@R1
- MOV DPTR,#TAB
- MOVC A,@A+DPTR
- MOV P0,A ;先放段码入P0
- MOV A,R5 ;扫描字放入A
- MOV P2,A ;扫描字放入扫描控制端口
- LCALL DL1MS ;1MS子程序另编
- MOV A,R1
- CLR C
- SUBB A,#01H
- MOV R1,A
- INC R5
- CJNE R5,#06,PLAY
- MOV P0,#00H ;P0段码输出口复位
- MOV P2,#0FFH ;一次显示结束P2扫描控制口复位
- RET
- TAB: DB 3FH,6H,5BH,4FH,66H,6DH,7DH,7H,7FH,6FH,00H
- ;*****************************************************
- ADD1: MOV A,@R0 ;取当前计时单元数据到A
- DEC R0 ;指向前一地址
- SWAP A ;A中数据高四位与低四位交换
- ORL A,@R0 ;前一地址中数据放入A中低四位
- ADD A,#01H ;A加1操作
- DA A ;十进制调整
- MOV R3,A ;移入R3寄存器
- ANL A,#0FH ;高四位变0
- MOV @R0,A ;放回前一地址单元
- MOV A,R3 ;取回R3中暂存数据
- INC R0 ;指向当前地址单元
- SWAP A ;A中数据高四位与低四位交换
- ANL A,#0FH ;高四位变0
- MOV @R0,A ;数据放入当削地址单元中
- RET ;子程序返回
- ;**************************************************
- CLR0: CLR A ;清累加器
- MOV @R0,A ;清当前地址单元
- DEC R0 ;指向前一地址
- MOV @R0,A ;前一地址单元清0
- RET ;子程序返回
- ;**************************************************
- SETMM: CLR ET0 ;关定时器T0中断
- CLR TR0 ;关闭定时器T0
- LCALL DL1S ;调用1秒延时程序
- JB P3.0,CLOSEDIS ;键按下时间小于1秒,关闭显示(省电)
- MOV R2,#06H ;进入调时状态,赋闪烁定时初值
- SETB ET1 ;允许T1中断
- SETB TR1 ;开启定时器T1
- SET2: JNB P3.0,SET1 ;P3.0口为0(键未释放),等待
- SETB 00H ;键释放,分调整闪烁标志置1
- SET4: JB P3.0,SET3 ;等待键按下
- LCALL DL05S ;有键按下,延时0.5秒
- JNB P3.0,SETHH ;按下时间大于0.5秒转调小时状态
- MOV R0,#77H ;按下时间小于0.5秒加1分钟操作
- LCALL ADD1 ;调用加1子程序
- MOV A,R3 ;取调整单元数据
- CLR C ;清进位标志
- CJNE A,#60H,HHH ;调整单元数据与60比较
- HHH: JC SET4 ;调整单元数据小于60转SET4循环
- LCALL CLR0 ;调整单元数据大于或等于60时清0
- CLR C ;清进位标志
- AJMP SET4 ;跳转到SET4循环
- CLOSEDIS: SETB ET0 ;省电(LED不显示)状态。开T0中断
- SETB TR0 ;开启T0定时器(开时钟)
- CLOSE: JB P3.0,CLOSE ;无按键按下,等待。
- LCALL DISPLAY ;有键按下,调显示子程序延时削抖
- JB P3.0,CLOSE ;是干扰返回CLOSE等待
- WAITH: JNB P3.0,WAITH ;等待键释放
- LJMP START1 ;返回主程序(LED数据显示亮)
- SETHH: CLR 00H ;分闪烁标志清除(进入调小时状态)
- SETHH1: JNB P3.0,SET5 ;等待键释放
- SETB 01H ;小时调整标志置1
- SET6: JB P3.0,SET7 ;等待按键按下
- LCALL DL05S ;有键按下延时0.5秒
- JNB P3.0,SETOUT ;按下时间大于0.5秒退出时间调整
- MOV R0,#79H ;按下时间小于0.5秒加1小时操作
- LCALL ADD1 ;调加1子程序
- MOV A,R3 ;
- CLR C ;
- CJNE A,#24H,HOUU ;计时单元数据与24比较
- HOUU: JC SET6 ;小于24转SET6循环
- LCALL CLR0 ;大于或等于24时清0操作
- AJMP SET6 ;跳转到SET6循环
- SETOUT: JNB P3.0,SETOUT1 ;调时退出程序。等待键释放
- LCALL DISPLAY ;延时削抖
- JNB P3.0,SETOUT ;是抖动,返回SETOUT再等待
- CLR 01H ;清调小时标志
- CLR 00H ;清调分标志
- CLR 02H ;清闪烁标志
- CLR TR1 ;关闭定时器T1
- CLR ET1 ;关定时器T1中断
- SETB TR0 ;开启定时器T0
- SETB ET0 ;开定时器T0中断(计时开始)
- LJMP START1 ;跳回主程序
- SET1: LCALL DISPLAY ;键释放等待时调用显示程序(调分)
- AJMP SET2 ;防止键按下时无时钟显示
- SET3: LCALL DISPLAY ;等待调分按键时时钟显示用
- AJMP SET4
- SET5: LCALL DISPLAY ;键释放等待时调用显示程序(调小时)
- AJMP SETHH1 ;防止键按下时无时钟显示
- SET7: LCALL DISPLAY ;等待调小时按键时时钟显示用
- AJMP SET6
- SETOUT1: LCALL DISPLAY ;退出时钟调整时键释放等待
- AJMP SETOUT ;防止键按下时无时钟显示
- ;*******************************************
- DL1MS: MOV R6,#14H
- DL1: MOV R7,#19H
- DL2: DJNZ R7,DL2
- DJNZ R6,DL1
- RET
- ;
- DL1S: LCALL DL05S
- LCALL DL05S
- RET
- DL05S: MOV R3,#2CH ;5.76毫秒*44=0.253秒
- DL05S1: LCALL DISPLAY
- DJNZ R3,DL05S1
- RET
- ;*******************************************
- END
复制代码
完整的Word格式文档51黑下载地址:
|