设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › 单片机DIY制作 › 315M无线遥控单片机软件解码
返回列表 发新帖
查看: 3394|回复: 5
打印 上一主题 下一主题
收起左侧

315M无线遥控单片机软件解码

[复制链接]
跳转到指定楼层
楼主
ID:72088 发表于 2021-9-3 20:54 | 只看该作者 |只看大图 回帖奖励 |倒序浏览 |阅读模式
学习单片机很久了，没做过像样的东西，对315M和433M无线遥控做过很多维修，也安装过一些遥控开关，更遇到过配遥控的客户无数，研究了配遥控器的方法。

用单片机STC15W204S软件解码密码，同步头长度，做过两个版本的线路板，第一版这里不介绍了，这里说一下第二版，看图


图上说的清楚，接收模块供电是单独滤波后的，防止干扰单片机，信号输出经一集成块放大（贴片5脚的那个），隔离单片机与接收模块干扰，是远距离解码的关键。
上原理图和PBC图，省的你们楼层问我要，呵呵！！


这是焊接好的线路板，这里没用时钟，所以没焊接DS3231，


显示屏是0.91寸的OLED屏，这玩意老贵了，用一个心疼半天。


写入程序，开机喽！！！！只看屏幕，不算丑，


解码一个遥控试试，4M是单片机震荡频率，烧写时需手动填写，选项里没有4M
顺便说明一下意思啊，图片介绍更清楚：


多解码几个不同震荡电阻试试看效果：




发射按键就是P3.3脚，这里没法演示发射，需要视频才能演示，我不会发链接
发射也是很精准的，接收设备很灵敏解码，第一版不介绍就是因为发射不精准
设备解码很不灵，用的发射模块是1000米的，这3.7V供电肯定达不到这距离，
要9V-12V才能600米左右，天线和障碍物因素众多，没详细实验距离
接收普通遥控信号最远30米，接收远距离遥控100米成功解码，
谢谢大家的阅读，此板已在某条鱼出售

程序只起到抛砖引玉的功能，不能全部分享给大家，有人收获多，有人收获不到，


