设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › Arduino › 用于arduino的MS5837-30BAR和02BAR的官方测试源程序与资 ...
返回列表 发新帖
查看: 6672|回复: 3
收起左侧

用于arduino的MS5837-30BAR和02BAR的官方测试源程序与资料

[复制链接]
ID:413939 发表于 2018-10-23 11:56 | 显示全部楼层 |阅读模式
用于arduino的MS5837-30BAR和02BAR的官方测试程序可以在代码里面自由对MS5837的种类进行切换，非常的方便
MS5837是高精度的压力传感器，形状微小
在很多地方都有应用，比如潜水仪器等等
另上传关于MS5837的芯片手册，供大家使用

未命名_副本1.jpg

BlueRobotics_MS5837_Library-master

源程序如下:

  2. #include "MS5837.h"
  3. #include <Wire.h>

  5. #define MS5837_ADDR               0x76  
  6. #define MS5837_RESET              0x1E
  7. #define MS5837_ADC_READ           0x00
  8. #define MS5837_PROM_READ          0xA0
  9. #define MS5837_CONVERT_D1_8192    0x4A
  10. #define MS5837_CONVERT_D2_8192    0x5A

  12. const float MS5837::Pa = 100.0f;
  13. const float MS5837::bar = 0.001f;
  14. const float MS5837::mbar = 1.0f;

  16. const uint8_t MS5837::MS5837_30BA = 0;
  17. const uint8_t MS5837::MS5837_02BA = 1;

  19. MS5837::MS5837() {
  20.         fluidDensity = 1029;
  21. }

  23. bool MS5837::init() {
  24.         // Reset the MS5837, per datasheet
  25.         Wire.beginTransmission(MS5837_ADDR);
  26.         Wire.write(MS5837_RESET);
  27.         Wire.endTransmission();

  29.         // Wait for reset to complete
  30.         delay(10);

  32.         // Read calibration values and CRC
  33.         for ( uint8_t i = 0 ; i < 7 ; i++ ) {
  34.                 Wire.beginTransmission(MS5837_ADDR);
  35.                 Wire.write(MS5837_PROM_READ+i*2);
  36.                 Wire.endTransmission();

  38.                 Wire.requestFrom(MS5837_ADDR,2);
  39.                 C[i] = (Wire.read() << 8) | Wire.read();
  40.         }

  42.         // Verify that data is correct with CRC
  43.         uint8_t crcRead = C[0] >> 12;
  44.         uint8_t crcCalculated = crc4(C);

  46.         if ( crcCalculated == crcRead ) {
  47.                 return true; // Initialization success
  48.         }

  50.         return false; // CRC fail
  51. }

  53. void MS5837::setModel(uint8_t model) {
  54.         _model = model;
  55. }

  57. void MS5837::setFluidDensity(float density) {
  58.         fluidDensity = density;
  59. }

  61. void MS5837::read() {
  62.         // Request D1 conversion
  63.         Wire.beginTransmission(MS5837_ADDR);
  64.         Wire.write(MS5837_CONVERT_D1_8192);
  65.         Wire.endTransmission();

  67.         delay(20); // Max conversion time per datasheet
  68.         
  69.         Wire.beginTransmission(MS5837_ADDR);
  70.         Wire.write(MS5837_ADC_READ);
  71.         Wire.endTransmission();

  73.          Wire.requestFrom(MS5837_ADDR,3);
  74.         D1 = 0;
  75.         D1 = Wire.read();
  76.         D1 = (D1 << 8) | Wire.read();
  77.         D1 = (D1 << 8) | Wire.read();
  78.         
  79.         // Request D2 conversion
  80.         Wire.beginTransmission(MS5837_ADDR);
  81.         Wire.write(MS5837_CONVERT_D2_8192);
  82.         Wire.endTransmission();

  84.         delay(20); // Max conversion time per datasheet
  85.         
  86.         Wire.beginTransmission(MS5837_ADDR);
  87.         Wire.write(MS5837_ADC_READ);
  88.         Wire.endTransmission();

  90.         Wire.requestFrom(MS5837_ADDR,3);
  91.         D2 = 0;
  92.         D2 = Wire.read();
  93.         D2 = (D2 << 8) | Wire.read();
  94.         D2 = (D2 << 8) | Wire.read();

  96.         calculate();
  97. }

  99. void MS5837::calculate() {
  100.         // Given C1-C6 and D1, D2, calculated TEMP and P
  101.         // Do conversion first and then second order temp compensation
  102.         
  103.         int32_t dT = 0;
  104.         int64_t SENS = 0;
  105.         int64_t OFF = 0;
  106.         int32_t SENSi = 0;
  107.         int32_t OFFi = 0;  
  108.         int32_t Ti = 0;   
  109.         int64_t OFF2 = 0;
  110.         int64_t SENS2 = 0;
  111.         
  112.         // Terms called
  113.         dT = D2-uint32_t(C[5])*256l;
  114.         if ( _model == MS5837_02BA ) {
  115.                 SENS = int64_t(C[1])*65536l+(int64_t(C[3])*dT)/128l;
  116.                 OFF = int64_t(C[2])*131072l+(int64_t(C[4])*dT)/64l;
  117.                 P = (D1*SENS/(2097152l)-OFF)/(32768l);
  118.         } else {
  119.                 SENS = int64_t(C[1])*32768l+(int64_t(C[3])*dT)/256l;
  120.                 OFF = int64_t(C[2])*65536l+(int64_t(C[4])*dT)/128l;
  121.                 P = (D1*SENS/(2097152l)-OFF)/(8192l);
  122.         }
  123.         
  124.         // Temp conversion
  125.         TEMP = 2000l+int64_t(dT)*C[6]/8388608LL;
  126.         
  127.         //Second order compensation
  128.         if ( _model == MS5837_02BA ) {
  129.                 if((TEMP/100)<20){         //Low temp
  130.                         Serial.println("here");
  131.                         Ti = (11*int64_t(dT)*int64_t(dT))/(34359738368LL);
  132.                         OFFi = (31*(TEMP-2000)*(TEMP-2000))/8;
  133.                         SENSi = (63*(TEMP-2000)*(TEMP-2000))/32;
  134.                 }
  135.         } else {
  136.                 if((TEMP/100)<20){         //Low temp
  137.                         Ti = (3*int64_t(dT)*int64_t(dT))/(8589934592LL);
  138.                         OFFi = (3*(TEMP-2000)*(TEMP-2000))/2;
  139.                         SENSi = (5*(TEMP-2000)*(TEMP-2000))/8;
  140.                         if((TEMP/100)<-15){    //Very low temp
  141.                                 OFFi = OFFi+7*(TEMP+1500l)*(TEMP+1500l);
  142.                                 SENSi = SENSi+4*(TEMP+1500l)*(TEMP+1500l);
  143.                         }
  144.                 }
  145.                 else if((TEMP/100)>=20){    //High temp
  146.                         Ti = 2*(dT*dT)/(137438953472LL);
  147.                         OFFi = (1*(TEMP-2000)*(TEMP-2000))/16;
  148.                         SENSi = 0;
  149.                 }
  150.         }
  151.         
  152.         OFF2 = OFF-OFFi;           //Calculate pressure and temp second order
  153.         SENS2 = SENS-SENSi;
  154.         
  155.         if ( _model == MS5837_02BA ) {
  156.                 TEMP = (TEMP-Ti);
  157.                 P = (((D1*SENS2)/2097152l-OFF2)/32768l)/100;
  158.         } else {
  159.                 TEMP = (TEMP-Ti);
  160.                 P = (((D1*SENS2)/2097152l-OFF2)/8192l)/10;
  161.         }
  162. }

  164. float MS5837::pressure(float conversion) {
  165.         return P*conversion;
  166. }

  168. float MS5837::temperature() {
  169.         return TEMP/100.0f;
  170. }

  172. float MS5837::depth() {
  173.         return (pressure(MS5837::Pa)-101300)/(fluidDensity*9.80665);
  174. }

  176. float MS5837::altitude() {
  177.         return (1-pow((pressure()/1013.25),.190284))*145366.45*.3048;
  178. }


  181. uint8_t MS5837::crc4(uint16_t n_prom[]) {
  182.         uint16_t n_rem = 0;

  184.         n_prom[0] = ((n_prom[0]) & 0x0FFF);
  185.         n_prom[7] = 0;

  187.         for ( uint8_t i = 0 ; i < 16; i++ ) {
  188.                 if ( i%2 == 1 ) {
  189.                         n_rem ^= (uint16_t)((n_prom[i>>1]) & 0x00FF);
  190.                 } else {
  191.                         n_rem ^= (uint16_t)(n_prom[i>>1] >> 8);
  192.                 }
  193.                 for ( uint8_t n_bit = 8 ; n_bit > 0 ; n_bit-- ) {
  194.                         if ( n_rem & 0x8000 ) {
  195.                                 n_rem = (n_rem << 1) ^ 0x3000;
  196.                         } else {
  197.                                 n_rem = (n_rem << 1);
  198.                         }
  199.                 }
  200.         }
  201.         
  202.         n_rem = ((n_rem >> 12) & 0x000F);

  204.         return n_rem ^ 0x00;
  205. }

复制代码

所有资料51hei提供下载:
BlueRobotics_MS5837_Library-master.zip (8.31 KB, 下载次数: 51)
MS5837-30BA芯片手册.pdf (1.21 MB, 下载次数: 22)

评分

参与人数 1黑币 +50 收起 理由
admin + 50 共享资料的黑币奖励！

查看全部评分

回复

使用道具 举报

ID:565602 发表于 2019-10-25 19:20 | 显示全部楼层
有个客户在用，今天开始调试，先顶再读
回复

使用道具 举报

ID:683452 发表于 2020-1-8 11:30 | 显示全部楼层
蠻厲害的選擇
回复

使用道具 举报

ID:318415 发表于 2020-4-4 10:57 | 显示全部楼层
感谢楼主 ！

我自己写了个ms5837 一直没找到问题 对着例子 改了改可以用  

再次感谢！！
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表