设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › 电子制作DIY › 带无线更新的基于esp8266和blinker的小爱语音控制智能灯
返回列表 发新帖
查看: 4271|回复: 0
打印 上一主题 下一主题
收起左侧

带无线更新的基于esp8266和blinker的小爱语音控制智能灯

[复制链接]
跳转到指定楼层
楼主
ID:47972 发表于 2021-2-8 13:52 | 只看该作者 |只看大图 回帖奖励 |倒序浏览 |阅读模式
  前段时间看了ESP8266点灯的视频，想着自己也DIY一个。
上网搜了资料，买来ESP-8266-12F和继电器模块，开始动手制作。
制作过程省略，要是有不太明白的地方可以找度娘，一搜一大把，我这就偷个懒。
……制作的过程中遇到的问题与大家分享一下。
     1.最先遇到的就是每次下载程序都得插在电脑上下载，因为我用的免费版的，blinker一旦更新库文件或者与小爱的接口，咱们的灯就控制不了。 这就很麻烦了，不可能每次更新都去拆装一下灯吧。于是又找度娘商量了一下，度娘给了我一个http_update的例程，把这个例程加入进去，程序更新是解决了，可是电脑得开web服务器，不过总算是不用拆装灯具了。
     2.第二个问题就是设备ID是固化在程序里的，如果我做好2个或5个设备(blinker免费版最多5个独立设备)，更新的时候岂不是得生成5个更新包，万一更新的时候弄错了，后续使用就很麻烦。这个问题得解决掉，查看8266 库的时候发现8266是可以将FLASH当作EEPROM来操作的，于是把设备ID在下载程序后第一次运行就存在EEPROM里，后面就只要读出来就可以了。这样不管几个设备，更新程序都可以通用了。
    3.第三个问题就是WIFI配置。与设备ID一样，网上例程都是将WIFI SSID和PASSWORD固化在程序里的。如果只是测试用是没问题的，只要不改WIFI密码,或者改WIFI密码的时候先给灯的程序更新一下.......咱这个不是得装灯里面吗？这就又是个麻烦。好在blinker app里面就带有WIFI配网
  操作路径：打开blinker app => 点左上角的几条横线 => 点开发者 => 点开发工具 =>ApConfig,输入你的WIFI名称和密码，然后打开你要配置的设备，就可以愉快的点开始配置了。
