找回密码
 立即注册

QQ登录

只需一步,快速开始

搜索
查看: 2624|回复: 0
打印 上一主题 下一主题
收起左侧

单片机数显大型交通灯控制汇编语言程序及proteus仿真

[复制链接]
跳转到指定楼层
楼主
交通灯仿真原理图如下(proteus仿真工程文件可到本帖附件中下载)


单片机汇编语言源程序如下:
  1. SNF   EQU  00H             ;;;南北通行标志位
  2. EWF   EQU  01H             ;;;东西通行标志位
  3. URF   EQU  02H             ;;;紧急事件标志位
  4. ORG   0000H
  5. LJMP  MAIN                 ;;;上电转主程序
  6. ORG   000BH                ;;;定时中断入口
  7. LJMP  DSZD                    
  8. ORG   0003H                ;;;紧急中断入口
  9. LJMP  URZD
  10. ORG   0030H   
  11. MAIN: LCALL INIT           ;;;调用初始化子程序
  12. LOOP: LCALL DIS            ;;;循环执行显示子程序
  13.       AJMP  LOOP
  14. ;///////////初始化程序
  15. INIT: SETB   SNF              
  16.       SETB   EWF           
  17.       SETB   URF           
  18.       MOV   R2,#20         ;;;定时器中断20次为1s
  19.       MOV   TMOD,#01H      ;;;初始化定时器
  20.       MOV   TL0,#0B0H
  21.       MOV   TH0,#3CH
  22.       SETB  EA             ;;;开定时中断与紧急中断
  23.       SETB  ET0
  24.       SETB  TR0
  25.       SETB  EX0
  26.       SETB  IT0            ;;;设置中断程控方式
  27.       MOV   DPTR,#TAB      ;;;数值首地址放入DPTR中
  28.       MOV   40H,#40        ;;;东南西北通行时间设置
  29.       MOV   41H,#40
  30.       MOV   30H,#40        ;;;通行时间初始化
  31.       MOV   31H,#60
  32.       MOV   P0,#4CH        ;;;初始化时南北通行并把交通灯状态分别放在32H和33H中
  33.       MOV   32H,#4CH
  34.       MOV   P2,#15H
  35.       MOV   33H,#15H
  36.       RET
  37. ;////////////显示子程序
  38. DIS:  MOV   P3,#0DFH       ;;;选中南北方向的十位数码管
  39.       MOV   A,30H          ;;;把显示数据送人数码管显示
  40.       MOV   B,#10
  41.       DIV   AB
  42.       MOVC  A,@A+DPTR
  43.       MOV   P1,A           ;;;
  44.       LCALL D1MS
  45.       MOV   P3,#0EFH       ;;;选中南北方向的个位数码管
  46.       MOV   A,B            ;;;送入数码管显示
  47.       MOVC  A,@A+DPTR      
  48.       MOV   P1,A
  49.       LCALL D1MS

  50.       MOV   P3,#7FH        ;;;选中第东西方向的十位数码管
  51.       MOV   A,31H          ;;;送入数码管显示
  52.       MOV   B,#10
  53.       DIV   AB
  54.       MOVC  A,@A+DPTR
  55.       MOV   P1,A
  56.       LCALL D1MS
  57.       MOV   P3,#0BFH       ;;;选中第东西方向的个位数码管
  58.       MOV   A,B
  59.       MOVC  A,@A+DPTR
  60.       MOV   P1,A
  61.       LCALL D1MS
  62.       SETB  P3.0
  63.       SETB  P3.1
  64.       JNB   P3.0,DIS_S     ;;;查询是否第一个按键按下
  65.       JNB   P3.1,DIS_E     ;;;查询是否第二个按键按下
  66.       AJMP  DIS_R          ;;;没有键按下则返回
  67. DIS_S:LCALL D5MS           ;;;按键去抖
  68.       JNB   P3.0,DIS_SN
  69.       AJMP  DIS_R   
  70. DIS_SN:MOV   40H,#50       ;;;对通行时间从新分配,南北通行时间加长
  71.        MOV   41H,#30
  72.        AJMP  DIS_R
  73. DIS_E:LCALL D5MS           ;;;按键去抖
  74.       JNB   P3.1,DIS_EW
  75.       AJMP  DIS_R
  76. DIS_EW:MOV   40H,#30       ;;;东西通行时间加长
  77.        MOV   41H,#50
  78. DIS_R:RET                  
  79. ;///////定时中断处理程序
  80. DS_C: LJMP  DS_R           ;;;接力跳转
  81. DSZD: PUSH  ACC            ;;;保护现场
  82.       PUSH  PSW
  83.       CLR   TR0            ;;;关定时器及中断标志位并重新赋值
  84.       CLR   TF0
  85.       MOV   TL0,#0B0H
  86.       MOV   TH0,#3CH
  87.       DJNZ  R2,DS_C        ;;;判断1m时间是否到达
  88.       MOV   R2,#20         ;;;到达重新赋值
  89.       DEC   30H            ;;;南北方向通行时间减一
  90.       MOV   A,30H          ;;;把减一后的时间送入显示存储单元
  91. ;;;;;;;南北通行到达最后4秒时黄灯闪烁
  92. DS_10:CJNE  A,#4,DS_11     ;;;如果通行时间剩余4秒
  93.       JNB   SNF,DS_11      ;;;判断是否是南北通行
  94.       MOV   P0,#8AH        
  95.       MOV   32H, #8AH      ;;;把交通灯状态存入存储单元(后面类似)
  96. DS_11:CJNE  A,#3,DS_12     ;;;不是剩余3秒,返回
  97.       JNB   SNF,DS_12      ;;;不是南北通行时间,返回
  98.       MOV   P0,#88H
  99.       MOV   32H, #88H
  100. DS_12:CJNE  A,#2,DS_13
  101.       JNB   SNF,DS_13
  102.       MOV   P0,#8AH
  103.       MOV   32H, #8AH
  104. DS_13:CJNE  A,#1,DS_14
  105.       JNB   SNF,DS_14
  106.       MOV   P0,#88H
  107.       MOV   32H, #88H
  108. ;------------------------
  109. DS_14:JNZ   DS_NE          ;;;通行时间没有结束转向改变东西方向的数码管
  110.       CPL   SNF            ;;;如果通行时间结束则对标志位取反
  111.       JNB   SNF,DS_1       ;;;判断是否南北通行
  112.       MOV   30H,40H        ;;;是,点亮相应的交通灯
  113.       MOV   P0,#4CH
  114.       MOV   32H,#4CH       ;;;存储交通灯状态
  115.       MOV   P2,#15H
  116.       MOV   33H, #15H      ;;;存储交通灯状态
  117. DS_NE:DEC   31H            ;;;东西方向通行时间减一
  118.       MOV   A,31H          ;;;把通行剩余时间送入显示存储单元
  119. ;;;;;;;;东西方向通行时间剩余4秒钟黄灯闪烁(程序注释与南北方向类似 略)
  120. DS_20:CJNE  A,#4,DS_21   
  121.       JB    EWF,DS_21
  122.       MOV   P0,#51H
  123.       MOV   32H, #51H
  124. DS_21:CJNE  A,#3,DS_22
  125.       JB    EWF,DS_22
  126.       MOV   P0,#41H
  127.       MOV   32H, #41H
  128. DS_22:CJNE  A,#2,DS_23
  129.       JB    EWF,DS_23
  130.       MOV   P0,#51H
  131.       MOV   32H, #51H
  132. DS_23:CJNE  A,#1,DS_24
  133.       JB    EWF,DS_24
  134.       MOV   P0,#41H
  135.       MOV   32H, #41H
  136. ;-----------------------------
  137. DS_24:JNZ   DS_R             ;;;东西方向时间没有结束,返回
  138.       CPL   EWF              ;;;对通行状态取反
  139.       JNB   EWF,DS_2         ;;;东西方向通行时间到来,跳转
  140.       MOV   31H,#80          ;;;东西方向通行结束,重新显示时间
  141.       MOV   P0,#89H          ;;;点亮相应的交通灯
  142.       MOV   32H, #89H
  143.       MOV   P2,#29H
  144.       MOV   33H, #29H
  145.       AJMP  DS_R     
  146. DS_1: MOV   30H,#80          ;;;南北通行时间结束,重新对显示存储单元赋值     
  147.       MOV   P0,#89H          ;;;执行转弯状态1
  148.       MOV   32H, #89H
  149.       MOV   P2,#26H
  150.       MOV   33H, #26H
  151.       AJMP  DS_NE            
  152. DS_2: MOV   31H,41H         ;;;东西方向开始通行,赋值予显示存储单元
  153.       MOV   P0,#61H         ;;;点亮相应的交通灯
  154.       MOV   32H, #61H
  155.       MOV   P2,#15H
  156.       MOV   33H, #15H
  157. DS_R: SETB  TR0
  158.       POP   PSW             ;;;恢复现场
  159.       POP   ACC
  160.       RETI
  161. ;/////////////紧急中断处理程序
  162. URZD: PUSH  ACC             ;;;保护现场
  163.       PUSH  PSW
  164.       CLR   IE0             ;;;清除中断标志位
  165.       CLR   TR0             ;;;关定时器
  166.       CPL   URF             ;;;紧急事件标志位
  167.       JB    URF,UR_CON      ;;;紧急结束;跳转
  168.       MOV   P0,#49H         ;;;各路口灯全显示红灯亮
  169.       MOV   P2,#15H
  170.       AJMP  UR_R
  171. UR_CON:SETB  TR0            ;;;恢复正常交通
  172.       MOV   A,32H
  173.       MOV   P0,A
  174.       MOV   A,33H
  175.       MOV   P2,A
  176. UR_R: POP   PSW             ;;;恢复现场
  177.       POP   ACC
  178.       RETI      
  179. ;////////////查表指令0,1,2,3,4,5,6,7,8,9
  180. TAB:  DB  3FH,  06H,  5BH,  4FH,  66H,  6DH
  181.       DB  7DH,  07H,  7FH,  6FH

  182. ;//////////延时5ms与1ms
  183. D5MS:  MOV    R7,#5
  184. D1MS:  MOV    R7,#10
  185.        MOV    R6,#50
  186. L1:    DJNZ   R6,$
  187.        DJNZ   R7,L1
  188.        RET
  189.        END


复制代码

所有资料51hei提供下载:
数显大型交通灯控制.rar (53.38 KB, 下载次数: 36)


分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏1 分享淘帖 顶 踩
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表