单片机论坛

 找回密码
 立即注册

QQ登录

只需一步,快速开始

搜索
查看: 5371|回复: 1
收起左侧

51单片机汇编中断程序(导引)

[复制链接]
liuyy 发表于 2015-1-19 14:20 | 显示全部楼层 |阅读模式
本帖最后由 liuyy 于 2015-1-19 14:22 编辑

51单片机汇编程序入口后加的跳转指令"LJMP"是为什么:
    要弄明白这个问题,你要对51单片机的中断有一个初步的了解,我可以给你介绍一下。比方说你希望不管程序运行到哪里,只要你一按某个按键,就执行一段你预先写好的程序,然后再回到原来的地方继续。你按按键的动作可以视为单片机的一个I/O管脚电平由高到低(如果你把按键接在I/O和地之间)。在51单片机中,有两个I/O可以实现这样的功能(这就是外中断,ORG 0003H LJMP INT0S 中的INT0S就是外中断0,具体你可以查51单片机中断系统的资料)。那它到底是怎样实现的呢?比方说,某一时刻,你的按键按下了,处理器会知道满足了外中断的触发条件,那它会执行哪一段程序呢?设计师人为地给它规定了一个固定的地址,如外中断0被触发时就是跳到地址为0003H的单元开始执行,别的中断(定时器等)同理,都有一个固定的地址,一旦被触发就会自动跳到那个地址,这就是中断向量。那为什么是0003H而不是程序存储器的末尾呢?这是因为不同51单片机的存储器大小是不同的,如果中断向量也因此而不同的话,单片机开发的麻烦就太多了。所以设计师干脆就把中断向量放在开头。单片机复位后是从0000H开始执行的,总不能让它一开始就无缘无故中断,所以要转移到一个和中断向量不相干的地方执行主程序。ORG 0 LJMP STAR(其实应该是START)就是这样一个转移指令,转到标记为START的主程序处开始执行。一条LJMP指令的长度为3,这也就是第一个中断向量为0003H的原因了(不浪费一丝空间,不得不佩服Intel设计师的高明)。ORG 0003H LJMP INT0S 为什么中断向量处还要跳转呢?这是因为中断向量间的空间也很有限,只能完成一些最简单的任务,稍微长一点的程序就需要放在更大的空间里,从中断向量处跳转到该处执行真正的中断服务程序。有关中断系统的具体内容,建议你还是看看相关资料,我只是把它的基本原理和你讲了一下,真正使用还是请你自己探索。

下面是一个完整的51单片机中断汇编程序的例子:
0.jpg
首先,介绍一下51单片机的定时计数器,51有两个定时计数器,分别为T0,T1,基本一样,

;有一点不同,下面我们介绍定时计数器T0

;了解8051的timer0中断的程序写法,用中断法产生定时

;上面显示的是proteus仿真图,下面的是源程序

;说明:(源程序中的中断入口地址很重要(这个是固定的),程序中断时,会在对应中断固定的

;入口地址进入,因为规定的相隔入口间的空进有限,只能用跳转指令跳转,最终用RETI强制返回

;这个程序把所有的中断入口地址都写上了,没有用到的,用RETI直接屏蔽)

;运行结果是使led灯明一下,暗一下。



COUNT EQU  9217;对于11.0592的晶振来说,延时10ms

LED  EQU  P1.1





        ORG  0000H

        LJMP RESET       ;开始时跳转转到初始化程序中



        ORG  0003H       ;外部中断0

        RETI



        ORG  000BH       ;定时器/计数器T0入口地址

        LJMP INT_TIMER0   ;跳转到定时器/计数器中断服务程序中去



        ORG  0013H      ;外部中断1  

        RETI      



        ORG  001BH    ;定时器/计数器T1

        RETI



        ORG  0023H ;串行口中断

        RETI



           ORG  0030H

RESET:

           MOV  R0,#00H

           DJNZ R0,$  ;刚开始,先进行少量的延时,是各种工作寄存器准备好

           CLR  LED





           MOV    TMOD,#00000001B   ;设置定时器T0工作在方式1(16位)



           MOV    TH0,#HIGH(65536-COUNT);设置初值(关于怎么计算,很多书上都有)

           MOV    TL0,#LOW(65536-COUNT)

           ;MOV  TH0,#(65536-COUNT)/256;取高八位数据(这是第二种方法)

           ;MOV  TL0,#255   ;取底五位(为最大了)



           CLR  TF0   ;先把溢出标志位清零

           SETB TR0   ;开始计时

           SETB EA    ;全局中断打开

           SETB ET0   ;定时器/计数器T0溢出中断打开



           MOV  R2,#00H  ;作为定时器累加器使用



LOOP:    SJMP LOOP   ;在此循环,等待中断





INT_TIMER0:         ;当TF0=1,跳转到下面的中断服务程序中

        INC  R2          ;使R2自增一

        CLR  TF0       ;重新置中断标志位为0

        MOV  TH0,#(65536-COUNT)/256  ; 重新符初值(因为溢出后变成0了)

        MOV  TL0,#255  

        CJNE R2,#5,RETURN     ;让灯明暗相间50ms

        MOV  R2, #00H

        CPL  LED              ;让灯明暗交替变化

RETURN:   

        RETI



        END



;程序写完了(并不是很难,不过就是配置一下定时器,在中断中写点处理程序罢了

;),

回复

使用道具 举报

无效楼层,该帖已经被删除
wdliming 发表于 2018-8-3 11:49 | 显示全部楼层
谢谢分享
回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|手机版|小黑屋|单片机论坛 |51hei电子论坛2群 联系QQ:125739409;技术交流QQ群219535678

Powered by 单片机教程网

快速回复 返回顶部 返回列表