单片机论坛

 找回密码
 立即注册

QQ登录

只需一步,快速开始

搜索
查看: 14502|回复: 29
收起左侧

19课:单片机定时器、中断试验

  [复制链接]
admin 发表于 2013-5-21 03:14 | 显示全部楼层 |阅读模式
  我们在学单片机时我们第一个例程就是灯的闪烁,那是用延时程序做的,现在回想起来,这样做不很恰当,为什么呢?我们的主程序做了灯的闪烁,就不能再干其它的事了,难道单片机只能这样工作吗?当然不是,我们能用定时器来实现灯的闪烁的功能。例1:查询方式
ORG 0000H
AJMP START
ORG 30H
START:
MOV P1,#0FFH ;关所 灯
MOV TMOD,#00000001B ;定时/计数器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即数5536
SETB TR0 ;定时/计数器0开始运行
LOOP:JBC TF0,NEXT ;如果TF0等于1,则清TF0并转NEXT处
AJMP LOOP ;不然跳转到LOOP处运行
NEXT:CPL P1.0
MOV TH0,#15H
MOV TL0,#9FH;重置定时/计数器的初值
AJMP LOOP
END AJMP LOOP
END
   键入程序,看到了什么?灯在闪烁了,这可是用定时器做的,不再是主程序的循环了。简单地分析一下程序,为什么用JBC呢?TF0是定时/计数器0的溢出标记位,当定时器产生溢出后,该位由0变1,所以查询该位就可知宇时时间是否已到。该位为1后,要用软件将标记位清0,以便下一次定时是间到时该位由0变1,所以用了JBC指令,该指位在判1转移的同时,还将该位清0。
   以上程序是能实现灯的闪烁了,可是主程序除了让灯闪烁外,还是不能做其他的事啊!不,不对,我们能在LOOP:……和AJMP LOOP指令之间插入一些指令来做其他的事情,只要保证执行这些指令的时间少于定时时间就行了。那我们在用软件延时程序的时候不是也能用一些指令来替代DJNZ吗?是的,但是那就要求你精确计算所用指令的时间,然后再减去对应的DJNZ循环次数,很不方便,而现在只要求所用指令的时间少于定时时间就行,显然要求低了。当然,这样的办法还是不好,所以我们常用以下的办法来实现。
程序2:用中断实现
ORG 0000H   ,http://www.51hei.com
AJMP START
ORG 000BH ;定时器0的中断向量地址
AJMP TIME0 ;跳转到真正的定时器程序处
ORG 30H
START:
MOV P1,#0FFH ;关所 灯
MOV TMOD,#00000001B ;定时/计数器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即数5536
SETB EA ;开总中断允许
SETB ET0 ;开定时/计数器0允许
SETB TR0 ;定时/计数器0开始运行
LOOP: AJMP LOOP ;真正工作时,这里可写任意程序
TIME0: ;定时器0的中断处理程序
PUSH ACC
PUSH PSW ;将PSW和ACC推入堆栈保护
CPL P1.0
MOV TH0,#15H
MOV TL0,#0A0H ;重置定时常数
POP PSW
POP ACC
RETI
END
    上面的例程中,定时时间一到,TF0由0变1,就会引发中断,CPU将自动转至000B处寻找程序并执行,由于留给定时器中断的空间只有8个字节,显然不足以写下所有有中断处理程序,所以在000B处安排一条跳转指令,转到实际处理中断的程序处,这样,中断程序能写在任意地方,也能写任意长度了。进入定时中断后,首先要保存当前的一些状态,程序中只演示了保存存ACC和PSW,实际工作中应该根据需要将可能会改变的单元的值都推入堆栈进行保护(本程序中实际不需保存护任何值,这里只作个演示)。
   上面的两个单片机程序运行后,我们发现灯的闪烁非常快,根本分辨不出来,只是视觉上感到灯有些晃动而已,为什么呢?我们能计算一下,定时器中预置的数是5536,所以每计60000个脉冲就是定时时间到,这60000个脉冲的时间是多少呢?我们的晶体震荡器是12M,所以就是60000微秒,即60毫秒,因此速度是非常快的。如果我想实现一个1S的定时,该怎么办呢?在该晶体震荡器濒率下,最长的定时也就是65。536个毫秒啊!上面给出一个例程。