下面是发射程序和显示程序，汇编写的大家轻喷！！！！！
  1. ;=============================按键发射接收到的编码==================================
  2. TTTT:
  3.         CLR LED_F        ;发射指示灯
  4.         MOV R3,#8        ;每字节调用8次
  5. TTT_1:
  6.         mov 20h,24h
  7.         mov 21h,25h
  8.         mov 22h,26h
  9.         MOV R0,#20H
  10. TTT_2:
  11.         LCALL FASE_T0
  12. TTT_3:
  13.         CLR C
  14.         MOV A,@R0
  15.         RLC A               
  16.         MOV @R0,A
  17.         JC TTT_4        
  18.         LCALL FASE_0        ;输出0码               
  19.         JMP TTT_5
  20. TTT_4:
  21.         LCALL FASE_1        ;输出1码
  22. TTT_5:
  23.         DJNZ R3,TTT_3        ;一字节是否发完
  24.         MOV R3,#8
  25.         INC R0
  26.         CJNE R0,#23H,TTT_3        ;3字节是否发完
  27.         MOV R3,#8        ;每字节调用8次
  28.         MOV R0,#20H

  30.         JNB K1,TTT_1
  31.         CLR FAST
  32.         SETB LED_F
  33.         RET
  34. ;-------------同步码----------------
  35. FASE_T0:
  36.         SETB FAST
  37.         LCALL DEL_FS
  38.         MOV R5,#31
  39. FASE_T1:
  40.         CLR FAST
  41.         LCALL DEL_FS
  42.         DJNZ R5,FASE_T1
  43.         RET
  44. ;--------------0码-----------------
  45. FASE_0:        SETB FAST
  46.         LCALL DEL_FS
  47.         MOV R5,#3
  48. FASE_01:CLR FAST
  49.         LCALL DEL_FS
  50.         DJNZ R5,FASE_01
  51.         RET
  52. ;--------------1码-----------------
  53. FASE_1:        MOV R5,#3        ;
  54. FASE_11:SETB FAST
  55.         LCALL DEL_FS
  56.         DJNZ R5,FASE_11
  57.         CLR FAST
  58.         LCALL DEL_FS
  59.         RET



  63. ;-----------数据解码显示-----------------20H/21H/22H/2FH------
  64. ;显示0/F/D/1
  65. DISP_JMB:
  66.         MOV R0, #20H        ;原数据地址
  67.         MOV R1, #40H
  68.         MOV R7, #0                ;左移次数计数
  69.         MOV 2FH,#0                ;该位可以位操作（位操作地址是7FH--78H）
  70. DISP_JM:
  71.         MOV A,@R0
  72.         CLR C
  73.         RLC A        ;C→A0  A7→C  数据存入C
  74.         MOV 79H,C        ;移入2FH单元A1位
  75.         CLR C
  76.         RLC A        ;C→A0  A7→C  数据存入C
  77.         MOV 78H,C        ;移入2FH单元A0位
  78.         MOV @R0,A        ;暂存@R0
  79.         MOV A,2FH        
  80.         JNZ        DISP_0F
  81.         MOV @R1,#0          ;------00--0解码显示
  82.         JMP DISP_01DF
  83. DISP_0F:
  84.         CJNE A,#01,DISP_0D
  85.         MOV @R1,#15        ;--------01--F解码显示
  86.         JMP DISP_01DF        
  87. DISP_0D:
  88.         CJNE A,#02,DISP_0H
  89.         MOV @R1,#13        ;--------10--D解码显示
  90.         JMP DISP_01DF
  91. DISP_0H:
  92.         CJNE A,#03,DISP_01DF
  93.         MOV @R1,#1        ;--------11--1解码显示
  94.         JMP DISP_01DF
  95. DISP_01DF:
  96.         MOV 2FH,#0
  97.         INC R1
  98.         INC R7
  99.         CJNE R7,#4,DISP_JM        ;是否移动了4次，够4次说明一字节输出完成
  100.         MOV R7,#0        ;左移次数清零
  101.         INC R0
  102.         CJNE R0,#23H,DISP_JM;3字节是否调取完成
  103.         MOV 4CH,#36
  104.         MOV 4DH,#36
  105.         MOV 4EH,#4
  106.         MOV 4FH,#22
  107. DISP_EN:
  108.         RET

  110. ;===========================第一排显示=====================================
  111. DISP_A:
  112.         MOV R0,#40H
  113.          MOV DIZHI_X,#00H ;列地址 1
  114.         LCALL DISP_B0
  115.         INC R0
  116.         MOV DIZHI_X,#08H ;列地址 2
  117.         LCALL DISP_B0
  118.         INC R0
  119.         MOV DIZHI_X,#10H ;列地址 3
  120.         LCALL DISP_B0
  121.         INC R0
  122.         MOV DIZHI_X,#18H ;列地址 4
  123.         LCALL DISP_B0
  124.         INC R0
  125.         MOV DIZHI_X,#20H ;列地址 5
  126.         LCALL DISP_B0
  127.         INC R0
  128.         MOV DIZHI_X,#28H ;列地址 6
  129.         LCALL DISP_B0
  130.         INC R0
  131.         MOV DIZHI_X,#30H ;列地址 7
  132.         LCALL DISP_B0
  133.         INC R0
  134.         MOV DIZHI_X,#38H ;列地址 8
  135.         LCALL DISP_B0
  136.         INC R0
  137.         MOV DIZHI_X,#40H ;列地址 9
  138.         LCALL DISP_B0
  139.         INC R0
  140.         MOV DIZHI_X,#48H ;列地址 10
  141.         LCALL DISP_B0
  142.         INC R0
  143.         MOV DIZHI_X,#50H ;列地址 11
  144.         LCALL DISP_B0
  145.         INC R0
  146.         MOV DIZHI_X,#58H ;列地址 12
  147.         LCALL DISP_B0
  148.         INC R0
  149.         MOV DIZHI_X,#60H ;列地址 13
  150.         LCALL DISP_B0
  151.         INC R0
  152.         MOV DIZHI_X,#68H ;列地址 14
  153.         LCALL DISP_B0
  154.         INC R0
  155.         MOV DIZHI_X,#70H ;列地址 15
  156.         LCALL DISP_B0
  157.         INC R0
  158.         MOV DIZHI_X,#78H ;列地址 16
  159.         LCALL DISP_B0
  160.         RET
  161. ;=========================第二排显示程序==============================
  162. DISP_B:
  163.         MOV R0,#40H
  164.          MOV DIZHI_X,#00H ;设置列地址 1
  165.         LCALL DISP_B2
  166.         INC R0
  167.         MOV DIZHI_X,#08H ;列地址 2
  168.         LCALL DISP_B2
  169.         INC R0
  170.         MOV DIZHI_X,#10H ;列地址 3
  171.         LCALL DISP_B2
  172.         INC R0
  173.         MOV DIZHI_X,#18H ;列地址 4
  174.         LCALL DISP_B2
  175.         INC R0
  176.         MOV DIZHI_X,#20H ;列地址 5
  177.         LCALL DISP_B2
  178.         INC R0
  179.         MOV DIZHI_X,#28H ;列地址 6
  180.         LCALL DISP_B2
  181.         INC R0
  182.         MOV DIZHI_X,#30H ;列地址 7
  183.         LCALL DISP_B2
  184.         INC R0
  185.         MOV DIZHI_X,#38H ;列地址 8
  186.         LCALL DISP_B2
  187.         INC R0
  188.         MOV DIZHI_X,#40H ;列地址 9
  189.         LCALL DISP_B2
  190.         INC R0
  191.         MOV DIZHI_X,#48H ;列地址 10
  192.         LCALL DISP_B2
  193.         INC R0
  194.         MOV DIZHI_X,#50H ;列地址 11
  195.         LCALL DISP_B2        
  196.         INC R0
  197.         MOV DIZHI_X,#58H ;列地址 12
  198.         LCALL DISP_B2
  199.         INC R0
  200.         MOV DIZHI_X,#60H ;列地址 13
  201.         LCALL DISP_B2
  202.         INC R0
  203.         MOV DIZHI_X,#68H ;列地址 14
  204.         LCALL DISP_B2
  205.         INC R0
  206.         MOV DIZHI_X,#70H ;列地址 15
  207.         LCALL DISP_B2
  208.         INC R0
  209.         MOV DIZHI_X,#78H ;列地址 16
  210.         LCALL DISP_B2
  211.         RET
  212. ;--数值第一排8*16显示子程序---------
  213. DISP_B0:
  214.           MOV DIZHI_Y,#0B0H ;设置页起始地址（B0-B7）(第一排)
  215.           LCALL TBT_0                ;根据值取表
  216.         LCALL XIE_MLING        ;写页地址和列地址
  217.          MOV R6,#8
  218.         LCALL MAK_XZJ  ;
  219.         INC DIZHI_Y                ;8*16下半部分页地址加1
  220.         LCALL XIE_MLING;写页地址和列地址
  221.         MOV R6,#8
  222.         LCALL MAK_XZJ
  223.         RET
  224. ;--数值第二排8*16显示子程序---------
  225. DISP_B2:
  226.           MOV DIZHI_Y,#0B2H ;设置页起始地址（B0-B7）(第2排)
  227.           LCALL TBT_0        ;根据值取表
  228.         LCALL XIE_MLING        ;写页地址和列地址
  229.          MOV R6,#8
  230.         LCALL MAK_XZJ  ;
  231.         INC DIZHI_Y                ;8*16下半部分页地址加1
  232.         LCALL XIE_MLING;写页地址和列地址
  233.         MOV R6,#8
  234.         LCALL MAK_XZJ
  235.         RET
  236. ;=========================数据区清零程序======================================
  237. QLCX:
  238.         MOV A,#0        ;清零程序
  239.         MOV R6,#40H
  240.         MOV R0,#20H
  241. QQQQ:
  242.         MOV @R0,A
  243.         INC R0
  244.         DJNZ R6,QQQQ
  245.         RET
  246. ;============================初始化0.91寸OLED=================================
  247. RESET:
  248.         MOV R7,#0AEH        ;关闭显示
  249.         LCALL COMMAND
  250.         MOV R7,#20H                ;设置模式命令
  251.         LCALL COMMAND
  252.         MOV R7,#10H                ;00水平地址，01垂直地址，10页地址
  253.         LCALL COMMAND
  254.         MOV R7,#0B0H        ;设置页起始地址（B0-B7）
  255.         LCALL COMMAND
  256.         MOV R7,#0C8H        ;设置COM输出扫描方向(C8从上到下，C0反向)
  257.         LCALL COMMAND
  258.         MOV R7,#00H                ;设置低列地址
  259.         LCALL COMMAND
  260.         MOV R7,#10H                ;设置高列地址
  261.         LCALL COMMAND
  262.         MOV R7,#40H                ;设置起始行地址
  263.         LCALL COMMAND
  264.         MOV R7,#81H                ;设置对比度
  265.         LCALL COMMAND
  266.         MOV R7,#200                ;对比度值（00-255）
  267.         LCALL COMMAND
  268.         MOV R7,#0A1H        ;设置egment re-map 0 to 127
  269.         LCALL COMMAND
  270.         MOV R7,#0A6H        ;正常显示（A6正常，A7反相显示）
  271.         LCALL COMMAND
  272.         MOV R7,#0A8H        ;设置驱动路数
  273.         LCALL COMMAND
  274.         MOV R7,#31                ;路数（0-63）
  275.         LCALL COMMAND
  276.          MOV R7,#0A5H        ;
  277.         LCALL COMMAND
  278.         MOV R7,#0A4H        ;全部显示开启
  279.         LCALL COMMAND
  280.         MOV R7,#0D3H        ;设置显示偏移
  281.         LCALL COMMAND
  282.         MOV R7,#0                ;偏移量
  283.         LCALL COMMAND
  284.         MOV R7,#0D5H        ;设置震荡频率
  285.         LCALL COMMAND
  286.         MOV R7,#0F0H        ;
  287.         LCALL COMMAND
  288.         MOV R7,#0D9H        ;设置充电周期
  289.         LCALL COMMAND
  290.         MOV R7,#22H                ;
  291.         LCALL COMMAND
  292.         MOV R7,#0DAH        ;引脚硬件配置
  293.         LCALL COMMAND
  294.         MOV R7,#02H                ;
  295.         LCALL COMMAND
  296.         MOV R7,#0DBH        ;设置电压倍率
  297.         LCALL COMMAND
  298.          MOV R7,#20H                ;
  299.         LCALL COMMAND
  300.         MOV R7,#8DH                ;设置
  301.         LCALL COMMAND
  302.         MOV R7,#14H               
  303.         LCALL COMMAND
  304.         MOV R7,#0AFH        ;打开显示
  305.         LCALL COMMAND
  306.         RET



  310. ;====================清屏程序=================================
  311. QPCX:
  312.         MOV R7,#00H                ;00水平地址，01垂直地址，10页地址
  313.         LCALL COMMAND
  314.            MOV R6,#0
  315.            MOV R4,#252
  316.         MOV R7,#0B0H        ;设置页起始地址（B0-B7）
  317.         LCALL COMMAND
  318.         MOV R7,#00H        ;设置低列地址
  319.            LCALL COMMAND
  320.         MOV R7,#10H        ;设置高列地址
  321.         LCALL COMMAND
  322. MAH:
  323.         MOV A,20h
  324.         MOV R7,A
  325.         LCALL COMDADA
  326.         INC R6                          
  327.         CJNE R6,#0,MAH
  328.         INC R4
  329.         CJNE R4,#0,MAH
  330.         RET        


  333. ;==================================================================
  334. ;--------写命令程序----------
  335. COMMAND:
  336.           MOV R3,#3
  337. COMMAND_1:
  338.         DEC R3          ;######防止出现程序检测不到I2C出现死循环
  339.         lcall start                ;启动总线        
  340.         mov a,#78h           ;地址写入
  341.         lcall send
  342.         lcall ack
  343.         MOV A, R3
  344.         JZ COMMAND_EN
  345.         jc         command_1


  348.         mov a,#00h
  349.         lcall send
  350.         lcall ack


  353.         mov a,R7
  354.         lcall send
  355.         lcall ack
  356.          lcall stop
  357. COMMAND_EN:
  358.         ret
  359. ;--------写数据程序----------
  360. COMDADA:
  361.         MOV R3,#3
  362. COMDADA_1:
  363.         DEC R3                 ;######防止出现程序检测不到I2C出现死循环
  364.         lcall start                ;启动总线        
  365.         mov a,#78h
  366.         lcall send
  367.         lcall ack
  368.         MOV A, R3
  369.         JZ COMDADA_EN
  370.         jc         comdada_1


  373.         mov a,#40h
  374.         lcall send
  375.         lcall ack
  376.         mov a,R7
  377.         lcall send
  378.         lcall ack
  379.          lcall stop
  380. COMDADA_EN:
  381.         ret
  382. ;------写页、列地址命令-----------
  383. XIE_MLING:
  384.         MOV R7,DIZHI_Y        ;设置页起始地址（B0-B7）
  385.         LCALL COMMAND
  386.         MOV A,DIZHI_X
  387.         ANL A,#0FH        ;
  388.         MOV R7,A        ;设置低列地址
  389.         LCALL COMMAND
  390.         MOV A,DIZHI_X
  391.         SWAP A
  392.         ANL A,#0FH        ;
  393.         ORL A,#10H
  394.          MOV R7,A        ;设置高列地址
  395.         LCALL COMMAND
  396.         RET
  397. ;--------写一字节数据--------------
  398. MAK_XZJ:
  399.         CLR A
  400.         MOVC A,@A+DPTR               
  401.         MOV R7,A
  402.         LCALL COMDADA
  403.         INC DPTR                          
  404.         DJNZ R6,MAK_XZJ
  405.         RET
  406. ;============================IIC总线程序=================================
  407. ;-------总线启动程序---------
  408. start:
  409.         setb         scl
  410.         setb         sda
  411.         nop
  412.         nop
  413.         clr         sda
  414.         nop
  415.         nop
  416.         clr         scl
  417.         ret
  418. ;-------总线停止程序---------
  419. stop:
  420.         clr         sda
  421.         nop
  422.         nop
  423.         setb         scl
  424.         nop
  425.         nop
  426.         setb         sda
  427.         ret
  428. ;-----------应答----------
  429. ack:
  430.         setb         sda
  431.         nop
  432.         nop
  433.         setb         scl
  434.         jb         sda,        ack_0
  435.         clr         c
  436.         sjmp         ack_1
  437. ack_0:
  438.         setb         c
  439. ack_1:
  440.         nop
  441.         nop
  442.         clr         scl
  443.         ret
  444. ;--------------发送8位数据---------
  445. send:
  446.         mov         b,        #08h
  447. send_1:
  448.         rlc         a
  449.         mov         sda,        c
  450.         setb         scl
  451.         nop
  452.         nop
  453.         clr         scl
  454.         djnz         b,        send_1
  455.         ret
  456. ;--------------接收8位数据-----------
  457. receive:
  458.         mov         b,        #08h
  459.         clr         a
  460.         setb         sda
  461. receive_1:
  462.         setb         scl
  463.         nop
  464.         nop
  465.         mov         c,sda
  466.         rlc         a
  467.         clr         scl
  468.         djnz         b,        receive_1
  469.         ret
  470. ;----------10MS--------------
  471. DELAY10ms:
  472.           MOV  6EH, #100
  473. DLY5: MOV  6FH, #100
  474.       DJNZ 6FH, $
  475.       DJNZ 6EH, DLY5
  476.       RET
