设为首页收藏本站
开启辅助访问 切换到宽版

 找回密码
 立即注册

QQ登录

只需一步，快速开始

热门： 51单片机 | 24小时必答区 | 单片机教程 | 单片机DIY制作 | STM32 | Cortex M3 | 模数电子 | 电子DIY制作 | 音响/功放 | 拆机乐园 | Arduino | 嵌入式OS | 程序设计

帖子
»论坛 › 嵌入式/单片机论坛 › MCU综合技术区 › 多功能检测仪程序（4路温度控制）
返回列表 发新帖
查看: 4260|回复: 1
打印 上一主题 下一主题
收起左侧

多功能检测仪程序（4路温度控制）

[复制链接]
跳转到指定楼层
楼主
ID:70976 发表于 2014-12-26 23:39 | 只看该作者 回帖奖励 |倒序浏览 |阅读模式
  1. ;*******************************************************************
  2. ;*温度控制程序,在LCD屏幕上显示4路温度（车内外温度、水温、油温）
  3. ;分两页显示，每页显示2路温度，温度传感器开路时语音报警和显示故障
  4. ;水温、油温超温报警
  5. ;*LCD12864显示，晶振11.0592M
  6. ;*******************************************************************
  7. ;-----------------------------------------------------------
  8. ;以下参数可以修改
  9. ;-----------------------------------------------------------
  10.           XSYSSJ    DATA   40     ;显示延时时间
  11.           XSGZSJ    DATA   40     ;故障显示延时时间
  12.           CNBJCS    DATA   2      ;车内温度传感器出故障报警次数
  13.           CWBJCS    DATA   2      ;车外温度传感器出故障报警次数
  14.           SWBJCS    DATA   2      ;水温传感器故出障报警次数
  15.           YWBJCS    DATA   2      ;油温度传感器出故障报警次数
  16.           SWGWSD    DATA   50     ;水温超高报警值（单位℃）
  17.           SWDWSD    DATA   23     ;水温超低报警值（单位℃）
  18.           YWGWSD    DATA   40     ;油温超高报警值（单位℃）
  19.           YWDWSD    DATA   25     ;油温超低报警值（单位℃）
  20.          
  21. ;-----------------------------------------------------------
  22. ;以下参数不宜修改
  23. ;-----------------------------------------------------------
  24.           FLAG0     BIT   20H.0   ;车内温度传感器标志
  25.           FLAG1     BIT   20H.1   ;车外温度传感器标志
  26.           FLAG2     BIT   20H.2   ;水温传感器标志
  27.           FLAG3     BIT   20H.3   ;油温传感器标志

  29.           FLAG4     BIT   20H.4   ;车内温度传感器故障标志位，1为故障0为正常
  30.           FLAG5     BIT   20H.5   ;车外温度传感器故障标志位，1为故障0为正常
  31.           FLAG6     BIT   20H.6   ;水温传感器故障标志位，1为故障0为正常
  32.           FLAG7     BIT   20H.7   ;油温传感器故障标志位，1为故障0为正常

  34.           FLAH0     BIT   21H.0   ;温度正负标志，1为负0为正，正不显示
  35.           FLAH1     BIT   21H.1   ;水温过高标志，1为过高
  36.           FLAH2     BIT   21H.2   ;油温过高标志，1为过高

  38. ;-----------------------------------------------------------
  39.           XSYS      DATA  22H     ;显示延时时间存放单元
  40.           LCD_X     EQU   23H     ;LCD 地址变量

  42.           TEMP_ZH   DATA  24H     ;实时温度值存放单元
  43.           TEMPL     DATA  25H     ;温度低位值存放单元
  44.           TEMPH     DATA  26H     ;温度高位值存放单元
  45.           TEMP_TH   DATA  27H     ;高温报警值存放单元
  46.           TEMP_TL   DATA  28H     ;低温报警值存放单元
  47.           YY_DAT    DATA  29H     ;语音地址存放单元

  49.           CNBJ      DATA  2AH     ;车内温度传感器故障报警次数存放单元
  50.           CWBJ      DATA  2BH     ;车外温度传感器故障报警次数存放单元
  51.           SWBJ      DATA  2CH     ;水温传感器故障报警次数存放单元
  52.           YWBJ      DATA  2DH     ;油温传感器故障报警次数存放单元

  54.           YYDAT     DATA  2EH     ;语音发码值暂存地址
  55. ;-----------------------------------------------------------
  56.           CNCGBJ    DATA   30     ;“车内温度传感器出故障，请检查”语音地址
  57.           CWCGBJ    DATA   31     ;“车外温度传感器出故障，请检查”语音地址
  58.           SWCGBJ    DATA   32     ;“水温传感器出故障，请检查”语音地址
  59.           YWCGBJ    DATA   33     ;“油温传感器出故障，请检查”语音地址
  60. ;-----------------------------------------------------------
  61. ;以下参数是固定的，不要修改
  62. ;-----------------------------------------------------------
  63.           YYRST     EQU   P3.3    ;语音模块复位信号引脚
  64.           BUSY      EQU   P1.0    ;语音忙控制端，0为正在播放1为没有播放
  65.           YYSDA     EQU   P1.1    ;语音模块数据引脚

  67.           CG_CHENEI EQU   P1.4    ;车内温度传感器数据线
  68.           CG_CHEWAI EQU   P1.5    ;车外温度传感器数据线
  69.           CG_SHUIWE EQU   P1.6    ;水温传感器数据线
  70.           CG_YOUWEN EQU   P1.7    ;油温传感器数据线
  71. ;-----------------------------------------------------------
  72.           LCD_RS    EQU   P4.0    ;LCD 数据/命令选择端
  73.           LCD_RW    EQU   P4.1    ;LCD 读/写选择端
  74.           LCD_EN    EQU   P4.2    ;LCD 使能信号
  75.           LCD_BG    EQU   P4.3    ;LCD 背光控制端
  76.           LCD_SJ    EQU   P0      ;LCD 数据




  81. ;===========================================================
  82.           ORG  0000H
  83.           AJMP  MAIN
  84.           ORG  0100H
  85. ;===========================================================
  86. MAIN:     MOV  SP,#60H
  87.           MOV  A,#00H
  88.           MOV  R0,#20H         ;将 20H-2FH 单元清零
  89.           MOV  R1,#10H
  90. CLEAR:    MOV  @R0,A
  91.           INC  R0
  92.           DJNZ  R1,CLEAR
  93.           CLR  LCD_BG          ;打开LCD背光

  95.           CALL  SET_LCD        ;初始化 LCD

  97.           MOV   CNBJ,#CNBJCS   ;设置车内温度传感器故障报警次数
  98.           MOV   CWBJ,#CWBJCS   ;设置车外温度传感器故障报警次数
  99.           MOV   SWBJ,#SWBJCS   ;设置水温传感器故障报警次数
  100.           MOV   YWBJ,#YWBJCS   ;设置油温传感器故障报警次数

  102.           ;LCALL TEMP



  106. ;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  107. ;##########################################################
  108. ;以下温度显示程序（车内外温度、水温、油温）
  109. ;-----------------------------------------------------------
  110. ;用到的资源：R0～R7,A、B、C，20H～2EH,P4，P3.3，P1.0，P1.4～P1.7
  111. ;-----------------------------------------------------------
  112. ;##########################################################
  113. ;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  114. ;**************显示第一页温度（车内外温度）

  116. TEMP:     CALL  MENU_OK1       ;显示温度菜单1

  118.           MOV TEMP_TH,#00H     ;温度低位值存放单元
  119.           MOV TEMP_TL,#00H     ;温度低位值存放单元

  121.           SETB  FLAG0          ;开始读取车内温度传感器，设标志为1
  122.           CLR FLAG1
  123.           CLR FLAG2
  124.           CLR FLAG3
  125.           MOV  XSYS,#XSYSSJ    ;每页显示时间

  127. ;读取和显示车内温度
  128. L1:       CALL  RESET          ;18B20复位子程序
  129.           JB   FLAG4,L2        ;检查车外温度传感器是否正常
  130.           CALL  BJ1            ;调用报警程序
  131.           MOV  XSYS,#XSGZSJ    ;重新设每页显示时间
  132.           SJMP  L3             ;传感器出故障不再显示该温度
  133. L2:       CALL  READ_TEMP      ;读出温度与报警数据
  134.           CALL  CONVTEMP       ;转换处理温度为BCD码
  135.           CALL  CONV01         ;显示车内温度

  137. L3:       CLR FLAG0
  138.           SETB FLAG1
  139.           CLR FLAG2
  140.           CLR FLAG3

  142. ;读取和显示车外温度
  143.           CALL  RESET          ;18B20复位子程序
  144.           JB   FLAG5,L4        ;检查车内温度传感器是否正常
  145.           CALL  BJ2            ;调用报警程序
  146.           SJMP  L5             ;传感器出故障不再显示该温度
  147. L4:       CALL  READ_TEMP      ;读出温度与报警数据
  148.           CALL  CONVTEMP       ;转换处理温度为BCD码
  149.           CALL  CONV02         ;显示车外温度

  151. L5:       SETB FLAG0
  152.           CLR FLAG1
  153.           CLR FLAG2
  154.           CLR FLAG3

  156.           JB FLAG4,L71
  157.           JB FLAG5,L71

  159.           MOV R0,#XSGZSJ
  160. L70:      ACALL DELAY
  161.           DJNZ R0,L70
  162.           SJMP L6

  164. L71:      ACALL DELAY          ;延时
  165.           DEC XSYS             ;车内外温度显示页显示一段时间，以便观察
  166.           MOV A,XSYS
  167.           JZ L6
  168.           SJMP L1

  170. ;**************显示第二页温度（水温和油温）

  172. L6:       CALL  MENU_OK2       ;显示温度菜单2
  173.           MOV  XSYS,#XSYSSJ    ;重新设每页显示时间
  174.           CLR FLAG0
  175.           CLR FLAG1
  176.           SETB FLAG2
  177.           CLR FLAG3

  179. ;读取和显示水温
  180. L7:       CALL  RESET          ;传感器复位子程序
  181.           JB   FLAG6,L8        ;检查水温传感器是否正常
  182.           CALL  BJ3            ;调用报警程序
  183.           SJMP  L9
  184. L8:       CALL  READ_TEMP      ;读出温度与报警数据
  185.           CALL  CONVTEMP       ;转换处理温度为BCD码
  186.           CALL  TEMP_COMP      ;温度比较子程序
  187.           CALL  CONV01         ;显示水温

  189. L9:       CLR FLAG0
  190.           CLR FLAG1
  191.           CLR FLAG2
  192.           SETB FLAG3

  194. ;读取和显示油温
  195.           CALL  RESET          ;传感器复位子程序
  196.           JB   FLAG7,L10       ;检查油温传感器是否正常
  197.           CALL  BJ4            ;调用报警程序
  198.           SJMP  L11
  199. L10:      CALL  READ_TEMP      ;读出温度与报警数据
  200.           CALL  CONVTEMP       ;转换处理温度为BCD码
  201.           CALL  TEMP_COMP      ;温度比较子程序
  202.           CALL  CONV02         ;显示油温

  204. L11:      CLR FLAG0
  205.           CLR FLAG1
  206.           SETB FLAG2
  207.           CLR FLAG3

  209.           JB FLAG6,L81
  210.           JB FLAG7,L81

  212.           MOV R0,#XSGZSJ
  213. L80:      ACALL DELAY
  214.           DJNZ R0,L80
  215.           SJMP L82

  217. L81:      ACALL DELAY
  218.           DEC XSYS              ;水温、油温显示页显示一段时间，以便观察
  219.           MOV A,XSYS
  220.           JZ L82
  221.           AJMP L7
  222. L82:      AJMP MAIN
  223.           RET

  225. ;------------------------------------------------------
  226. ;报警程序，传感器故障声音报警和LCD显示
  227. ;------------------------------------------------------
  228. BJ1:      MOV A,CNBJ        ;车内温度故障报警和显示
  229.           JZ L13            ;声音报警N次后不再报警,只显示故障
  230.           MOV YY_DAT,#CNCGBJ;报出“车内温度传感器出故障，请检查”
  231.           JNB BUSY,L13      ;如果正在播放语音则跳过,只显示故障
  232.           DEC CNBJ          ;车内温度传感器语音报警次数倒计数
  233.           SJMP L12          ;故障语音报警

  235. BJ2:      MOV A,CWBJ        ;车外温度故障报警和显示
  236.           JZ L15            ;声音报警N次后不再报警,只显示故障
  237.           MOV YY_DAT,#CWCGBJ;报出“车外温度传感器出故障，请检查”
  238.           JNB BUSY,L15      ;如果正在播放语音则跳过,只显示故障
  239.           DEC CWBJ          ;车外温度传感器语音报警次数倒计数
  240.           SJMP L14          ;故障显示

  242. BJ3:      MOV A,SWBJ        ;水温故障报警和显示
  243.           JZ L13            ;声音报警N次后不再报警,只显示故障
  244.           MOV YY_DAT,#SWCGBJ;报出“水温传感器出故障，请检查”
  245.           JNB BUSY,L13      ;如果正在播放语音则跳过,只显示故障
  246.           DEC SWBJ          ;水温传感器语音报警次数倒计数
  247. L12:      ACALL YUYIN       ;语音播放
  248. L13:      MOV  A,#90H        ;显示在第二行
  249.           SJMP L16          ;故障显示

  251. BJ4:      MOV A,YWBJ        ;油温故障报警和显示
  252.           JZ L15            ;声音报警N次后不再报警,只显示故障
  253.           MOV YY_DAT,#YWCGBJ;报出“油温传感器出故障，请检查”
  254.           JNB BUSY,L15      ;如果正在播放语音则跳过,只显示故障
  255.           DEC YWBJ          ;油温传感器语音报警次数倒计数
  256. L14:      ACALL YUYIN       ;语音播放
  257. L15:      MOV  A,#98H       ;显示在第四行

  259. L16:      MOV  DPTR,#MUNE1  ;指针指到显示信息区
  260.           CALL  WCOM
  261. L203:     CLR  A            ;填入字符
  262.           MOVC  A,@A+DPTR   ;由信息区取出字符
  263.           CJNE  A,#0,L205   ;判断是否为结束码
  264.           RET

  266. L205:     CALL  WDATA       ;写入数据
  267.           INC  DPTR         ;指针加1
  268.           JMP  L203         ;继续填入字符

  270. MUNE1:    DB"探头故障请检查！",0 ;温度探头不正常报警程序

  272. ;--------------------------------------------------------------------
  273. ;传感器读温度子程序
  274. ; 将温度低位、高位、TH、TL从传感器中读出
  275. ; 分别存入 25H、26H、27H、28H 单元中
  276. ;--------------------------------------------------------------------
  277. READ_TEMP:MOV   A,#0CCH        ; 跳过ROM匹配
  278.          CALL  WRITE
  279.          MOV   A,#44H          ; 发出温度转换命令
  280.          CALL  WRITE
  281.          CALL  RESET
  282.          MOV   A,#0CCH         ; 跳过ROM匹配
  283.          CALL  WRITE
  284.          MOV   A,#0BEH         ; 发出读温度命令
  285.          CALL  WRITE           ;先写入命令

  287.          MOV R4,#4             ;存入4个单元中
  288.          MOV R1,#TEMPL         ;存入单元的首地址送入 R1
  289. RE00:    MOV R2,#8             ;8位数据长度
  290. RE01:    CLR CY
  291. ;***********************
  292.          JNB FLAG0,L01
  293.          SETB CG_CHENEI
  294.          NOP
  295.          NOP
  296.          CLR CG_CHENEI        ;读前总线保持为低
  297.          NOP
  298.          NOP
  299.          NOP
  300.          SETB CG_CHENEI       ;开始读总线释放
  301.          MOV R3,#07           ;延时15微妙
  302.          DJNZ R3,$
  303.          MOV C,CG_CHENEI      ;从传感器总线读得一个BIT
  304.          AJMP L5A

  306. L01:     JNB FLAG1,L02
  307.          SETB CG_CHEWAI
  308.          NOP
  309.          NOP
  310.          CLR CG_CHEWAI        ;读前总线保持为低
  311.          NOP
  312.          NOP
  313.          NOP
  314.          SETB CG_CHEWAI       ;开始读总线释放
  315.          MOV R3,#07           ;延时15微妙
  316.          DJNZ R3,$
  317.          MOV C,CG_CHEWAI      ;从传感器总线读得一个BIT
  318.          AJMP L5A

  320. L02:     JNB FLAG2,L03
  321.          SETB CG_SHUIWE
  322.          NOP
  323.          NOP
  324.          CLR CG_SHUIWE        ;读前总线保持为低
  325.          NOP
  326.          NOP
  327.          NOP
  328.          SETB CG_SHUIWE       ;开始读总线释放
  329.          MOV R3,#07           ;延时15微妙
  330.          DJNZ R3,$
  331.          MOV C,CG_SHUIWE      ;从传感器总线读得一个BIT
  332. L0:      AJMP L5A

  334. L03:     JNB FLAG3,L0
  335.          SETB CG_YOUWEN
  336.          NOP
  337.          NOP
  338.          CLR CG_YOUWEN        ;读前总线保持为低
  339.          NOP
  340.          NOP
  341.          NOP
  342.          SETB CG_YOUWEN       ;开始读总线释放
  343.          MOV R3,#07           ;延时15微妙
  344.          DJNZ R3,$
  345.          MOV C,CG_YOUWEN      ;从传感器总线读得一个BIT
  346. ;*****************************
  347. L5A:     MOV R3,#3CH
  348.          DJNZ R3,$            ;等待100微妙
  349.          RRC A                ;把读得的位值环移给A
  350.          DJNZ R2,RE01         ;读下一个BIT
  351.          MOV @R1,A
  352.          INC R1
  353.          DJNZ R4,RE00         ;没有读完，继续
  354. ;+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  355. ;         JB FLAG0,L000
  356. ;         PUSH A
  357. ;         MOV A,#WENDSD
  358. ;         CLR C
  359. ;         SUBB  A,TEMPL      ;减数>被减数，则
  360. ;        JC L00
  361. ;         SETB FLAH3
  362. ;L00:     POP A
  363. L000:    RET
  364. ;*****************************************************
  365. ;处理温度 BCD 码子程序
  366. ;整数部分:取出 TEMPL 高四位和 TEMPH 低四位进行重新组合
  367. ;小数部分:取出 TEMPL 低四位,查小数码表
  368. ;****************************************************
  369. CONVTEMP:MOV  A,TEMPH       ;判温度是否零下
  370.          ANL  A,#80H
  371.          JZ  TEMPC1         ;温度零上转
  372.          SETB FLAH0         ;温度为负值
  373.          CLR  C
  374.          MOV  A,TEMPL       ;二进制数求补（双字节）
  375.          CPL  A             ;取反加1
  376.          ADD  A,#01H
  377.          MOV  TEMPL,A
  378.          MOV  A,TEMPH
  379.          CPL  A
  380.          ADDC  A,#00H
  381.          MOV  TEMPH,A
  382.          JMP  TEMPC2

  384. TEMPC1:  CLR  FLAH0               ;温度为正值
  385. TEMPC2:  MOV  A,TEMPL
  386.          ANL  A,#0FH              ;取出小数部分
  387.          MOV  B,#10               ;将TEMP_L的低四位X10/16得小数后一位数.
  388.          MUL  AB
  389.   MOV  B,#16
  390.   DIV  AB
  391.          MOV  70H,A               ;小数部分 BCD

  393.          MOV  A,TEMPL             ;整数部分
  394.          ANL  A,#0F0H             ;取出高四位
  395.          SWAP  A
  396.          MOV  TEMPL,A
  397.          MOV  A,TEMPH             ;取出低四位
  398.          ANL  A,#0FH
  399.          SWAP  A
  400.          ORL  A,TEMPL             ;重新组合温度数据
  401.          MOV  TEMP_ZH,A           ;重新组合的温度数据存入TEMP_ZH
  402.          LCALL  HEX2BCD1

  404.          MOV  TEMPL,A             ;(A)＝十位数和个位数
  405.          ANL  A,#0F0H
  406.          SWAP  A
  407.          MOV  72H,A               ;十位数 BCD
  408.          MOV  A,TEMPL
  409.          ANL  A,#0FH
  410.          MOV  71H,A               ;个位数 BCD
  411.          MOV  A,R4                ;(R4)= 百位数
  412.          MOV  73H,A

  414. TEMPC3:  RET
  415. ;====================================================
  416. ;单字节十六进制转BCD
  417. ;入口：(A)=单字节十六进制的温度值
  418. ;出口：(R4)= 百位数，(A)=十位数和个位数
  419. ;====================================================
  420. HEX2BCD1:MOV  B,#64H
  421.          DIV  AB
  422.          MOV  R4,A             ;(R4)＝百位数
  423.          MOV  A,#0AH
  424.          XCH  A,B
  425.          DIV  AB
  426.          SWAP  A
  427.          ORL  A,B             ;(A)＝十位数和个位数
  428.          RET

  430. ;==========================================================
  431. ; LCD 温度值显示子程序
  432. ;73H-70H 分别存放百位、十位、个位、小数位的数据
  433. ;==========================================================
  434. CONV01:   MOV  A,73H         ;加载百位数据
  435.           MOV  LCD_X,#1      ;设置显示位置
  436.           JNB  FLAH0,CONV0   ;
  437.           MOV  A,#"-"        ;显示"-"
  438.           MOV  B,LCD_X
  439.           CALL  LCDP2

  441.           MOV  A,72H         ;十位
  442.           CJNE A,#00H,CONV3
  443.           INC  LCD_X         ;调整显示地址
  444.           MOV  A,#" "        ;十位数等于0显示空格
  445.           MOV  B,LCD_X
  446.           CALL  LCDP2
  447.           JMP  CONV4

  449. CONV0:    CJNE A,#00H,CONV2

  451. CONV1:    MOV  A,#" "        ;百位数等于0显示空格
  452.           MOV  B,LCD_X
  453.           CALL  LCDP2
  454.           MOV  A,72H         ;十位
  455.           CJNE A,#00H,CONV3
  456.           INC  LCD_X         ;调整显示地址
  457.           MOV  A,#" "        ;十位数等于0显示空格
  458.           MOV  B,LCD_X
  459.           CALL  LCDP2
  460.           JMP  CONV4

  462. CONV2:    CALL  SHOW_DIG2    ;显示数据

  464. CONV3:    INC  LCD_X         ;调整显示地址
  465.           MOV  A,72H         ;十位
  466.           CALL  SHOW_DIG2

  468. CONV4:    INC  LCD_X         ;调整显示地址
  469.           MOV  A,71H         ;个位
  470.           CALL  SHOW_DIG2
  471.           INC  LCD_X         ;调整显示地址
  472.           MOV  A,#'.'
  473.           MOV  B,LCD_X
  474.           CALL  LCDP2
  475.           MOV  A,70H         ;加载小数位
  476.           INC  LCD_X         ;设置位置
  477.           CALL  SHOW_DIG2    ;显示数据
  478.           RET
  479. ;=============================================
  480. ;在LCD的第二行显示数据字符
  481. ;A=ASCII 数据, B=位置变量
  482. ;==============================================
  483. LCDP2:   PUSH  ACC        ;在LCD的第二行显示字符
  484.          MOV  A,B         ;设置显示地址
  485.          ADD  A,#90H     ;设置LCD的第二行地址
  486.          CALL  WCOM       ;写入命令
  487.          POP  ACC         ;由堆栈取出A
  488.          CALL  WDATA      ;写入数据
  489.          RET
  490. ;-------------------------------------------------------
  491. SHOW_DIG2:                 ;在 LCD 的第二行显示数字
  492.           ADD  A,#30H      ;加30H，转换为ASCII码
  493.           MOV  B,LCD_X     ;确定显示位置
  494.           CALL  LCDP2      ;送显示
  495.           RET
  496. ;*************************************************************************
  497. ;==========================================================
  498. ; LCD 温度值显示子程序2，显示在第四行
  499. ;73H-70H 分别存放百位、十位、个位、小数位的数据
  500. ;==========================================================
  501. CONV02:   MOV  A,73H         ;加载百位数据
  502.           MOV  LCD_X,#1      ;设置显示位置
  503.           JNB  FLAH0,CONV10   ;
  504.           MOV  A,#"-"        ;显示"-"
  505.           MOV  B,LCD_X
  506.           CALL  LCDP4

  508.           MOV  A,72H         ;十位
  509.           CJNE A,#00H,CONV13
  510.           INC  LCD_X         ;调整显示地址
  511.           MOV  A,#" "        ;十位数等于0显示空格
  512.           MOV  B,LCD_X
  513.           CALL  LCDP4
  514.           JMP  CONV14

  516. CONV10:   CJNE A,#00H,CONV12

  518. CONV11:   MOV  A,#" "        ;百位数等于0显示空格
  519.           MOV  B,LCD_X
  520.           CALL  LCDP4
  521.           MOV  A,72H         ;十位
  522.           CJNE A,#00H,CONV13
  523.           INC  LCD_X         ;调整显示地址
  524.           MOV  A,#" "        ;十位数等于0显示空格
  525.           MOV  B,LCD_X
  526.           CALL  LCDP4
  527.           JMP  CONV14

  529. CONV12:   CALL  SHOW_DIG4    ;显示数据

  531. CONV13:   INC  LCD_X         ;调整显示地址
  532.           MOV  A,72H         ;十位
  533.           CALL  SHOW_DIG4

  535. CONV14:   INC  LCD_X         ;调整显示地址
  536.           MOV  A,71H         ;个位
  537.           CALL  SHOW_DIG4
  538.           INC  LCD_X         ;调整显示地址
  539.           MOV  A,#'.'
  540.           MOV  B,LCD_X
  541.           CALL  LCDP4
  542.           MOV  A,70H         ;加载小数位
  543.           INC  LCD_X         ;设置位置
  544.           CALL  SHOW_DIG4    ;显示数据
  545.           RET
  546. ;=============================================
  547. ;在LCD的第二行显示数据字符
  548. ;A=ASCII 数据, B=位置变量
  549. ;==============================================
  550. LCDP4:   PUSH  ACC        ;在LCD的第二行显示字符
  551.          MOV  A,B         ;设置显示地址
  552.          ADD  A,#98H      ;设置LCD的第二行地址
  553.          CALL  WCOM       ;写入命令
  554.          POP  ACC         ;由堆栈取出A
  555.          CALL  WDATA      ;写入数据
  556.          RET
  557. ;-------------------------------------------------------
  558. SHOW_DIG4:                 ;在 LCD 的第二行显示数字
  559.           ADD  A,#30H      ;加30H，转换为ASCII码
  560.           MOV  B,LCD_X     ;确定显示位置
  561.           CALL  LCDP4      ;送显示
  562.           RET
  563. ;*************************************************************************
  564. ;------------------------------------------------------------------
  565. ;传感器 写命令、数据子程序
  566. ;根据命令的内容，进行写操作
  567. ;------------------------------------------------------------------
  568. WRITE:  MOV R2,#8            ;8位数据长度
  569.         CLR  C
  570. WR1:    JNB FLAG0,L21
  571.         CLR CG_CHENEI        ;开始写入传感器总线要处于复位（低）状态
  572.         MOV R3,#08
  573.         DJNZ R3,$            ;总线复位保持16微妙以上
  574.         RRC A                ;把一个字节DATA 分成8个BIT环移给C
  575.         MOV CG_CHENEI,C      ;写入一个BIT
  576.         MOV R3,#3CH
  577.         DJNZ R3,$            ;等待120微妙
  578.         SETB CG_CHENEI       ;重新释放总线
  579.         NOP
  580.         DJNZ R2,WR1          ;写入下一个BIT
  581.         SETB CG_CHENEI
  582.         RET

  584. L21:    JNB FLAG1,L22
  585.         CLR CG_CHEWAI        ;开始写入传感器总线要处于复位（低）状态
  586.         MOV R3,#08
  587.         DJNZ R3,$            ;总线复位保持16微妙以上
  588.         RRC A                ;把一个字节DATA 分成8个BIT环移给C
  589.         MOV CG_CHEWAI,C      ;写入一个BIT
  590.         MOV R3,#3CH
  591.         DJNZ R3,$            ;等待120微妙
  592.         SETB CG_CHEWAI       ;重新释放总线
  593.         NOP
  594.         DJNZ R2,WR1          ;写入下一个BIT
  595.         SETB CG_CHEWAI
  596.         RET

  598. L22:    JNB FLAG2,L23
  599.         CLR CG_SHUIWE        ;开始写入传感器总线要处于复位（低）状态
  600.         MOV R3,#08
  601.         DJNZ R3,$            ;总线复位保持16微妙以上
  602.         RRC A                ;把一个字节DATA 分成8个BIT环移给C
  603.         MOV CG_SHUIWE,C      ;写入一个BIT
  604.         MOV R3,#3CH
  605.         DJNZ R3,$            ;等待120微妙
  606.         SETB CG_SHUIWE       ;重新释放总线
  607.         NOP
  608.         DJNZ R2,WR1          ;写入下一个BIT
  609.         SETB CG_SHUIWE
  610.         RET

  612. L23:    JNB FLAG3,L24
  613.         CLR CG_YOUWEN        ;开始写入传感器总线要处于复位（低）状态
  614.         MOV R3,#08
  615.         DJNZ R3,$            ;总线复位保持16微妙以上
  616.         RRC A                ;把一个字节DATA 分成8个BIT环移给C
  617.         MOV CG_YOUWEN,C      ;写入一个BIT
  618.         MOV R3,#3CH
  619.         DJNZ R3,$            ;等待120微妙
  620.         SETB CG_YOUWEN       ;重新释放总线
  621.         NOP
  622.         DJNZ R2,WR1          ;写入下一个BIT
  623.         SETB CG_YOUWEN
  624. L24:    RET

  626. ;=================================================
  627. MENU_OK1: MOV  DPTR,#M_OK11  ;指针指到显示信息区
  628.           MOV  A,#1          ;显示在第一行
  629.           CALL  LCD_PRINT
  630.           MOV  DPTR,#M_OK12  ;指针指到显示信息区
  631.           MOV  A,#2          ;显示在第二行
  632.           CALL  LCD_PRINT
  633.           MOV  DPTR,#M_OK13  ;指针指到显示信息区
  634.           MOV  A,#3          ;显示在第二行
  635.           CALL  LCD_PRINT
  636.           MOV  DPTR,#M_OK14  ;指针指到显示信息区
  637.           MOV  A,#4          ;显示在第二行
  638.           CALL  LCD_PRINT
  639.           RET
  640. M_OK11:   DB"车内温度：      ",0
  641. M_OK12:   DB"            ℃ ",0
  642. M_OK13:   DB"车外温度：      ",0
  643. M_OK14:   DB"            ℃ ",0
  644. ;=================================================
  645. MENU_OK2: MOV  DPTR,#M_OK21  ;指针指到显示信息区
  646.           MOV  A,#1          ;显示在第一行
  647.           CALL  LCD_PRINT
  648.           MOV  DPTR,#M_OK22  ;指针指到显示信息区
  649.           MOV  A,#2          ;显示在第二行
  650.           CALL  LCD_PRINT
  651.           MOV  DPTR,#M_OK23  ;指针指到显示信息区
  652.           MOV  A,#3          ;显示在第二行
  653.           CALL  LCD_PRINT
  654.           MOV  DPTR,#M_OK24  ;指针指到显示信息区
  655.           MOV  A,#4          ;显示在第二行
  656.           CALL  LCD_PRINT
  657.           RET
  658. M_OK21:   DB"水温：         ",0
  659. M_OK22:   DB"            ℃ ",0
  660. M_OK23:   DB"油温：         ",0
  661. M_OK24:   DB"            ℃ ",0

  663. ;==================================================
  664. ;在LCD的第一行或第二行显示字符串
  665. ;DPTR = 放字符串的地址
  666. ;==================================================
  667. LCD_PRINT:CJNE  A,#1,LINE2  ;判断是否为第一行
  668. LINE1:    MOV  A,#80H       ;设置 LCD 的第一行地址
  669.           CALL  WCOM        ;写入命令
  670.           CALL  CLR_LINE    ;清除该行字符数据
  671.           MOV  A,#80H       ;设置 LCD 的第一行地址
  672.           CALL  WCOM        ;写入命令
  673.           JMP  FILL

  675. LINE2:    CJNE  A,#2,LINE3  ;判断是否为第二行
  676.           MOV  A,#90H       ;设置 LCD 的第二行地址
  677.           CALL  WCOM        ;写入命令
  678.           CALL  CLR_LINE    ;清除该行字符数据
  679.           MOV  A,#90H       ;设置 LCD 的第二行地址
  680.           CALL  WCOM
  681.           JMP  FILL

  683. LINE3:    CJNE  A,#3,LINE4  ;判断是否为第三行
  684.           MOV  A,#88H       ;设置 LCD 的第三行地址
  685.           CALL  WCOM        ;写入命令
  686.           CALL  CLR_LINE    ;清除该行字符数据
  687.           MOV  A,#88H       ;设置 LCD 的第三行地址
  688.           CALL  WCOM
  689.           JMP  FILL

  691. LINE4:    MOV  A,#98H      ;设置 LCD 的第四行地址
  692.           CALL  WCOM        ;写入命令
  693.           CALL  CLR_LINE    ;清除该行字符数据
  694.           MOV  A,#98H      ;设置 LCD 的第四行地址
  695.           CALL  WCOM

  697. FILL:     CLR  A            ;填入字符
  698.           MOVC  A,@A+DPTR   ;由信息区取出字符
  699.           CJNE  A,#0,LC1    ;判断是否为结束码
  700.           RET

  702. LC1:      CALL  WDATA       ;写入数据
  703.           INC  DPTR         ;指针加1
  704.           JMP  FILL         ;继续填入字符
  705. ;===============================================
  706. ;清除一行 LCD 的字符
  707. ;输入一行空格，来替代原显示字符
  708. ;===============================================
  709. CLR_LINE: MOV  R0,#24       ;清除该行 LCD 的字符
  710. CL1:      MOV  A,#' '
  711.           CALL  WDATA
  712.           DJNZ  R0,CL1
  713.           RET
  714. ;====================================================
  715. ;传感器 复位与检测子程序
  716. ;传感器 正常 FLAG* 置 1，不正常 FLAG* 置 0。
  717. ;====================================================
  718. RESET:  JNB FLAG0,L31
  719.         SETB CG_CHENEI        ;
  720.         NOP
  721.         CLR CG_CHENEI
  722.         MOV R0,#6BH           ;主机发出延时复位低脉冲
  723.         MOV R1,#04H
  724. TSR11:  DJNZ R0,$             ;延时
  725.         MOV R0,#6BH
  726.         DJNZ R1,TSR11
  727.         SETB CG_CHENEI        ;然后拉高数据线
  728.         NOP
  729.         NOP
  730.         NOP
  731.         MOV R0,#32H
  732. TSR21:  JNB CG_CHENEI,TSR31   ;等待传感器回应
  733.         DJNZ R0,TSR21
  734.         JMP TSR41             ; 延时
  735. TSR31:  SETB FLAG4            ; 置标志位,表示DS1820存在
  736.         JMP TSR51
  737. TSR41:  CLR FLAG4             ; 清标志位,表示DS1820不存在
  738.         JMP TSR61
  739. TSR51:  MOV R0,#06BH
  740.         DJNZ R0,$             ; 时序要求延时一段时间
  741. TSR61:  SETB CG_CHENEI
  742.         RET
  743. ;------------------------
  744. L31:    JNB FLAG1,L32
  745.         SETB CG_CHEWAI        ;
  746.         NOP
  747.         CLR CG_CHEWAI
  748.         MOV R0,#6BH           ;主机发出延时复位低脉冲
  749.         MOV R1,#04H
  750. TSR12:  DJNZ R0,$             ;延时
  751.         MOV R0,#6BH
  752.         DJNZ R1,TSR12
  753.         SETB CG_CHEWAI        ;然后拉高数据线
  754.         NOP
  755.         NOP
  756.         NOP
  757.         MOV R0,#32H
  758. TSR22:  JNB CG_CHEWAI,TSR32   ;等待传感器回应
  759.         DJNZ R0,TSR22
  760.         JMP TSR42             ; 延时
  761. TSR32:  SETB FLAG5            ; 置标志位,表示DS1820存在
  762.         JMP TSR52
  763. TSR42:  CLR FLAG5             ; 清标志位,表示DS1820不存在
  764.         JMP TSR62
  765. TSR52:  MOV R0,#06BH
  766.         DJNZ R0,$             ; 时序要求延时一段时间
  767. TSR62:  SETB CG_CHEWAI
  768.         RET
  769. ;------------------------
  770. L32:    JNB FLAG2,L33
  771.         SETB CG_SHUIWE        ;
  772.         NOP
  773.         CLR CG_SHUIWE
  774.         MOV R0,#6BH           ;主机发出延时复位低脉冲
  775.         MOV R1,#04H
  776. TSR13:  DJNZ R0,$             ;延时
  777.         MOV R0,#6BH
  778.         DJNZ R1,TSR13
  779.         SETB CG_SHUIWE        ;然后拉高数据线
  780.         NOP
  781.         NOP
  782.         NOP
  783.         MOV R0,#32H
  784. TSR23:  JNB CG_SHUIWE,TSR33   ;等待传感器回应
  785.         DJNZ R0,TSR23
  786.         JMP TSR43             ; 延时
  787. TSR33:  SETB FLAG6            ; 置标志位,表示DS1820存在
  788.         JMP TSR53
  789. TSR43:  CLR FLAG6             ; 清标志位,表示DS1820不存在
  790.         JMP TSR63
  791. TSR53:  MOV R0,#06BH
  792.         DJNZ R0,$             ; 时序要求延时一段时间
  793. TSR63:  SETB CG_SHUIWE
  794.         RET
  795. ;------------------------
  796. L33:    JNB FLAG3,L34
  797.         SETB CG_YOUWEN        ;
  798.         NOP
  799.         CLR CG_YOUWEN
  800.         MOV R0,#6BH           ;主机发出延时复位低脉冲
  801.         MOV R1,#04H
  802. TSR14:  DJNZ R0,$             ;延时
  803.         MOV R0,#6BH
  804.         DJNZ R1,TSR14
  805.         SETB CG_YOUWEN        ;然后拉高数据线
  806.         NOP
  807.         NOP
  808.         NOP
  809.         MOV R0,#32H
  810. TSR24:  JNB CG_YOUWEN,TSR34   ;等待传感器回应
  811.         DJNZ R0,TSR24
  812.         JMP TSR44             ; 延时
  813. TSR34:  SETB FLAG7            ; 置标志位,表示DS1820存在
  814.         JMP TSR54
  815. TSR44:  CLR FLAG7             ; 清标志位,表示DS1820不存在
  816.         JMP TSR64
  817. TSR54:  MOV R0,#06BH
  818.         DJNZ R0,$             ; 时序要求延时一段时间
  819. TSR64:  SETB CG_YOUWEN
  820. L34:    RET
  821. ;------------------------

  823. ;==========================================================
  824. ;=================================================
  825. ;对 LCD 做初始化设置
  826. ;=================================================
  827. SET_LCD:  MOV A,#34H      ;34H--扩充指令操作
  828.           CALL  WCOM         ;写入命令
  829.    MOV A,#30H      ;30H--基本指令操作
  830.           CALL  WCOM         ;写入命令
  831.    MOV A,#01H      ;清除显示
  832.           CALL  WCOM         ;写入命令
  833.           MOV A,#06H      ;指定在资料写入或读取时，光标的移动方向
  834.           CALL  WCOM         ;DDRAM 的地址计数器(AC)加1
  835.    MOV A,#0CH      ;开显示,关光标,不闪烁
  836.           CALL  WCOM         ;写入命令

  838.           RET

  840. ;==================================================
  841. ;===============================================
  842. ;命令写入子程序
  843. ;RS=L,RW=L,D0-D7=指令码，E=高脉冲
  844. ;以8位控制方式将命令写至LCD
  845. ;===============================================
  846. WCOM:    LCALL CHK_BUSY
  847.   CLR LCD_RS
  848.   CLR LCD_RW
  849.   MOV LCD_SJ,A
  850.   SETB LCD_EN
  851.   NOP
  852.   NOP
  853.   CLR LCD_EN
  854.   RET
  855. ;===============================================
  856. ;数据写入子程序
  857. ;RS=H,RW=L,D0-D7=指令码，E=高脉冲
  858. ;以8位控制方式将数据写至LCD
  859. ;===============================================
  860. WDATA:    MOV  LCD_SJ,A       ;写入数据
  861.           SETB  LCD_RS
  862.           CLR  LCD_RW
  863.           SETB  LCD_EN
  864.           CALL  DE
  865.           CLR  LCD_EN
  866.           CALL  DE
  867.           RET
  868. ;**********************************************************

  870. ;测忙碌子程序
  871. ;RS=0,RW=1,E=H,D0-D7=状态字

  873. ;**********************************************************
  874. CHK_BUSY:  MOV LCD_SJ,#0FFH    ;测忙碌子程序
  875.     CLR LCD_RS
  876.     SETB LCD_RW
  877.     SETB LCD_EN
  878.     JB LCD_SJ.7,$
  879.     CLR LCD_EN
  880.     RET

  882. ;====================================================
  883. ;实时温度值与设定报警温度值 TH、TL 比较子程序
  884. ;当实际温度大于 TH 的设定值时，显示“过高”并闪动显示
  885. ;当实际温度小于 TH 的设定值时，显示“正常”
  886. ;当实际温度小于 TL 的设定值时，显示“过低”
  887. ;====================================================
  888. TEMP_COMP:JNB FLAG2,L101
  889.           MOV TEMP_TH,#SWGWSD
  890.           MOV TEMP_TL,#SWDWSD      ;设置 LCD 的第一行地址
  891.           SJMP L102
  892. L101:     JNB FLAG3,L103
  893.           MOV TEMP_TH,#YWGWSD
  894.           MOV TEMP_TL,#YWDWSD

  896. L102:     MOV  A,TEMP_ZH
  897.           CJNE  A,TEMP_TH,T_COMP0
  898. T_COMP0:  JNC   CHULI1
  899.           MOV  A,TEMP_ZH
  900.           SUBB  A,TEMP_TL       ;减数>被减数，则
  901.           JC  CHULI2            ;借位标志位C=1，转

  903.           MOV  DPTR,#BJ50       ;显示"正常"
  904.           CALL  TEMP_BJ3
  905.           CLR   FLAG1           ;清除报警标志
  906. L103:     RET

  908. CHULI1:   MOV  DPTR,#BJ60       ;形成闪烁效果
  909.           CALL  TEMP_BJ3
  910.           MOV  R5,#10           ;延时10MS
  911.           ACALL DELAY1
  912.           MOV  DPTR,#BJ30       ;显示"过高"
  913.           CALL  TEMP_BJ3
  914.           SETB  FLAG1           ;设置报警标志
  915.           RET

  917. CHULI2:   MOV  DPTR,#BJ40       ;显示"过低"
  918.           CALL  TEMP_BJ3
  919.           CLR   FLAG1           ;清除报警标志
  920.           RET
  921. ;=========================================
  922. ;标记字符写入子程序
  923. ;=========================================
  924. TEMP_BJ3: JNB FLAG2,L001
  925.           MOV  A,#86H       ;设置 LCD 的第一行地址
  926.           SJMP L002
  927. L001:     JNB FLAG3,L004
  928.           MOV  A,#8EH       ;设置 LCD 的第三行地址
  929. L002:     CALL  WCOM
  930. L003:     CLR  A            ;填入字符
  931.           MOVC  A,@A+DPTR   ;由信息区取出字符
  932.           CJNE  A,#0,L005   ;判断是否为结束码
  933. L004:     RET

  935. L005:     CALL  WDATA       ;写入数据
  936.           INC  DPTR         ;指针加1
  937.           JMP  L003         ;继续填入字符

  939. BJ30:     DB  "过高",0      ;过高标记
  940. BJ40:     DB  "过低",0      ;正常标记
  941. BJ50:     DB  "正常",0      ;过低标记
  942. BJ60:     DB  "    ",0      ;过低标记
  943. ;**********************************************************
  944. ;语音驱动和播放程序
  945. ;**********************************************************
  946. ;50H为语音段地址暂存器，1到210段，实际用到40
  947. ;50H为E0H～E7H时分别代表自低往高的8级音量
  948. ;在语音播放过程中发送F2H至50H可循环播放当前地址语音
  949. ;发送FEH至50H停止播放语音
  950. ;****************************************************
  951. YUYIN: RET        ;$$$$$$$$$$$$$
  952.        MOV TMOD,#00000001B ;定时/计数器0工作于方式1
  953.        MOV R6,#08H         ;发码8位循环数据
  954.        LCALL ONE_LINE      ;调用一线发码子程序
  955.        RET

  957. ONE_LINE:                  ;////一线发码子程序
  958.        SETB YYRST          ;复位
  959.        MOV R7,#2           ;延时2MS
  960.        LCALL DELAY1MS
  961.        CLR YYRST           ;延时使系统稳定
  962.        MOV R7,#6           ;延时6MS
  963.        LCALL DELAY1MS
  964.        CLR YYSDA           ;唤醒语音芯片
  965.        MOV R7,#17          ;延时17MS
  966.        LCALL DELAY1MS
  967.        MOV A,YY_DAT

  969. LP1:   SETB YYSDA
  970.        RRC A               ;分辨50H内的数据各位是高电平还是低电平
  971.        JNC DIDIANPIN       ;高电平用高:低=2:1的脉宽表示
  972.        LCALL DELAY200US
  973.        LCALL DELAY200US
  974.        LCALL DELAY200US
  975.        CLR YYSDA
  976.        LCALL DELAY200US
  977. LP2:   DJNZ R6,LP1         ;查看数据是否发完，未发完继续发
  978.        MOV R6,#08H
  979.        SETB YYSDA
  980.        RET

  982. DIDIANPIN:                 ;低电平用高:低=1:2的脉宽表示
  983.        LCALL DELAY200US
  984.        CLR YYSDA
  985.        LCALL DELAY200US
  986.        LCALL DELAY200US
  987.        LCALL DELAY200US
  988.        SJMP LP2

  990. ;以下为延时子程序
  991. DELAY200US:                ;延时200US子程序，晶振11.0592MHz，方式1
  992.        MOV  TH0,#0FFH
  993.        MOV  TL0,#47H
  994.        SETB TR0
  995. LOP1:  JBC  TF0,NEXT1
  996.        SJMP LOP1
  997. NEXT1: CLR TR0
  998.        RET

  1000. DELAY1MS:                  ;延时1ms子程序
  1001.        MOV  TH0,#0FCH
  1002.        MOV  TL0,#66H
  1003.        SETB TR0
  1004. LOP2:  JBC  TF0,NEXT2
  1005.        SJMP LOP2
  1006. NEXT2: DJNZ R7,DELAY1MS
  1007.        CLR TR0
  1008.        RET
  1009. ;**********************************************************
  1010. ;延时子程序
  1011. ;**********************************************************
  1012. DE:       MOV  R7,#250        ;延时 500 微秒
  1013.           DJNZ  R7,$
  1014.           RET
  1015. ;===============================================
  1016. DELAY:   MOV  R5,#20      ;延时20MS
  1017. DELAY1:  MOV  R6,#48      ;50
  1018. DL1:     MOV  R7,#96      ;100
  1019.          DJNZ  R7,$
  1020.          DJNZ  R6,DL1
  1021.          DJNZ  R5,DELAY1
  1022.          RET              ;96*2*48*(12/11.0592)+2*(12/11.0592)≈10000uS=10mS

  1024.           END
复制代码


万年历, 电子钟, 温度传感器, 检测仪, 程序
分享到:  QQ好友和群QQ好友和群 QQ空间QQ空间 腾讯微博腾讯微博 腾讯朋友腾讯朋友
收藏收藏 分享淘帖 顶顶 踩踩

相关帖子
回复

举报

沙发
ID:72846 发表于 2015-1-28 11:46 | 只看该作者
我测试下，感谢分享
回复

举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

小黑屋|51黑电子论坛 |51黑电子论坛6群 QQ 管理员QQ:125739409;技术交流QQ群281945664

Powered by 单片机教程网

快速回复 返回顶部 返回列表