ORG 0000H
AJMP START
ORG 000BH ;定时器0的中断向量地址
AJMP TIME0 ;跳转到真正的定时器程序处
ORG 30H
START:
MOV P1,#0FFH ;关所 灯
MOV 30H,#00H ;软件计数器预清0
MOV TMOD,#00000001B ;定时/计数器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即数15536
SETB EA ;开总中断允许
SETB ET0 ;开定时/计数器0允许
SETB TR0 ;定时/计数器0开始运行
LOOP: AJMP LOOP ;真正工作时,这里可写任意程序
TIME0: ;定时器0的中断处理程序
PUSH ACC
PUSH PSW ;将PSW和ACC推入堆栈保护
INC 30H
MOV A,30H
CJNE A,#20,T_RET ;30H单元中的值到了20了吗?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清软件计数器
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定时常数
POP PSW
POP ACC
RETI
END
  先自己分析一下,看看是怎么实现的?这里采用了软件计数器的概念,思路是这样的,先用定时/计数器0做一个50毫秒的定时器,定时是间到了以后并不是立即取反P10,而是将软件计数器中的值加1,如果软件计数器计到了20,就取反P10,并清掉软件计数器中的值,不然直接返回,这样,就变成了20次定时中断才取反一次P10,因此定时时间就延长了成了20*50即1000毫秒了。
   这个思路在工程中是非常有用的,有的时候我们需要若干个定时器,可51中总共才有2个,怎么办呢?其实,只要这几个定时的时间有一定的公约数,我们就能用软件定时器加以实现,如我要实现P10口所接灯按1S每次,而P11口所接灯按2S每次闪烁,怎么实现呢?对了我们用两个计数器,一个在它计到20时,取反P10,并清零,就如上面所示,另一个计到40取反P11,然后清0,不就行了吗?这部份的程序如下
ORG 0000H
AJMP START
ORG 000BH ;定时器0的中断向量地址
AJMP TIME0 ;跳转到真正的定时器程序处
ORG 30H
START:
MOV P1,#0FFH ;关所 灯
MOV 30H,#00H ;软件计数器预清0
MOV TMOD,#00000001B ;定时/计数器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即数15536
SETB EA ;开总中断允许
SETB ET0 ;开定时/计数器0允许
SETB TR0 ;定时/计数器0开始运行
LOOP: AJMP LOOP ;真正工作时,这里可写任意程序
TIME0: ;定时器0的中断处理程序
PUSH ACC
PUSH PSW ;将PSW和ACC推入堆栈保护
INC 30H
INC 31H ;两个计数器都加1
MOV A,30H
CJNE A,#20,T_NEXT ;30H单元中的值到了20了吗?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清软件计数器
T_NEXT:
MOV A,31H
CJNE A,#40,T_RET ;31h单元中的值到40了吗?
T_L2:
CPL P1.1
MOV 31H,#0 ;到了,取反P11,清计数器,返回
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定时常数
POP PSW
POP ACC
RETI
END
您能用定时器的办法实现前面讲的流水灯吗?试试看。

回复

使用道具 举报