复制代码


评分

参与人数 1黑币 +100 收起 理由
admin + 100 共享资料的黑币奖励！

查看全部评分

分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏4 分享淘帖 顶顶 踩踩
回复

使用道具 举报

沙发
ID:1041599 发表于 2022-8-8 07:42 | 只看该作者
感谢楼主分享，那个74AHC1具体型号是？ 具体如何起到抗干扰的作用？
回复

使用道具 举报

板凳
ID:72088 发表于 2022-8-11 15:52 | 只看该作者
月亮小小鸟 发表于 2022-8-8 07:42
感谢楼主分享，那个74AHC1具体型号是？ 具体如何起到抗干扰的作用？

缓冲隔离作用，
回复

使用道具 举报

地板
ID:68189 发表于 2022-8-11 17:29 | 只看该作者
74AHC1 是反相器（施密特）？

回复

使用道具 举报

5#
ID:1034262 发表于 2022-8-12 14:29 | 只看该作者
315M和433M通信，自己定义编码的话，我都用曼彻斯特编码，这是归0码，很合适做无线编码。
回复

使用道具 举报

6#
ID:1041599 发表于 2022-8-14 05:11 | 只看该作者
74AHC1G125  这个型号适用不？

74ahc1g125.png (96.69 KB, 下载次数: 39)

74ahc1g125.png
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表