设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

搜索
»论坛 › 嵌入式/单片机论坛 › MCU综合技术区 › 电压检测程序
返回列表 发新帖
查看: 4544|回复: 0
打印 上一主题 下一主题
收起左侧

电压检测程序

[复制链接]
跳转到指定楼层
楼主
ID:70976 发表于 2014-12-26 23:28 | 只看该作者 回帖奖励 |倒序浏览 |阅读模式
  1.           LCD_X  EQU   23H        ;LCD 地址变量（决定文字的在LCD上的显示位置）
  2.           FSJCQ  EQU   33H        ;TMOD工作方式暂存寄存器
  3.           BJZC   EQU   34H        ;需要比较数据暂存寄存器，用于报警显示
  4.           BJWX   EQU   35H        ;超标设定值暂存寄存器
  5.           BJJG   EQU   36H        ;偏高设定值暂存寄存器
  6.           JJCQ   EQU   37H        ;酒精显示0%暂存寄存器
  7.           YYBZ   EQU   38H        ;语音播放标志
  8.           DJSJCQ EQU   39H        ;10S倒计时寄存器
  9.           JJCYCS EQU   3AH        ;酒精检测采样次数寄存器
  10.           SHZZ2  EQU   3BH        ;数据中转寄存器

  12.           XSYSSJ  DATA   5        ;正常时显示延时时间
  13.           YWBJCS  EQU   5        ;缺油报警次数
  14.           WXBJZ1  EQU   100       ;有害气体危险报警设定值200PPM
  15.                                   ;实际设定值=200（显示设定值）/2（修正倍率）
  16.           JGBJZ1  EQU   60        ;有害气体警告报警设定值120PPM
  17.                                   ;实际设定值=120（显示设定值）/2（修正倍率）
  18.           WXBJZ2  EQU   50        ;酒精危险报警设定值0.05% BAC
  19.                                   ;实际设定值=0.05%（显示设定值）*1000（显示位修正）/1（修正倍率）
  20.           JGBJZ2  EQU   20        ;酒精警告报警设定值0.02% BAC
  21.                                   ;实际设定值=0.02%（显示设定值）*1000（显示位修正）/1（修正倍率）
  22.           XIUZ1   EQU   10        ;有害气体浓度显示数据修正值，设置大时则显示数值小，反之显示大
  23.           XIUZ2   EQU   34        ;酒精浓度显示数据修正值，设置大时则显示数值小，反之显示大

  25. ;-----------------------------------------------------------
  26.           LCD_RS    EQU   P4.0    ;LCD 数据/命令选择端
  27.           LCD_RW    EQU   P4.1    ;LCD 读/写选择端
  28.           LCD_EN    EQU   P4.2    ;LCD 使能信号
  29.           LCD_BG    EQU   P4.3    ;LCD 背光控制端
  30.           LCD_SJ    EQU   P0      ;LCD 数据

  32.           BITE      EQU   9       ;串口发送9位数据
  33.           FSSZ      EQU   40H     ;主机发送的数据块首址
  34.           JSSZ      EQU   50H     ;主机接收的数据块首址

  36.           YY_DAT    DATA  29H     ;语音段地址存放单元
  37.           YYRST     EQU   P3.3    ;语音模块复位信号引脚
  38.           BUSY      EQU   P1.0    ;语音忙控制端，0为正在播放1为没有播放空闲时
  39.           YYSDA     EQU   P1.1    ;语音模块数据线引脚

  41. ;===========================================================
  42.           ORG  0000H
  43.           AJMP  MAIN

  45.           ORG  0100H

  47. ;=========================================
  48. ;以下为主程序
  49. ;=========================================
  50. ;以下为油位显示和报警程序
  51. MAIN:     MOV  SP,#60H
  52.           CLR  LCD_BG         ;打开LCD背光
  53.           LCALL  SET_LCD      ;初始化 LCD
  54.           CLR A
  55.           MOV  R0,#20H        ;将20H-7FH 单元清零
  56.           MOV  R1,#63
  57. CLEAR:    MOV  @R0,A
  58.           INC  R0
  59.           DJNZ  R1,CLEAR

  61.           MOV A,#5
  62.           MOV DPTR,#1000H     ;查看语音报警次数
  63.           MOVX @DPTR,A

  65.           ;MOV 08H,#5

  67. YWJCCX:   LCALL MENU_7        ;显示菜单1

  69. FFFF:     LCALL YWJC          ;调用油位检测程序
  70.           LCALL DYXZ          ;调用电瓶电压检测程序
  71.           LCALL DELAY3
  72.           LCALL DELAY3
  73.           SJMP FFFF

  75. ;***************************************************
  76. ;以下为子程序
  77. ;==============================================
  78. ;以下为LCD显示有害气体程序
  79. ;72H-70H 分别存放百位、十位、个位的数据
  80. ;==============================================
  81. CONV400:  MOV  A,73H         ;加载百位数据
  82.           MOV  LCD_X,#0      ;设置显示位置
  83.           CJNE A,#00H,CONV410
  84.           MOV  A,#" "        ;百位数等于0显示空格
  85.           MOV  B,LCD_X
  86.           CALL  LCDP2
  87.           JMP  CONV420

  89. CONV410:  CALL  SHOW_DIG2    ;显示数据

  91. CONV420:  INC  LCD_X         ;调整显示地址
  92.           MOV  A,72H         ;十位
  93.           CALL  SHOW_DIG2

  95.           INC  LCD_X         ;调整显示地址
  96.           MOV  A,#'.'
  97.           MOV  B,LCD_X
  98.           CALL  LCDP2

  100.           INC  LCD_X         ;调整显示地址
  101.           MOV  A,71H         ;十位
  102.           CALL  SHOW_DIG2

  104.           RET
  105. ;=========================================
  106. ;LCD 显示菜单1
  107. ;=========================================
  108. MENU_7:   MOV  DPTR,#M_OK31  ;指针指到显示信息区
  109.           MOV  A,#1          ;显示在第一行
  110.           CALL  LCD_PRINT
  111.           MOV  DPTR,#M_OK32  ;指针指到显示信息区
  112.           MOV  A,#2          ;显示在第二行
  113.           CALL  LCD_PRINT
  114.           MOV  DPTR,#M_OK33  ;指针指到显示信息区
  115.           MOV  A,#3          ;显示在第二行
  116.           CALL  LCD_PRINT
  117.           MOV  DPTR,#M_OK34  ;指针指到显示信息区
  118.           MOV  A,#4          ;显示在第二行
  119.           CALL  LCD_PRINT
  120.           RET
  121. M_OK31:   DB"油量：          ",0
  122. M_OK32:   DB"        升      ",0
  123. M_OK33:   DB"电瓶电压：      ",0
  124. M_OK34:   DB"        V       ",0


  127. ;--------------------------------------------------------------------------
  128. ;以下为油位检测和报警显示程序
  129. ;--------------------------------------------------------------------------
  130. YWJC:     MOV R2,#0AH         ;与10号从机串口通信，多功能板地址为0AH
  131.           MOV R3,#01H         ;主机要求从机发送数据块
  132.           LCALL COM           ;主机与多功能检测板串口通信，要求其发送9个字节数据块

  134.           MOV A,JSSZ+3        ;取出传感器检测到的电压读数（原始数据，16进制）
  135.           MOV B,#2            ;显示修正倍率，原始数*倍率=LCD显示值
  136.           LCALL HEX2BCD1      ;调用数值转换程序
  137.           MOV YYBZ,#JSSZ+3    ;设标志
  138.           MOV  DPTR,#BJ61     ;显示油位过低
  139.           LCALL BTT5          ;显示清屏
  140.           LCALL CONV400       ;调用LCD显示程序
  141.           LCALL YWBJ          ;调用报警比较程序
  142.           RET

  144. YWBJ:     MOV A,JSSZ+3        ;取出检测到的电压读数（原始数据，16进制）
  145.           SUBB A,#19H         ;比较，查看是否是低油位
  146.           JNC BTT6            ;油位没有过低直接返回

  148.           MOV DPTR,#1000H     ;查看语音报警次数
  149.           MOVX A,@DPTR
  150.           JZ YWBJ1            ;等于0FF说明首次打开此段语音
  151.           DEC A               ;没有播放完允许再播放
  152.           MOV DPTR,#1000H     ;查看语音报警次数
  153.           MOVX @DPTR,A

  155.           ;MOV A,08H     ;查看语音报警次数
  156.           ;JZ YWBJ1   ;等于0FF说明首次打开此段语音
  157.           ;DEC A               ;没有播放完允许再播放
  158.           ;MOV 08H,A     ;查看语音报警次数

  160.           JNB BUSY,$          ;如果语言正在播放，则等待
  161.           MOV YY_DAT,#38      ;报出“油位过低请加油”
  162.           LCALL YUYIN         ;开始语音播放

  164. YWBJ1:    LCALL DELAY3        ;延时
  165.           MOV  DPTR,#BJ60     ;显示油位过低
  166. BTT5:     MOV  A,#90H         ;设置 LCD 显示的地址（第四行）
  167.           CALL  WCOM          ;写入指令
  168. BLC:      CLR  A              ;填入字符
  169.           MOVC  A,@A+DPTR     ;由信息区取出字符
  170.           CJNE  A,#0,BLD      ;判断是否为结束码
  171. BTT6:     RET
  172. BLD:      CALL  WDATA         ;写入数据
  173.           INC  DPTR           ;指针加1
  174.           JMP  BLC            ;继续填入字符

  176. BJ60:     DB "低油位，请加油  ",0
  177. BJ61:     DB "        升      ",0

  179. ;--------------------------------------------------------------------------
  180. ;以下为电瓶电压检测和报警显示程序
  181. ;--------------------------------------------------------------------------
  182. DYXZ:     MOV R2,#0AH         ;与10号从机串口通信，多功能板地址为0AH
  183.           MOV R3,#01H         ;主机要求从机发送数据块
  184.           LCALL COM           ;主机与多功能检测板串口通信，要求其发送9个字节数据块
  185. ;电压比较程序
  186.           MOV A,JSSZ+5        ;取出检测到的电压读数（原始数据，16进制）
  187.           SUBB A,#7AH         ;比较，查看电压是否高于8V
  188.           JC BTT1             ;电压高于8V小于15.5V显示电压值，超过不显示只报警
  189.           MOV R1,A            ;送暂存器
  190.           MOV A,JSSZ+5
  191.           SUBB A,#0C2H        ;超过15.5V报警
  192.           JC BTT2
  193. ;电压过高
  194.           JNB BUSY,$          ;如果语言正在播放，则等待
  195.           MOV YY_DAT,#20      ;报出“电瓶电压过高，请检查”
  196.           LCALL YUYIN         ;开始语音播放
  197.           MOV  DPTR,#BJ50     ;超标显示的内容
  198.           LCALL DYBJXS        ;超过15.5V报警显示电压过高
  199.           SJMP BTT3

  201. ;电压正常显示电压值
  202. BTT2:     MOV  DPTR,#BJ52     ;显示清屏
  203.           LCALL DYBJXS
  204.           MOV A,R1
  205.           MOV  DPTR,#DAB8     ;电压值修正（实际电压与检测到的数值成非线性）
  206.           MOVC  A,@A+DPTR
  207.           MOV B,#100          ;把十进制数值分离出来
  208.           DIV AB
  209.           MOV 73H,A           ;十位
  210.           MOV A,B
  211.           MOV B,#10
  212.           DIV AB
  213.           MOV 72H,A           ;个位
  214.           MOV 71H,B           ;小数点后1位
  215.           MOV YYBZ,#JSSZ+5    ;设标志
  216.           LCALL CONV400       ;电压值显示
  217.           SJMP BTT3           ;返回主程序
  218. ;电压过低
  219. BTT1:     JNB BUSY,$          ;如果语言正在播放，则等待
  220.           MOV YY_DAT,#19      ;报出“电瓶电压过低，请检查”
  221.           LCALL YUYIN         ;开始语音播放
  222.           MOV  DPTR,#BJ51     ;未达到8V报警电压过低
  223.           LCALL DYBJXS        ;调用报警显示程序
  224. BTT3:     RET


  227. DYBJXS:   MOV  A,#98H          ;设置 LCD 显示的地址（第四行）
  228.           CALL  WCOM           ;写入指令
  229. BLA:      CLR  A               ;填入字符
  230.           MOVC  A,@A+DPTR      ;由信息区取出字符
  231.           CJNE  A,#0,BLB       ;判断是否为结束码
  232.           RET
  233. BLB:      CALL  WDATA          ;写入数据
  234.           INC  DPTR            ;指针加1
  235.           JMP  BLA             ;继续填入字符

  237. BJ50:     DB "电压过高，请检查",0
  238. BJ51:     DB "电压过低，请检查",0
  239. BJ52:     DB"        V       ",0


  242. DAB8:                          ;电压值修正
  243. DB  80,80,81,82,83,84,85,85,
  244. DB  86,87,88,89,90,90,91,91,
  245. DB  92,92,93,93,94,94,95,95,
  246. DB  96,97,98,98,99,100,100,101,
  247. DB  102,103,104,105,105,106,107,108,
  248. DB  109,110,110,111,112,113,114,115,
  249. DB  116,117,118,119,120,121,122,123,
  250. DB  124,125,126,128,130,132,134,135,
  251. DB  137,139,140,142,144,145,148,150,
  252. DB  153,155,158,160,163,165,170,173,
  253. DB  175,178,180,185,190,195,200,205,
  254. DB  0,





  260. ;=========================================
  261. ;以下为两个单字节十六进制相乘
  262. ;入口：A*B
  263. ;出口：16位低字节放A中，高字节放B中
  264. ;=========================================
  265. HEX2BCD1: MUL AB
  266.           MOV R6,B
  267.           MOV R7,A
  268.           MOV JJCQ,A        ;为显示0%作准备
  269. ;=========================================
  270. ;以下为双字节十六进制整数转换成双字节BCD码整数
  271. ;入口条件：待转换的双字节十六进制整数在R6、R7中。
  272. ;出口信息：转换后的三字节BCD码整数在R3、R4、R5中。
  273. ;影响资源：PSW、A、R2～R7，堆栈需求：２字节
  274. ;=========================================
  275.           CLR A             ;BCD码初始化
  276.           MOV R3,A
  277.           MOV R4,A
  278.           MOV R5,A
  279.           MOV R2,#10H       ;转换双字节十六进制整数
  280. HB3:      MOV A,R7          ;从高端移出待转换数的一位到CY中
  281.           RLC A
  282.           MOV R7,A
  283.           MOV A,R6
  284.           RLC A
  285.           MOV R6,A
  286.           MOV A,R5          ;BCD码带进位自身相加，相当于乘2
  287.           ADDC A,R5
  288.           DA A              ;十进制调整
  289.           MOV R5,A
  290.           MOV A,R4
  291.           ADDC A,R4
  292.           DA A
  293.           MOV R4,A
  294.           MOV A,R3
  295.           ADDC A,R3
  296.           MOV R3,A          ;双字节十六进制数的万位数不超过6，不用调整
  297.           DJNZ R2,HB3       ;处理完16bit

  299. ;=========================================
  300. ;以下为把BCD码提取出并送显示寄存器70H～73H
  301. ;入口：;三字节BCD码整数在R3（高位为十万低位为万）、
  302. ;R4（高位为千低位为百）、R5（高位为十低位为个）中。
  303. ;出口：73H-70H（舍去十万、万位）
  304. ;=========================================
  305.           MOV A,R4
  306.           ANL A,#00001111B
  307.           MOV 73H,A
  308.           MOV A,R5
  309.           ANL A,#11110000B
  310.           SWAP A
  311.           MOV 72H,A
  312.           MOV A,R5
  313.           ANL A,#00001111B
  314.           MOV 71H,A
  315.           MOV 70H,#0
  316.           RET

  318. ;=========================================
  319. ;以下为主机串行通信程序
  320. ;占用资源：R0～R4,A、40H、50H
  321. ;=========================================
  322. COM:   MOV A,TMOD           ;设置T1工作方式为方式2、T0工作方式保持不变
  323.        MOV FSJCQ,A
  324.        ORL A,#00101111B
  325.        MOV TMOD,A
  326.        MOV TH1,#0FDH        ;11.0592MHz 晶振,波特率=9600，时长0.6695
  327.        MOV TL1,#0FDH
  328.        MOV SCON,#0D8H       ;置串行模式3，SM2=1,允许接收
  329.        SETB TR1             ;启动T1
  330.        LCALL COM1           ;调用一线发码子程序
  331.        MOV TMOD,FSJCQ       ;恢复T1、T0原先的工作方式
  332.        RET

  334. COM1:   MOV A,R2            ;发送地址帧
  335.         MOV SBUF,A
  336.         JNB TI,$
  337.         CLR TI
  338.         JNB RI,$            ;等待从机应答
  339.         CLR RI
  340.         MOV A,SBUF
  341.         XRL A,R2
  342.         JNZ MS104           ;判应答地址是否相符
  343.         CLR TB8             ;地址符合，准备发送命令
  344.         MOV SBUF,R3         ;发送发送或接收数据命令
  345.         JNB TI,$
  346.         CLR TI
  347.         JNB RI,$            ;等待从机应答
  348.         CLR RI
  349.         MOV A,SBUF          ;取应答信息
  350.         JNB ACC.7,MS102     ;判断是否出错
  351. MS101:  SETB TB8
  352.         MOV SBUF,#0FFH      ;不相符重新联络
  353.         JNB TI,$
  354.         CLR TI
  355.         SJMP COM1           ;转重发地址

  357. MS102:  CJNE R3,#00H,MS103  ;判是否要求从机接收数据
  358.         JNB ACC.0,MS101     ;从机接收数据准备就绪否？
  359.         MOV R0,#FSSZ        ;主机发送的数据块首址
  360.         MOV R4,#BITE        ;设数据块长度(9字节)
  361. LPTX:   MOV SBUF,@R0        ;主机发送数据块
  362.         JNB TI,$            ;等待发送完1帧
  363.         CLR TI
  364.         INC R0              ;修改地址指针
  365.         DJNZ R4,LPTX        ;判数据块是否传完
  366.         SJMP MS104          ;返回主程序

  368. MS103:  JNB ACC.1,MS101     ;从机发送数据准备就绪否？
  369.         MOV R1,#JSSZ        ;主机接收的数据块首址
  370.         MOV R4,#BITE        ;设数据块长度(9字节)
  371. LPRX:   JNB RI,LPRX         ;等待接收完1帧
  372.         CLR RI
  373.         MOV A,SBUF          ;取出接收到的字符
  374.         MOV @R1,A
  375.         INC R1
  376.         DJNZ R4,LPRX        ;未接收完则继续

  378. MS104:  CLR TR1             ;关闭T1
  379.         RET

  381. ;=============================================
  382. ;在LCD的第二行显示数据字符
  383. ;A=ASCII 数据, B=位置变量
  384. ;==============================================
  385. LCDP2:    PUSH  ACC           ;在LCD的第二行显示字符
  386.           MOV  A,B            ;设置显示地址
  387.           MOV R0,YYBZ
  388.           CJNE R0,#JSSZ+3,LCDP3
  389.           ADD  A,#90H         ;设置LCD的第二行地址90
  390.           SJMP LCDP4
  391. LCDP3:    CJNE R0,#JSSZ+5,LCDP5
  392.           ADD  A,#98H         ;设置LCD的第四行地址98
  393. LCDP4:    CALL  WCOM          ;写入命令
  394. LCDP5:    POP  ACC            ;由堆栈取出A
  395.           CALL  WDATA         ;写入数据
  396.           RET
  397. ;-------------------------------------------------------
  398. SHOW_DIG2:                   ;在 LCD 的第二行显示数字
  399.           ADD  A,#30H        ;加30H，转换为ASCII码
  400.           MOV  B,LCD_X       ;确定显示位置
  401.           CALL  LCDP2        ;送显示
  402.           RET

  404. ;=================================================
  405. ;对 LCD 做初始化设置
  406. ;=================================================
  407. SET_LCD:  MOV A,#34H      ;34H--扩充指令操作
  408.           CALL  WCOM         ;写入命令
  409.    MOV A,#30H      ;30H--基本指令操作
  410.           CALL  WCOM         ;写入命令
  411.    MOV A,#01H      ;清除显示
  412.           CALL  WCOM         ;写入命令
  413.           MOV A,#06H      ;指定在资料写入或读取时，光标的移动方向
  414.           CALL  WCOM         ;DDRAM 的地址计数器(AC)加1
  415.    MOV A,#0CH      ;开显示,关光标,不闪烁
  416.           CALL  WCOM         ;写入命令
  417.           RET

  419. ;===============================================
  420. ;命令写入子程序
  421. ;RS=L,RW=L,D0-D7=指令码，E=高脉冲
  422. ;以8位控制方式将命令写至LCD
  423. ;===============================================
  424. WCOM:    LCALL CHK_BUSY       ;写入指令
  425.   CLR LCD_RS
  426.   CLR LCD_RW
  427.   MOV LCD_SJ,A
  428.   SETB LCD_EN
  429.   NOP
  430.   NOP
  431.   CLR LCD_EN
  432.   RET
  433. ;===============================================
  434. ;数据写入子程序
  435. ;RS=H,RW=L,D0-D7=指令码，E=高脉冲
  436. ;以8位控制方式将数据写至LCD
  437. ;===============================================
  438. WDATA:    MOV  LCD_SJ,A       ;写入数据
  439.           SETB  LCD_RS
  440.           CLR  LCD_RW
  441.           SETB  LCD_EN
  442.           CALL  DE
  443.           CLR  LCD_EN
  444.           CALL  DE
  445.           RET
  446. ;===============================================
  447. ;测LCD忙碌子程序
  448. ;RS=0,RW=1,E=H,D0-D7=状态字
  449. ;===============================================
  450. CHK_BUSY: MOV LCD_SJ,#0FFH   ;测忙碌子程序
  451.    CLR LCD_RS
  452.    SETB LCD_RW
  453.    SETB LCD_EN
  454.    JB LCD_SJ.7,$
  455.    CLR LCD_EN
  456.    RET

  458. ;==================================================
  459. ;在LCD的显示字符串
  460. ;DPTR = 放字符串的地址
  461. ;==================================================
  462. LCD_PRINT:CJNE  A,#1,LINE2  ;判断是否为第一行
  463. LINE1:    MOV  A,#80H       ;设置 LCD 的第一行地址
  464.           CALL  WCOM        ;写入命令
  465.           CALL  CLR_LINE    ;清除该行字符数据
  466.           MOV  A,#80H       ;设置 LCD 的第一行地址
  467.           CALL  WCOM        ;写入命令
  468.           JMP  FILL

  470. LINE2:    CJNE  A,#2,LINE3  ;判断是否为第二行
  471.           MOV  A,#90H       ;设置 LCD 的第二行地址
  472.           CALL  WCOM        ;写入命令
  473.           CALL  CLR_LINE    ;清除该行字符数据
  474.           MOV  A,#90H       ;设置 LCD 的第二行地址
  475.           CALL  WCOM
  476.           JMP  FILL

  478. LINE3:    CJNE  A,#3,LINE4  ;判断是否为第三行
  479.           MOV  A,#88H       ;设置 LCD 的第三行地址
  480.           CALL  WCOM        ;写入命令
  481.           CALL  CLR_LINE    ;清除该行字符数据
  482.           MOV  A,#88H       ;设置 LCD 的第三行地址
  483.           CALL  WCOM
  484.           JMP  FILL

  486. LINE4:    MOV  A,#98H       ;设置 LCD 的第四行地址
  487.           CALL  WCOM        ;写入命令
  488.           CALL  CLR_LINE    ;清除该行字符数据
  489.           MOV  A,#98H       ;设置 LCD 的第四行地址
  490.           CALL  WCOM

  492. FILL:     CLR  A            ;填入字符
  493.           MOVC  A,@A+DPTR   ;由信息区取出字符
  494.           CJNE  A,#0,LC1    ;判断是否为结束码
  495.           RET

  497. LC1:      CALL  WDATA       ;写入数据
  498.           INC  DPTR         ;指针加1
  499.           JMP  FILL         ;继续填入字符
  500. ;===============================================
  501. ;清除一行 LCD 的字符
  502. ;输入一行空格，来替代原显示字符
  503. ;===============================================
  504. CLR_LINE: MOV  R0,#16       ;清除该行 LCD 的字符
  505. CL1:      MOV  A,#' '
  506.           CALL  WDATA
  507.           DJNZ  R0,CL1
  508.           RET
  509. ;**********************************************************
  510. ;延时子程序
  511. ;**********************************************************
  512. DE:      MOV  R7,#229        ;延时 500 微秒,此条2个机器周期
  513.          DJNZ  R7,$
  514.          RET    ;此条2个机器周期，总延时（229*2+2+2）*(12/11.0592)≈500uS

  516. DELAY:   MOV  R5,#20         ;延时200MS
  517. DELAY1:  MOV  R6,#96         ;100
  518. DL1:     MOV  R7,#96         ;100
  519.          DJNZ  R7,$
  520.          DJNZ  R6,DL1
  521.          DJNZ  R5,DELAY1     ;96*2*48*(12/11.0592)+2*(12/11.0592)≈10000uS=10mS
  522.          RET

  524. DELAY2:  MOV  R6,#10         ;延时5MS
  525. DL2:     MOV  R7,#229        ;100微秒
  526.          DJNZ  R7,$
  527.          DJNZ  R6,DL2
  528.          DJNZ  R5,DELAY2
  529.          RET

  531. DELAY3:  MOV  R5,#10         ;延时200MS
  532. DELA:    MOV  R6,#255
  533. DL3:     MOV  R7,#255
  534.          DJNZ  R7,$
  535.          DJNZ  R6,DL3
  536.          DJNZ  R5,DELA
  537.          RET
  538. ;**********************************************************
  539. ;语音驱动和播放程序
  540. ;**********************************************************
  541. ;50H为语音段地址暂存器，1到210段，实际用到40
  542. ;50H为E0H～E7H时分别代表自低往高的8级音量
  543. ;在语音播放过程中发送F2H至50H可循环播放当前地址语音
  544. ;发送FEH至50H停止播放语音
  545. ;****************************************************
  546. YUYIN: MOV A,TMOD          ;设置T1工作方式为方式1、T0工作方式保持不变
  547.        MOV FSJCQ,A
  548.        ORL A,#00011111B
  549.        MOV TMOD,A
  550.        MOV R6,#08H         ;发码8位循环数据
  551.        LCALL ONE_LINE      ;调用一线发码子程序
  552.        MOV TMOD,FSJCQ          ;恢复T1、T0原先的工作方式
  553.        RET

  555. ONE_LINE:                  ;////一线发码子程序
  556.        SETB YYRST          ;复位
  557.        MOV R7,#2           ;延时2MS
  558.        LCALL DELAY1MS
  559.        CLR YYRST           ;延时使系统稳定
  560.        MOV R7,#6           ;延时6MS
  561.        LCALL DELAY1MS
  562.        CLR YYSDA           ;唤醒语音芯片
  563.        MOV R7,#17          ;延时17MS
  564.        LCALL DELAY1MS
  565.        MOV A,YY_DAT

  567. LP1:   SETB YYSDA
  568.        RRC A               ;分辨50H内的数据各位是高电平还是低电平
  569.        JNC DIDIANPIN       ;高电平用高:低=2:1的脉宽表示
  570.        LCALL DELAY200US
  571.        LCALL DELAY200US
  572.        LCALL DELAY200US
  573.        CLR YYSDA
  574.        LCALL DELAY200US
  575. LP2:   DJNZ R6,LP1         ;查看数据是否发完，未发完继续发
  576.        MOV R6,#08H
  577.        SETB YYSDA
  578.        RET

  580. DIDIANPIN:                 ;低电平用高:低=1:2的脉宽表示
  581.        LCALL DELAY200US
  582.        CLR YYSDA
  583.        LCALL DELAY200US
  584.        LCALL DELAY200US
  585.        LCALL DELAY200US
  586.        SJMP LP2

  588. ;以下为延时子程序
  589. DELAY200US:                ;延时200US子程序，晶振11.0592MHz，方式1
  590.        MOV  TH1,#0FFH
  591.        MOV  TL1,#47H
  592.        SETB TR1
  593. LOP1:  JBC  TF1,NEXT1
  594.        SJMP LOP1
  595. NEXT1: CLR TR1
  596.        RET

  598. DELAY1MS:MOV  TH1,#0FCH    ;延时1ms子程序
  599.        MOV  TL1,#66H
  600.        SETB TR1
  601. LOP2:  JBC  TF1,NEXT2
  602.        SJMP LOP2
  603. NEXT2: DJNZ R7,DELAY1MS
  604.        CLR TR1
  605.        RET


  608.          END
复制代码


程序, 检测
分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏 分享淘帖 顶顶 踩踩

相关帖子
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

手机版|小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表