heron 发表于 2018-3-8 23:33 | 显示全部楼层
跟着例子做的定时器中断实现流水灯实验,欢迎指正错误(没锁大写通篇小写,凑活着看看吧

org 0000h
ajmp start
org 000bh
ajmp time0
org 30h
start:
  mov p1,#0feh                ;赋值11111110b,为了实现流水,先打开了一颗灯
  mov 30h,#00h
  mov tmod,#00000001b
  mov th0,#3ch
  mov tl0,#0b0h
  setb ea
  setb et0
  setb tr0
loop:ajmp loop
time0:
  push acc
  push psw
  inc 30h
  mov a,30h
  cjne a,20,t_next
  t_0:
    mov a,p1
    rl a                        ;左移一位
    mov p1,a
    mov 30h,#0
  t_next:
    mov th0,#15h
        mov tl0,#9fh

  pop psw
  pop acc
  reti
end
回复

使用道具 举报

danpianji889 发表于 2013-8-15 11:14 | 显示全部楼层
非常好,谢谢
回复

使用道具 举报

sjztjk 发表于 2013-8-17 15:06 | 显示全部楼层
学习了,谢谢分享。
回复

使用道具 举报

雪中梅花 发表于 2014-6-5 14:09 | 显示全部楼层
谢谢楼主软件通过下载试验收获很大。
回复

使用道具 举报

windljn 发表于 2014-7-15 15:35 | 显示全部楼层
支持楼主
回复

使用道具 举报

lxl2255 发表于 2015-1-4 10:05 | 显示全部楼层
#在学习了非常好这里快支持楼主速回复#
回复

使用道具 举报

kaka3511 发表于 2015-2-7 17:21 | 显示全部楼层
怎么感觉有点难,是不是我太笨了?
回复

使用道具 举报

kaka3511 发表于 2015-2-7 17:31 | 显示全部楼层
我有一头小毛驴我从来也不骑
回复

使用道具 举报

云龙腾海 发表于 2015-4-21 10:21 来自手机 | 显示全部楼层
我想要c语言的,,,,
回复

使用道具 举报

好男人就是我 发表于 2015-4-23 08:37 来自手机 | 显示全部楼层
感谢分享~!!!
回复

使用道具 举报

yzl 发表于 2015-6-2 14:16 | 显示全部楼层
此文讲解非常清楚初学者一看一目了然加快了初学者学习决心
回复

使用道具 举报

yzl 发表于 2015-6-2 14:25 | 显示全部楼层
1说理清楚使学者一目了然
回复

使用道具 举报

阿桑 发表于 2015-9-6 20:24 来自手机 | 显示全部楼层
好,非常感谢。谢谢
回复

使用道具 举报

wkuz2222 发表于 2015-12-19 12:06 | 显示全部楼层
wsfa aewfaewf
回复

使用道具 举报

a1097994700 发表于 2016-4-6 16:25 | 显示全部楼层
回帖支持!
回复

使用道具 举报

ln7812 发表于 2016-6-26 14:32 | 显示全部楼层
看君一贴编程实例,胜读十天书。谢谢楼主,学习了,
回复

使用道具 举报

abc_123 发表于 2016-10-24 09:04 | 显示全部楼层
很好,谢谢
回复

使用道具 举报

lsrly 发表于 2016-11-15 23:14 | 显示全部楼层
怎么不是C呀!
回复

使用道具 举报

a88mm 发表于 2016-12-17 14:16 | 显示全部楼层
目测汇编的用最必要的步骤实现,省去了不必要的步骤
回复

使用道具 举报

镜花水月K12 发表于 2017-4-20 11:22 | 显示全部楼层
很棒
回复

使用道具 举报

123456LYH 发表于 2017-8-16 19:44 | 显示全部楼层
非常详细
回复

使用道具 举报

zjy007 发表于 2017-10-20 15:08 | 显示全部楼层
汇编看着舒不舒服,但简单直接
回复

使用道具 举报

990259743 发表于 2017-10-22 19:33 | 显示全部楼层

学习了,谢谢分享
回复

使用道具 举报

DGP 发表于 2017-11-23 09:48 来自手机 | 显示全部楼层
看着汇编代码脑袋疼
回复

使用道具 举报

chaoself 发表于 2018-2-7 23:24 | 显示全部楼层
学习了,谢谢分享
回复

使用道具 举报

wuzjh 发表于 2018-2-11 22:13 | 显示全部楼层
谢谢老师!受益非浅。
回复

使用道具 举报

28#
无效楼层,该帖已经被删除
fscommand 发表于 2018-4-30 09:08 来自手机 | 显示全部楼层
可惜不是c写的,看不懂
回复

使用道具 举报

keneng 发表于 2018-6-26 13:54 | 显示全部楼层
继续学习,感谢楼主了。
回复

使用道具 举报

18339183028 发表于 2019-1-29 12:33 来自手机 | 显示全部楼层
没学汇编
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|手机版|小黑屋|单片机论坛 |51Hei单片机16群 联系QQ:125739409;技术交流QQ群7344883

Powered by 单片机教程网

快速回复 返回顶部 返回列表