设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › MCU综合技术区 › 基于51单片机的有害气体检测程序（汇编）
返回列表 发新帖
查看: 5144|回复: 2
打印 上一主题 下一主题
收起左侧

基于51单片机的有害气体检测程序（汇编）

[复制链接]
跳转到指定楼层
楼主
ID:70976 发表于 2014-12-26 22:35 | 只看该作者 回帖奖励 |倒序浏览 |阅读模式


  3.           LCD_X  EQU   23H        ;LCD 地址变量（决定文字的在LCD上的显示位置）
  4.           FSJCQ  EQU   33H        ;TMOD工作方式暂存寄存器
  5.           BJZC   EQU   34H        ;需要比较数据暂存寄存器，用于报警显示
  6.           BJWX   EQU   35H        ;超标设定值暂存寄存器
  7.           BJJG   EQU   36H        ;偏高设定值暂存寄存器
  8.           JJCQ   EQU   37H        ;酒精显示0%暂存寄存器
  9.           YYBZ   EQU   38H        ;语音播放标志
  10.           DJSJCQ EQU   39H        ;10S倒计时寄存器
  11.           JJCYCS EQU   4AH        ;酒精检测采样次数寄存器

  13.           XSYSSJ    DATA   5      ;正常时显示延时时间

  15.           WXBJZ1  EQU   100       ;有害气体危险报警设定值200PPM
  16.                                   ;实际设定值=200（显示设定值）/2（修正倍率）
  17.           JGBJZ1  EQU   60        ;有害气体警告报警设定值120PPM
  18.                                   ;实际设定值=120（显示设定值）/2（修正倍率）
  19.           WXBJZ2  EQU   50        ;酒精危险报警设定值0.05% BAC
  20.                                   ;实际设定值=0.05%（显示设定值）*1000（显示位修正）/1（修正倍率）
  21.           JGBJZ2  EQU   20        ;酒精警告报警设定值0.02% BAC
  22.                                   ;实际设定值=0.02%（显示设定值）*1000（显示位修正）/1（修正倍率）
  23.           XIUZ1   EQU   10        ;有害气体浓度显示数据修正值，设置大时则显示数值小，反之显示大
  24.           XIUZ2   EQU   34        ;酒精浓度显示数据修正值，设置大时则显示数值小，反之显示大

  26. ;-----------------------------------------------------------
  27.           LCD_RS    EQU   P4.0    ;LCD 数据/命令选择端
  28.           LCD_RW    EQU   P4.1    ;LCD 读/写选择端
  29.           LCD_EN    EQU   P4.2    ;LCD 使能信号
  30.           LCD_BG    EQU   P4.3    ;LCD 背光控制端
  31.           LCD_SJ    EQU   P0      ;LCD 数据

  33.           BITE      EQU   9       ;串口发送9位数据
  34.           FSSZ      EQU   40H     ;主机发送的数据块首址
  35.           JSSZ      EQU   50H     ;主机接收的数据块首址

  37.           YY_DAT    DATA  29H     ;语音段地址存放单元
  38.           YYRST     EQU   P3.3    ;语音模块复位信号引脚
  39.           BUSY      EQU   P1.0    ;语音忙控制端，0为正在播放1为没有播放空闲时
  40.           YYSDA     EQU   P1.1    ;语音模块数据线引脚

  42. ;===========================================================
  43.           ORG  0000H
  44.           AJMP  MAIN
  45.           ORG  0003H       ;外中断0中断程序入口
  46.           RETI                ;中断返回
  47.           ORG  000BH          ;定时器T0中断程序入口
  48.           RETI                ;中断返回
  49.           ORG  0013H       ;外中断1中断入口
  50.           RETI               ;中断返回
  51.           ORG  001BH       ;定时器T1中断程序入口
  52.           RETI             ;跳至INTT1中断服务程序
  53.           ORG  0023H       ;串口中断入口地址
  54.           RETI               ;中断返回

  56.           ORG  0100H
  57. ;=========================================
  58. ;以下初始化程序
  59. ;=========================================
  60. MAIN:     MOV  SP,#60H
  61.           CLR  LCD_BG         ;打开LCD背光
  62.           LCALL  SET_LCD      ;初始化 LCD
  63.           MOV  R0,#20H        ;将20H-7FH 单元清零
  64.           MOV  R1,#95
  65. CLEAR:    MOV  @R0,A
  66.           INC  R0
  67.           DJNZ  R1,CLEAR

  69. ;=========================================
  70. ;以下为主程序
  71. ;=========================================
  72. ;以下为有害气体浓度显示和报警程序
  73. YHJCCX:   LCALL  MENU_3       ;显示菜单1
  74.           MOV R2,#0AH         ;与10号从机串口通信，多功能板地址为0AH
  75.           MOV R3,#01H         ;主机要求从机发送数据块
  76.           LCALL COM           ;主机与多功能检测板串口通信，要求其发送9个字节数据块

  78.           MOV A,JSSZ+1        ;取出传感器检测到的电压读数（原始数据，16进制）
  79.           MOV B,#2            ;显示修正倍率，原始数*倍率+修正值=LCD显示值
  80.           SUBB A,#XIUZ1       ;显示修正
  81.           JNC LBB1            ;软件调整初值
  82.           MOV A,#0            ;使之正常时显示0
  83. LBB1:     LCALL HEX2BCD1      ;调用数值转换程序
  84.           LCALL CONV100       ;调用LCD显示程序
  85.           MOV BJZC,JSSZ+1     ;取出传感器检测到的电压读数（原始数据），做报警比较
  86.           MOV BJWX,#WXBJZ1+XIUZ1 ;实际危险报警值=设定值/倍率+修正值
  87.           MOV BJJG,#JGBJZ1+XIUZ1 ;实际警告报警值=设定值/倍率+修正值
  88.           MOV YYBZ,#JSSZ+1    ;设有害气体语音播放标志
  89.           LCALL BJBJ1         ;调用报警程序

  91.           JB P3.4,LBB5
  92.           LCALL DELAY2
  93.           JB P3.4,LBB5
  94.           LCALL JJJCCX

  96. LBB5:     LCALL DELAY3

  98.           SJMP YHJCCX

  100. ;以下为酒精浓度显示和报警程序
  101. JJJCCX:   MOV JJCYCS,#5       ;设酒精检测轮回采样次数
  102.           LCALL JIUJJC        ;显示准备进入酒精检测程序的画面
  103. JJJCCX1:  MOV R2,#0AH         ;与10号从机串口通信，多功能板地址为0AH
  104.           MOV R3,#01H         ;主机要求从机发送数据块
  105.           LCALL COM           ;主机与多功能检测板串口通信，要求其发送9个字节数据块
  106.           LCALL  MENU_4       ;显示菜单1
  107.           MOV A,JSSZ+2        ;取出传感器检测到的电压读数（原始数据，16进制）
  108.           MOV B,#1            ;显示修正倍率，原始数*倍率+修正值=LCD显示值
  109.           SUBB A,#XIUZ2       ;显示修正
  110.           JNC LBB2            ;软件调整初值
  111.           MOV A,#0            ;使之正常时显示0%
  112. LBB2:     LCALL HEX2BCD1      ;调用数值转换程序
  113.           LCALL CONV200       ;调用LCD显示程序
  114.           MOV BJZC,JSSZ+2     ;取出传感器检测到的电压读数（原始数据），做报警比较
  115.           MOV BJWX,#WXBJZ2+XIUZ2 ;实际危险报警值=设定值/倍率+修正值
  116.           MOV BJJG,#JGBJZ2+XIUZ2 ;实际警告报警值=设定值/倍率+修正值

  118.           LCALL DELAY3        ;延时，使其能看清楚看到检测到的数值

  120.           DEC JJCYCS
  121.           MOV A,JJCYCS
  122.           JNZ JJJCCX1         ;连续采样几次（未到则返回）

  124.           JNB BUSY,$          ;如果语言正在播放，则等待
  125.           MOV YY_DAT,#6       ;报出“检测完毕”
  126.           LCALL YUYIN         ;开始语音播放
  127.           LCALL DELAY
  128.           LCALL DELAY
  129.           MOV YYBZ,#JSSZ+2    ;设酒精报警语音播放标志
  130.           LCALL BJBJ1         ;调用报警程序
  131.           LCALL DELAY3        ;延时
  132.           RET

  134. ;***************************************************
  135. ;=========================================
  136. ;以下为两个单字节十六进制相乘
  137. ;入口：A*B
  138. ;出口：16位低字节放A中，高字节放B中
  139. ;=========================================
  140. HEX2BCD1: MUL AB
  141.           MOV R6,B
  142.           MOV R7,A
  143.           MOV JJCQ,A        ;为显示0%作准备
  144. ;=========================================
  145. ;以下为双字节十六进制整数转换成双字节BCD码整数
  146. ;入口条件：待转换的双字节十六进制整数在R6、R7中。
  147. ;出口信息：转换后的三字节BCD码整数在R3、R4、R5中。
  148. ;影响资源：PSW、A、R2～R7，堆栈需求：２字节
  149. ;=========================================         
  150.           CLR A             ;BCD码初始化
  151.           MOV R3,A
  152.           MOV R4,A
  153.           MOV R5,A
  154.           MOV R2,#10H       ;转换双字节十六进制整数
  155. HB3:      MOV A,R7          ;从高端移出待转换数的一位到CY中
  156.           RLC A
  157.           MOV R7,A
  158.           MOV A,R6
  159.           RLC A
  160.           MOV R6,A
  161.           MOV A,R5          ;BCD码带进位自身相加，相当于乘2
  162.           ADDC A,R5
  163.           DA A              ;十进制调整
  164.           MOV R5,A
  165.           MOV A,R4
  166.           ADDC A,R4
  167.           DA A
  168.           MOV R4,A
  169.           MOV A,R3
  170.           ADDC A,R3
  171.           MOV R3,A          ;双字节十六进制数的万位数不超过6，不用调整
  172.           DJNZ R2,HB3       ;处理完16bit

  174. ;=========================================
  175. ;以下为把BCD码提取出并送显示寄存器70H～73H
  176. ;入口：;三字节BCD码整数在R3（高位为十万低位为万）、
  177. ;R4（高位为千低位为百）、R5（高位为十低位为个）中。
  178. ;出口：73H-70H（舍去十万、万位）
  179. ;=========================================
  180.           MOV A,R4
  181.           ANL A,#11110000B
  182.           SWAP A
  183.           MOV 73H,A
  184.           MOV A,R4
  185.           ANL A,#00001111B
  186.           MOV 72H,A
  187.           MOV A,R5
  188.           ANL A,#11110000B
  189.           SWAP A
  190.           MOV 71H,A
  191.           MOV A,R5
  192.           ANL A,#00001111B
  193.           MOV 70H,A

  195.           RET

  197. ;==============================================
  198. ;以下为LCD显示有害气体程序
  199. ;72H-70H 分别存放百位、十位、个位的数据
  200. ;==============================================
  201. CONV100:  MOV  A,73H         ;加载百位数据
  202.           MOV  LCD_X,#1      ;设置显示位置
  203.           CJNE A,#00H,CONV110
  204.           MOV  A,#" "        ;百位数等于0显示空格
  205.           MOV  B,LCD_X
  206.           CALL  LCDP2
  207.           MOV  A,72H         ;十位
  208.           CJNE A,#00H,CONV120
  209.           INC  LCD_X         ;调整显示地址
  210.           MOV  A,#" "        ;十位数等于0显示空格
  211.           MOV  B,LCD_X
  212.           CALL  LCDP2
  213.           MOV  A,71H         ;十位
  214.           CJNE A,#00H,CONV130
  215.           INC  LCD_X         ;调整显示地址
  216.           MOV  A,#" "        ;十位数等于0显示空格
  217.           MOV  B,LCD_X
  218.           CALL  LCDP2
  219.           JMP  CONV140

  221. CONV110:  CALL  SHOW_DIG2    ;显示数据

  223. CONV120:  INC  LCD_X         ;调整显示地址
  224.           MOV  A,72H         ;十位
  225.           CALL  SHOW_DIG2

  227. CONV130:  INC  LCD_X         ;调整显示地址
  228.           MOV  A,71H         ;十位
  229.           CALL  SHOW_DIG2

  231. CONV140:  INC  LCD_X         ;调整显示地址
  232.           MOV  A,70H         ;个位
  233.           CALL  SHOW_DIG2

  235.           RET
  236. ;=================================================
  237. ;以下为LCD显示酒精浓度程序
  238. ;73H-70H 分别存放个位、小数后1位、后2位、后3位的数据
  239. ;=================================================
  240. CONV200:  MOV A,JJCQ
  241.           JNZ BBL1
  242.           MOV LCD_X,#0       ;当个位、十、百、千分位均为零时显示0%
  243.           MOV R0,#00H
  244. BBL2:     MOV A,#' '
  245.           MOV B,LCD_X
  246.           CALL LCDP2
  247.           INC LCD_X
  248.           INC R0
  249.           CJNE R0,#4,BBL2
  250.           MOV R0,#00H
  251.           CLR A              ;个位
  252.           CALL SHOW_DIG2
  253.           RET

  255. BBL1:     MOV  A,73H         ;加载个位数据
  256.           MOV  LCD_X,#0      ;设置显示位置
  257.           CALL  SHOW_DIG2    ;显示数据

  259.           INC  LCD_X         ;调整显示地址
  260.           MOV  A,#'.'
  261.           MOV  B,LCD_X
  262.           CALL  LCDP2

  264.           SJMP CONV120

  266. ;=========================================
  267. ;LCD 显示菜单1
  268. ;=========================================
  269. MENU_3:   MOV  DPTR,#M_OK31  ;指针指到显示信息区
  270.           MOV  A,#1          ;显示在第一行
  271.           CALL  LCD_PRINT
  272.           MOV  DPTR,#M_OK32  ;指针指到显示信息区
  273.           MOV  A,#2          ;显示在第二行
  274.           CALL  LCD_PRINT
  275.           MOV  DPTR,#M_OK33  ;指针指到显示信息区
  276.           MOV  A,#3          ;显示在第二行
  277.           CALL  LCD_PRINT
  278.           MOV  DPTR,#M_OK34  ;指针指到显示信息区
  279.           MOV  A,#4          ;显示在第二行
  280.           CALL  LCD_PRINT
  281.           RET
  282. M_OK31:   DB"有害气体浓度：  ",0
  283. M_OK32:   DB"           PPM  ",0
  284. M_OK33:   DB"检测结果：      ",0
  285. M_OK34:   DB"                ",0

  287. ;=========================================
  288. ;LCD 显示菜单2
  289. ;=========================================
  290. MENU_4:   MOV  DPTR,#M_OK41  ;指针指到显示信息区
  291.           MOV  A,#1          ;显示在第一行
  292.           CALL  LCD_PRINT
  293.           MOV  DPTR,#M_OK42  ;指针指到显示信息区
  294.           MOV  A,#2          ;显示在第二行
  295.           CALL  LCD_PRINT
  296.           MOV  DPTR,#M_OK43  ;指针指到显示信息区
  297.           MOV  A,#3          ;显示在第二行
  298.           CALL  LCD_PRINT
  299.           MOV  DPTR,#M_OK44  ;指针指到显示信息区
  300.           MOV  A,#4          ;显示在第二行
  301.           CALL  LCD_PRINT
  302.           RET
  303. M_OK41:   DB"酒精浓度：    ",0
  304. M_OK42:   DB"          % BAC ",0
  305. M_OK43:   DB"检测结果：      ",0
  306. M_OK44:   DB"                ",0

  308. ;=========================================
  309. ;LCD 显示菜单3
  310. ;=========================================
  311. MENU_5:   MOV  DPTR,#M_OK51  ;指针指到显示信息区
  312.           MOV  A,#1          ;显示在第一行
  313.           CALL  LCD_PRINT
  314.           MOV  DPTR,#M_OK52  ;指针指到显示信息区
  315.           MOV  A,#2          ;显示在第二行
  316.           CALL  LCD_PRINT
  317.           MOV  DPTR,#M_OK53  ;指针指到显示信息区
  318.           MOV  A,#3          ;显示在第二行
  319.           CALL  LCD_PRINT
  320.           MOV  DPTR,#M_OK54  ;指针指到显示信息区
  321.           MOV  A,#4          ;显示在第二行
  322.           CALL  LCD_PRINT
  323.           RET
  324. M_OK51:   DB"进入酒精检测程序",0
  325. M_OK52:   DB"传感器预热请稍等",0
  326. M_OK53:   DB"...  ... ",0
  327. M_OK54:   DB"倒计时：    S  ",0

  329. ;=========================================
  330. ;LCD 显示菜单4
  331. ;=========================================
  332. MENU_6:   MOV  DPTR,#M_OK61  ;指针指到显示信息区
  333.           MOV  A,#1          ;显示在第一行
  334.           CALL  LCD_PRINT
  335.           MOV  DPTR,#M_OK62  ;指针指到显示信息区
  336.           MOV  A,#2          ;显示在第二行
  337.           CALL  LCD_PRINT
  338.           MOV  DPTR,#M_OK63  ;指针指到显示信息区
  339.           MOV  A,#3          ;显示在第二行
  340.           CALL  LCD_PRINT
  341.           MOV  DPTR,#M_OK64  ;指针指到显示信息区
  342.           MOV  A,#4          ;显示在第二行
  343.           CALL  LCD_PRINT
  344.           RET
  345. M_OK61:   DB"现在开始酒精检测",0
  346. M_OK62:   DB"注意：          ",0
  347. M_OK63:   DB"嘴巴要距离传感器",0
  348. M_OK64:   DB"5---10cm轻轻吹气",0
  349. ;=========================================
  350. ;以下为主机串行通信程序
  351. ;占用资源：R0～R4,A、40H、50H
  352. ;=========================================
  353. COM:   MOV A,TMOD           ;设置T1工作方式为方式2、T0工作方式保持不变
  354.        MOV FSJCQ,A
  355.        ORL A,#00101111B
  356.        MOV TMOD,A
  357.        MOV TH1,#0FDH        ;11.0592MHz 晶振,波特率=9600，时长0.6695
  358.        MOV TL1,#0FDH
  359.        MOV SCON,#0D8H       ;置串行模式3，SM2=1,允许接收
  360.        SETB TR1             ;启动T1
  361.        LCALL COM1           ;调用一线发码子程序
  362.        MOV TMOD,FSJCQ       ;恢复T1、T0原先的工作方式
  363.        RET

  365. COM1:   MOV A,R2            ;发送地址帧
  366.         MOV SBUF,A
  367.         JNB TI,$
  368.         CLR TI
  369.         JNB RI,$            ;等待从机应答
  370.         CLR RI
  371.         MOV A,SBUF
  372.         XRL A,R2
  373.         JNZ MS104           ;判应答地址是否相符
  374.         CLR TB8             ;地址符合，准备发送命令
  375.         MOV SBUF,R3         ;发送发送或接收数据命令
  376.         JNB TI,$
  377.         CLR TI
  378.         JNB RI,$            ;等待从机应答
  379.         CLR RI
  380.         MOV A,SBUF          ;取应答信息
  381.         JNB ACC.7,MS102     ;判断是否出错
  382. MS101:  SETB TB8
  383.         MOV SBUF,#0FFH      ;不相符重新联络
  384.         JNB TI,$
  385.         CLR TI
  386.         SJMP COM1           ;转重发地址

  388. MS102:  CJNE R3,#00H,MS103  ;判是否要求从机接收数据
  389.         JNB ACC.0,MS101     ;从机接收数据准备就绪否？
  390.         MOV R0,#FSSZ        ;主机发送的数据块首址
  391.         MOV R4,#BITE        ;设数据块长度(9字节)
  392. LPTX:   MOV SBUF,@R0        ;主机发送数据块
  393.         JNB TI,$            ;等待发送完1帧
  394.         CLR TI
  395.         INC R0              ;修改地址指针
  396.         DJNZ R4,LPTX        ;判数据块是否传完
  397.         SJMP MS104          ;返回主程序

  399. MS103:  JNB ACC.1,MS101     ;从机发送数据准备就绪否？
  400.         MOV R1,#JSSZ        ;主机接收的数据块首址
  401.         MOV R4,#BITE        ;设数据块长度(9字节)
  402. LPRX:   JNB RI,LPRX         ;等待接收完1帧
  403.         CLR RI
  404.         MOV A,SBUF          ;取出接收到的字符
  405.         MOV @R1,A
  406.         INC R1
  407.         DJNZ R4,LPRX        ;未接收完则继续

  409. MS104:  CLR TR1             ;关闭T1
  410.         RET


  413. ;=========================================
  414. ;报警比较和显示程序
  415. ;有害气体浓度：≥200PPM→语音报警并 显示"浓度超标，危险！"
  416. ;             ≥120PPM→语音报警并 显示"浓度偏高，请注意！"
  417. ;             ＜120PPM→语音不报警 显示"浓度未超标"
  418. ;酒精浓度：   ≥0.05% BCA→语音报警并 显示"浓度超标，危险！"
  419. ;            ≥0.02% BCA→语音报警并 显示"浓度偏高，请注意！"
  420. ;            ＜0.02% BCA→语音不报警 显示"浓度未超标"
  421. ;=========================================
  422. BJBJ1:    MOV A,BJZC
  423.           SUBB A,BJWX          ;与超标设定值进行比较
  424.           JC BL2

  426.           LCALL WENZBJ1        ;显示菜单1
  427.           LCALL DELAY          ;延时
  428.           LCALL DELAY          ;延时
  429.           LCALL WENZBJ4        ;显示菜单1-4,形成闪烁效果
  430.           LCALL DELAY          ;延时
  431.           LCALL DELAY          ;延时
  432.           LCALL WENZBJ1        ;显示菜单1

  434.           MOV A,YYBZ
  435.           CJNE A,#JSSZ+1,BL1   ;语音段播放识别
  436.           MOV YY_DAT,#2        ;有害气体检测时报出“车内有害气体浓度过高，请排除”
  437.           SJMP BL4
  438. BL1:      CJNE A,#JSSZ+2,BL6   ;语音段播放识别
  439.           MOV YY_DAT,#9        ;酒精检测时报出“酒精浓度偏高，你是不是喝酒了，要小心开车哦”
  440.           SJMP BL4

  442. BL2:      MOV A,BJZC           ;取ACC读数值（存在45H里）               ;
  443.           SUBB A,BJJG          ;与偏高设定值进行比较
  444.           JC BL5               ;
  445.           LCALL WENZBJ2        ;显示菜单2

  447.           LCALL DELAY          ;延时
  448.           LCALL DELAY          ;延时
  449.           LCALL WENZBJ4        ;显示菜单4,形成闪烁效果
  450.           LCALL DELAY          ;延时
  451.           LCALL DELAY          ;延时
  452.           LCALL WENZBJ2        ;显示菜单2

  454.           MOV A,YYBZ
  455.           CJNE A,#JSSZ+1,BL3   ;语音段播放识别
  456.           JNB BUSY,$
  457.           MOV YY_DAT,#2        ;有害气体检测时报出“车内有害气体浓度过高，请排除”
  458.           SJMP BL4
  459. BL3:      CJNE A,#JSSZ+2,BL6   ;语音段播放识别
  460.           JNB BUSY,$
  461.           MOV YY_DAT,#8        ;酒精检测时报出“酒精浓度过高，你喝多了，为了您的安全，请不要开车”
  462. BL4:      LCALL YUYIN          ;开始语音播放
  463.           SJMP BL6

  465. BL5:      LCALL WENZBJ3        ;显示菜单1-3
  466.           MOV A,YYBZ
  467.           CJNE A,#JSSZ+2,BL6   ;语音段播放识别
  468.           JNB BUSY,$
  469.           MOV YY_DAT,#7        ;酒精检测时报出“酒精浓度没有超标”
  470.           LCALL YUYIN          ;开始语音播放

  472. BL6:      RET

  474. WENZBJ1:  MOV  DPTR,#BJ10      ;超标显示的内容
  475.           SJMP BL7
  476. WENZBJ2:  MOV  DPTR,#BJ20      ;偏高显示的内容
  477.           SJMP BL7
  478. WENZBJ3:  MOV  DPTR,#BJ30      ;未超标显示的内容
  479.           SJMP BL7
  480. WENZBJ4:  MOV  DPTR,#BJ40      ;未超标显示的内容
  481. BL7:      MOV  A,#98H          ;设置 LCD 显示的地址（第四行）
  482.           CALL  WCOM           ;写入指令
  483. BL8:      CLR  A               ;填入字符
  484.           MOVC  A,@A+DPTR      ;由信息区取出字符
  485.           CJNE  A,#0,BL9       ;判断是否为结束码
  486.           RET
  487. BL9:      CALL  WDATA          ;写入数据
  488.           INC  DPTR            ;指针加1
  489.           JMP  BL8             ;继续填入字符

  491. BJ10:     DB "浓度超标，危险！",0
  492. BJ20:     DB "浓度偏高，请注意",0
  493. BJ30:     DB "  浓度没有超标  ",0
  494. BJ40:     DB "                ",0

  496. ;***********************************************************
  497. JIUJJC:   MOV FSSZ+1,#01H     ;命令10号从机打开有害气体传感器
  498.           MOV R2,#0AH         ;与10号从机串口通信，多功能板地址为0AH
  499.           MOV R3,#00H         ;主机要求从机接收数据块
  500.           LCALL COM           ;主机与多功能检测板串口通信，要求其接收9个字节数据块
  501.           MOV YY_DAT,#3       ;报出“现在进入酒精检测程序，请等待十秒钟”
  502.           JNB BUSY,$
  503.           LCALL YUYIN         ;开始语音播放
  504.           ACALL MENU_5
  505.           JNB BUSY,$
  506.           MOV DJSJCQ,#10
  507.           MOV A,DJSJCQ
  508. K2:       MOV B,#1
  509.           LCALL HEX2BCD1      ;调用数值转换程序
  510.           LCALL CONV300       ;调用LCD显示程序
  511.           MOV A,#3            ;延时
  512. LBB23:    LCALL DELAY
  513.           DEC A
  514.           JNZ LBB23
  515.           DEC DJSJCQ
  516.           MOV A,DJSJCQ
  517.           CJNE A,#00H,K2
  518.           MOV YY_DAT,#4       ;报出“现在开始酒精检测”
  519.           JNB BUSY,$
  520.           LCALL YUYIN         ;开始语音播放
  521.           ACALL MENU_6
  522.           MOV A,#10           ;延时
  523. LBB33:    LCALL DELAY
  524.           DEC A
  525.           JNZ LBB33
  526.           MOV YY_DAT,#5       ;报出“请把嘴巴对准探头轻轻吹气”
  527.           JNB BUSY,$
  528.           LCALL YUYIN         ;开始语音播放
  529.           RET

  531. CONV300:  MOV  A,71H          ;十位
  532.           CJNE A,#00H,K3
  533.           MOV A,#9CH          ;调整显示地址
  534.           CALL  WCOM          ;写入命令
  535.           MOV  A,#" "         ;百位数等于0显示空格
  536.           CALL  WDATA         ;写入数据
  537.           SJMP K4
  538. K3:       MOV A,#9CH          ;调整显示地址
  539.           CALL  WCOM          ;写入命令
  540.           MOV  A,71H
  541.           ADD  A,#30H         ;加30H，转换为ASCII码
  542.           CALL  WDATA         ;写入数据

  544. K4:       MOV A,#9DH          ;调整显示地址
  545.           CALL  WCOM          ;写入命令
  546.           MOV  A,70H
  547.           ADD  A,#30H         ;加30H，转换为ASCII码
  548.           CALL  WDATA         ;写入数据
  549.           RET
  550. ;-------------------------------------------------------







  558. ;以下程序通用

  560. ;=============================================
  561. ;在LCD的第二行显示数据字符
  562. ;A=ASCII 数据, B=位置变量
  563. ;==============================================
  564. LCDP2:    PUSH  ACC           ;在LCD的第二行显示字符
  565.           MOV  A,B            ;设置显示地址
  566.           ADD  A,#90H         ;设置LCD的第二行地址
  567.           CALL  WCOM          ;写入命令
  568.           POP  ACC            ;由堆栈取出A
  569.           CALL  WDATA         ;写入数据
  570.           RET
  571. ;-------------------------------------------------------
  572. SHOW_DIG2:                   ;在 LCD 的第二行显示数字
  573.           ADD  A,#30H        ;加30H，转换为ASCII码
  574.           MOV  B,LCD_X       ;确定显示位置
  575.           CALL  LCDP2        ;送显示
  576.           RET

  578. ;=================================================
  579. ;对 LCD 做初始化设置
  580. ;=================================================
  581. SET_LCD:  MOV A,#34H      ;34H--扩充指令操作
  582.           CALL  WCOM         ;写入命令
  583.    MOV A,#30H      ;30H--基本指令操作
  584.           CALL  WCOM         ;写入命令
  585.    MOV A,#01H      ;清除显示
  586.           CALL  WCOM         ;写入命令
  587.           MOV A,#06H      ;指定在资料写入或读取时，光标的移动方向
  588.           CALL  WCOM         ;DDRAM 的地址计数器(AC)加1
  589.    MOV A,#0CH      ;开显示,关光标,不闪烁
  590.           CALL  WCOM         ;写入命令
  591.           RET

  593. ;===============================================
  594. ;命令写入子程序
  595. ;RS=L,RW=L,D0-D7=指令码，E=高脉冲
  596. ;以8位控制方式将命令写至LCD
  597. ;===============================================
  598. WCOM:    LCALL CHK_BUSY       ;写入指令
  599.   CLR LCD_RS
  600.   CLR LCD_RW
  601.   MOV LCD_SJ,A
  602.   SETB LCD_EN
  603.   NOP
  604.   NOP
  605.   CLR LCD_EN
  606.   RET
  607. ;===============================================
  608. ;数据写入子程序
  609. ;RS=H,RW=L,D0-D7=指令码，E=高脉冲
  610. ;以8位控制方式将数据写至LCD
  611. ;===============================================
  612. WDATA:    MOV  LCD_SJ,A       ;写入数据
  613.           SETB  LCD_RS
  614.           CLR  LCD_RW
  615.           SETB  LCD_EN
  616.           CALL  DE
  617.           CLR  LCD_EN
  618.           CALL  DE
  619.           RET
  620. ;===============================================
  621. ;测LCD忙碌子程序
  622. ;RS=0,RW=1,E=H,D0-D7=状态字
  623. ;===============================================
  624. CHK_BUSY: MOV LCD_SJ,#0FFH   ;测忙碌子程序
  625.    CLR LCD_RS
  626.    SETB LCD_RW
  627.    SETB LCD_EN
  628.    JB LCD_SJ.7,$
  629.    CLR LCD_EN
  630.    RET

  632. ;==================================================
  633. ;在LCD的显示字符串
  634. ;DPTR = 放字符串的地址
  635. ;==================================================
  636. LCD_PRINT:CJNE  A,#1,LINE2  ;判断是否为第一行
  637. LINE1:    MOV  A,#80H       ;设置 LCD 的第一行地址
  638.           CALL  WCOM        ;写入命令
  639.           CALL  CLR_LINE    ;清除该行字符数据
  640.           MOV  A,#80H       ;设置 LCD 的第一行地址
  641.           CALL  WCOM        ;写入命令
  642.           JMP  FILL

  644. LINE2:    CJNE  A,#2,LINE3  ;判断是否为第二行
  645.           MOV  A,#90H       ;设置 LCD 的第二行地址
  646.           CALL  WCOM        ;写入命令
  647.           CALL  CLR_LINE    ;清除该行字符数据
  648.           MOV  A,#90H       ;设置 LCD 的第二行地址
  649.           CALL  WCOM
  650.           JMP  FILL

  652. LINE3:    CJNE  A,#3,LINE4  ;判断是否为第三行
  653.           MOV  A,#88H       ;设置 LCD 的第三行地址
  654.           CALL  WCOM        ;写入命令
  655.           CALL  CLR_LINE    ;清除该行字符数据
  656.           MOV  A,#88H       ;设置 LCD 的第三行地址
  657.           CALL  WCOM
  658.           JMP  FILL

  660. LINE4:    MOV  A,#98H       ;设置 LCD 的第四行地址
  661.           CALL  WCOM        ;写入命令
  662.           CALL  CLR_LINE    ;清除该行字符数据
  663.           MOV  A,#98H       ;设置 LCD 的第四行地址
  664.           CALL  WCOM

  666. FILL:     CLR  A            ;填入字符
  667.           MOVC  A,@A+DPTR   ;由信息区取出字符
  668.           CJNE  A,#0,LC1    ;判断是否为结束码
  669.           RET

  671. LC1:      CALL  WDATA       ;写入数据
  672.           INC  DPTR         ;指针加1
  673.           JMP  FILL         ;继续填入字符
  674. ;===============================================
  675. ;清除一行 LCD 的字符
  676. ;输入一行空格，来替代原显示字符
  677. ;===============================================
  678. CLR_LINE: MOV  R0,#16       ;清除该行 LCD 的字符
  679. CL1:      MOV  A,#' '
  680.           CALL  WDATA
  681.           DJNZ  R0,CL1
  682.           RET
  683. ;**********************************************************
  684. ;延时子程序
  685. ;**********************************************************
  686. DE:      MOV  R7,#229        ;延时 500 微秒,此条2个机器周期
  687.          DJNZ  R7,$
  688.          RET    ;此条2个机器周期，总延时（229*2+2+2）*(12/11.0592)≈500uS

  690. DELAY:   MOV  R5,#20         ;延时200MS
  691. DELAY1:  MOV  R6,#96         ;100
  692. DL1:     MOV  R7,#96         ;100
  693.          DJNZ  R7,$
  694.          DJNZ  R6,DL1
  695.          DJNZ  R5,DELAY1     ;96*2*48*(12/11.0592)+2*(12/11.0592)≈10000uS=10mS
  696.          RET        

  698. DELAY2:  MOV  R6,#10         ;延时5MS
  699. DL2:     MOV  R7,#229        ;100微秒
  700.          DJNZ  R7,$
  701.          DJNZ  R6,DL2
  702.          DJNZ  R5,DELAY2
  703.          RET

  705. DELAY3:  MOV  R5,#20         ;延时200MS
  706. DELA:    MOV  R6,#96
  707. DL3:     MOV  R7,#96
  708.          DJNZ  R7,$
  709.          DJNZ  R6,DL3
  710.          DJNZ  R5,DELA
  711.          RET   
  712. ;**********************************************************
  713. ;语音驱动和播放程序
  714. ;**********************************************************
  715. ;50H为语音段地址暂存器，1到210段，实际用到40
  716. ;50H为E0H～E7H时分别代表自低往高的8级音量
  717. ;在语音播放过程中发送F2H至50H可循环播放当前地址语音
  718. ;发送FEH至50H停止播放语音
  719. ;****************************************************
  720. YUYIN: MOV A,TMOD          ;设置T1工作方式为方式1、T0工作方式保持不变
  721.        MOV FSJCQ,A
  722.        ORL A,#00011111B
  723.        MOV TMOD,A
  724.        MOV R6,#08H         ;发码8位循环数据
  725.        LCALL ONE_LINE      ;调用一线发码子程序
  726.        MOV TMOD,FSJCQ          ;恢复T1、T0原先的工作方式
  727.        RET

  729. ONE_LINE:                  ;////一线发码子程序
  730.        SETB YYRST          ;复位
  731.        MOV R7,#2           ;延时2MS
  732.        LCALL DELAY1MS
  733.        CLR YYRST           ;延时使系统稳定
  734.        MOV R7,#6           ;延时6MS
  735.        LCALL DELAY1MS
  736.        CLR YYSDA           ;唤醒语音芯片
  737.        MOV R7,#17          ;延时17MS
  738.        LCALL DELAY1MS
  739.        MOV A,YY_DAT

  741. LP1:   SETB YYSDA
  742.        RRC A               ;分辨50H内的数据各位是高电平还是低电平
  743.        JNC DIDIANPIN       ;高电平用高:低=2:1的脉宽表示
  744.        LCALL DELAY200US
  745.        LCALL DELAY200US
  746.        LCALL DELAY200US
  747.        CLR YYSDA
  748.        LCALL DELAY200US
  749. LP2:   DJNZ R6,LP1         ;查看数据是否发完，未发完继续发
  750.        MOV R6,#08H
  751.        SETB YYSDA
  752.        RET

  754. DIDIANPIN:                 ;低电平用高:低=1:2的脉宽表示
  755.        LCALL DELAY200US
  756.        CLR YYSDA
  757.        LCALL DELAY200US
  758.        LCALL DELAY200US
  759.        LCALL DELAY200US
  760.        SJMP LP2

  762. ;以下为延时子程序
  763. DELAY200US:                ;延时200US子程序，晶振11.0592MHz，方式1
  764.        MOV  TH1,#0FFH
  765.        MOV  TL1,#47H
  766.        SETB TR1
  767. LOP1:  JBC  TF1,NEXT1
  768.        SJMP LOP1
  769. NEXT1: CLR TR1
  770.        RET

  772. DELAY1MS:MOV  TH1,#0FCH    ;延时1ms子程序
  773.        MOV  TL1,#66H
  774.        SETB TR1
  775. LOP2:  JBC  TF1,NEXT2
  776.        SJMP LOP2
  777. NEXT2: DJNZ R7,DELAY1MS
  778.        CLR TR1
  779.        RET


  782. END
复制代码


程序, 检测
分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏1 分享淘帖 顶顶1 踩踩

相关帖子
回复

使用道具 举报

沙发
ID:199787 发表于 2017-6-15 14:18 | 只看该作者
楼主有没有c语言的，急求。。
回复

使用道具 举报

板凳
ID:587868 发表于 2019-7-23 22:50 | 只看该作者
学习了，楼主真厉害！！！！！
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表