代码我和电路图我放附件里了，需要的朋友可以下载参考一下。

  1. #define BLINKER_PRINT Serial
  2. #define BLINKER_MIOT_LIGHT
  3. #define BLINKER_WIFI
  4. #define BLINKER_APCONFIG
  5. #include <Blinker.h>
  6. #include <Arduino.h>   
  7. #include <ESP8266WiFi.h>
  8. #include <ESP8266WiFiMulti.h>
  9. #include <ESP8266HTTPClient.h>
  10. #include <ESP8266httpUpdate.h>
  11. #include <EEPROM.h>         ";
  12.   char eep1=0;
  13.   char eep2=5;
  14. int addr = 3900;//避开blinker使用的eeprom地址
  15. char  tmp = 0;
  16. bool oState = false;
  17. bool switch_state = true;
  18. int counter = 0;
  19. float pai =0;
  20. bool UpDate = false;  //系统升级标志
  21. char auth[] = "xxxxxxxxxx";//上一步中在blinker app中获取到的Secret Key
  22. char up_date_path["http://xxxxxxxxxxxx/file.bin"];//更新固件的具体http地址,只试过http,没试过https不知道可不可行
  23. // 新建组件对象
  24. BlinkerButton Button1("btn-put");//灯开关组件
  25. BlinkerButton Button2("btn-upd");//升级用的开关组件
  26. BlinkerNumber Number1("num-abc");
  27. ESP8266WiFiMulti WiFiMulti;
  28. void read_skey()
  29.    {
  30.      EEPROM.begin(4096);
  31.      for(tmp=0;tmp<12;tmp++)
  32.       {
  33.        auth[tmp]=EEPROM.read(addr+tmp);
  34.       }  
  35.      EEPROM.end();
  36.      Serial.println("EEPROM_read OK:");
  37.      Serial.println(auth);
  38.    }
  39. void write_skey()
  40.      {
  41.       EEPROM.begin(4096);
  42.       EEPROM.write(addr+14,0x42);//auth码存储标志
  43.       EEPROM.write(addr+15,0xbd);//auth码存储标志反码
  44.       for(tmp=0;tmp<12;tmp++)
  45.       {
  46.        EEPROM.write(addr+tmp,auth[tmp]);
  47.       
  48.        }  
  49.       if (EEPROM.commit())
  50.        {
  51.            Serial.println(auth);
  52.            Serial.println("EEPROM successfully committed");   
  53.         }
  54.       else
  55.        {
  56.       Serial.println("ERROR! EEPROM commit failed");
  57.        }
  58.        EEPROM.end();
  59.    }
  60. /* 小米设备状态查询回调函数 */
  61. void miotQuery(int32_t queryCode)
  62. {
  63.     BLINKER_LOG("MIOT Query codes: ", queryCode);

  65.     switch (queryCode)
  66.     {
  67.         case BLINKER_CMD_QUERY_ALL_NUMBER :
  68.             BLINKER_LOG("MIOT Query All");
  69.             BlinkerMIOT.powerState(oState ? "on" : "off");
  70.             BlinkerMIOT.print();
  71.             break;
  72.         case BLINKER_CMD_QUERY_POWERSTATE_NUMBER :
  73.             BLINKER_LOG("MIOT Query Power State");
  74.             BlinkerMIOT.powerState(oState ? "on" : "off");
  75.             BlinkerMIOT.print();
  76.             break;
  77.         default :
  78.             BlinkerMIOT.powerState(oState ? "on" : "off");
  79.             BlinkerMIOT.print();
  80.             break;
  81.     }
  82. }
  83. // 按下按键即会执行该函数
  84. void button1_callback(const String & state)
  85. {
  86.      if (state=="on")
  87.      {
  88.        BLINKER_LOG("get button state: ", state);
  89.        digitalWrite(LED_BUILTIN, LOW);
  90.        Button1.print("on");
  91.        switch_state = true;
  92.      }else if (state=="off")
  93.      {
  94.        BLINKER_LOG("get button state: ", state);
  95.        digitalWrite(LED_BUILTIN, HIGH);
  96.        Button1.print("off");
  97.        switch_state = false;   
  98.      }
  99. }
  100. void heartbeat()//自定义心跳包的返回
  101. {

  103.     if (switch_state)
  104.       {
  105.         //BUILTIN_SWITCH.print("on");
  106.         Button1.print("on");
  107.       }
  108.     else
  109.     {
  110.       //BUILTIN_SWITCH.print("off");
  111.       Button1.print("off");
  112.     }

  114. }
  115. //按下此键改变升级状态，进行http升级
  116. void button2_callback(const String & stage)
  117.      {
  118.       UpDate = true;
  119.       }
  120. // 如果未绑定的组件被触发，则会执行其中内容
  121. void dataRead(const String & data)
  122. {
  123.     BLINKER_LOG("Blinker readString: ", data);
  124.     counter++;
  125.     Number1.print(counter);
  126.     if (counter>0xfff0)counter=0;
  127. }
  128. void miotPowerState(const String & state) //小爱语音控制函数
  129. {
  130.    
  131.     if (state == BLINKER_CMD_ON) {
  132.         digitalWrite(LED_BUILTIN, LOW);
  133.         BlinkerMIOT.powerState("on");
  134.         BlinkerMIOT.print();
  135.         Button1.print("on");
  136.         switch_state = true;
  137.     }
  138.     else if (state == BLINKER_CMD_OFF) {
  139.         digitalWrite(LED_BUILTIN, HIGH);
  140.         BlinkerMIOT.powerState("off");
  141.         BlinkerMIOT.print();
  142.         Button1.print("off");
  143.         switch_state = false;
  144.     }
  145.     BLINKER_LOG("need set power state: ", state);
  146. }

  148. void setup() {

  150.   Serial.begin(115200);
  151.   Serial.println();
  152.   Serial.println();
  153.   Serial.println();
  154.     #if defined(BLINKER_PRINT)
  155.         BLINKER_DEBUG.stream(BLINKER_PRINT);
  156.     #endif
  157. EEPROM.begin(4096);
  158.    eep1=EEPROM.read(addr+14);  //ID存储标志
  159.    eep2=255-EEPROM.read(addr+15);//ID存储标志反码
  160.    EEPROM.end();
  161.    if (eep1==eep2)
  162.      {
  163.       read_skey();
  164.       Serial.println("EEPROM read OK.");
  165.       }
  166.     else
  167.      {
  168.       write_skey();
  169.       }
  170.   Serial.print("WiFi Connected!");
  171.     // 初始化有LED的IO
  172.     pinMode(LED_BUILTIN, OUTPUT);
  173.     digitalWrite(LED_BUILTIN, LOW);
  174.     //   Blinker.begin(auth, ssid, pswd);  //初始化blinker
  175.     Blinker.begin(auth);  //使用blinker app配网，这里只需要ID就行，如果预置WIFI配置就用上面一行代码
  176.     //注册回调函数
  177.     Blinker.attachHeartbeat(heartbeat);
  178.     Blinker.attachData(dataRead);
  179.     BlinkerMIOT.attachPowerState(miotPowerState);
  180.     Button1.attach(button1_callback);
  181.     Button2.attach(button2_callback);
  182.     BlinkerMIOT.attachQuery(miotQuery);
  183.     ESPhttpUpdate.onStart(update_started);
  184.     ESPhttpUpdate.onEnd(update_finished);
  185.     ESPhttpUpdate.onProgress(update_progress);
  186.     ESPhttpUpdate.onError(update_error);
  187. }

  189. void update_started() {
  190.   Serial.println("CALLBACK:  HTTP update process started");
  191. }

  193. void update_finished() {
  194.   Serial.println("CALLBACK:  HTTP update process finished");
  195.   UpDate = false;
  196.   digitalWrite(LED_BUILTIN, HIGH);
  197. }

  199. void update_progress(int cur, int total) {
  200.   Serial.printf("CALLBACK:  HTTP update process at %d bytes of %3.1f %%total\n", cur, (float)cur/(float)total*100.0);
  201. }

  203. void update_error(int err) {
  204.   Serial.printf("CALLBACK:  HTTP update fatal error code %d\n", err);
  205.   UpDate = false;
  206.       if (switch_state)   //更新失败则恢复灯的开关状态。
  207.       {
  208.         digitalWrite(LED_BUILTIN, LOW);
  209.         Button1.print("on");
  210.       }
  211.     else
  212.     {
  213.       digitalWrite(LED_BUILTIN, HIGH);
  214.       Button1.print("off");
  215.     }
  216.   Button2.print("update error");
  217. }

  219. void loop() {
  220.   // wait for WiFi connection
  221.   Blinker.run();
  222.   if (UpDate) {  //接收到更新指令，进入更新程序
  223.      if (switch_state){
  224.        digitalWrite(LED_BUILTIN, HIGH);
  225.      }
  226.     else{
  227.       digitalWrite(LED_BUILTIN, LOW); //灯状态取反表示进入更新模式
  228.     }
  229.     WiFiClient client;
  230.     t_httpUpdate_return ret = ESPhttpUpdate.update(client, up_date_path);//更新固件
  231.     switch (ret) {
  232.       case HTTP_UPDATE_FAILED:
  233.         Serial.printf("HTTP_UPDATE_FAILD Error (%d): %s\n", ESPhttpUpdate.getLastError(), ESPhttpUpdate.getLastErrorString().c_str());
  234.         break;

  236.       case HTTP_UPDATE_NO_UPDATES:
  237.         Serial.println("HTTP_UPDATE_NO_UPDATES");
  238.         break;

  240.       case HTTP_UPDATE_OK:
  241.         Serial.println("HTTP_UPDATE_OK");
  242.         break;
  243.     }
  244.   }
  245. }

复制代码

blinker_esp_8266_httpUpdate.rar (735.03 KB, 下载次数: 28)

2个文件一起解压才能成功:
8266_标准库.part1.rar (18 MB, 下载次数: 17)
8266_标准库.part2.rar (14.39 MB, 下载次数: 26)


评分

参与人数 1黑币 +50 收起 理由
admin + 50 共享资料的黑币奖励！

查看全部评分

分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏5 分享淘帖 顶顶 踩踩
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表