下面，我们再来学习字符型液晶模块TC1602的使用，接口单片机是at89s51。
【1602液晶模块简介】
字符型型液晶是一种用5×7点阵图形来显示字符的液晶显示器，根据显示的容量可以分为1行16个字、2行16个字、2行20个字等，最常用的为2行16个字，即我们马上要学习的1602液晶模块，下面(图1)就是TC1602液晶模块的正面和反面照片。
 |
||
|
图1： 《TC1602液晶模块》 |
||
液晶屏显示模块与数码管相比，它显得更为专业、漂亮。液晶显示屏以其微功耗、体积小、显示内容丰富、超薄轻巧、使用方便等诸多优点，在仪器仪表、电子设备、家用电器等低功耗应用系统中得到越来越广泛的应用，使这些电子设备的人机界面变得越来越直观形象，目前已广泛应用于电子表、计算器、IC卡电话机、液晶电视机、便携式电脑、掌上型电子玩具、复印机、传真机等许多方面。本站S51增强型实验板配套的液晶模块是TC1602EL字符型液晶模块(带背光)，它是目前使用最为广泛的液晶屏之一，相信你学会了对它的使用，那你对其它的液晶屏的使用也能得心应手，毕竟基本原理都差不多。
本站使用带背光的液晶模块TC1602EL，TC1602EL采用标准的16脚接口，其引脚功能如下：
第1脚：VSS为电源地，接GND。
第2脚：VDD接5V正电源。
第3脚：VL为液晶显示器对比度调整端，接正电源时对比度最弱，接地电源时对比度最高，对比度过高时会产生“鬼影”，使用时可以通过一个10K的电位器调整对比度。
第4脚：RS为寄存器选择，高电平时选择数据寄存器、低电平时选择指令寄存器。
第5脚：RW为读写信号线，高电平时进行读操作，低电平时进行写操作。当RS和RW共同为低电平时可以写入指令或者显示地址，当RS为低电平RW为高电平时可以读忙信号，当RS为高电平RW为低电平时可以写入数据。
第6脚：E端为使能端，当E端由高电平跳变成低电平时，液晶模块执行命令。
第7～14脚：D0～D7为8位双向数据线。
第15脚：BLA背光电源正极(+5V)输入引脚。
第16脚：BLK背光电源负极，接GND。
|
注意：液晶模块背光须消耗电流约为50mA左右，S51增强型实验板上设计了DIP微动开关来控制背光的开关，如右图所示，当实验板上的DIP开关(第3位)拨打到ON状态时，液晶背光显示，拨到OFF状态时，背光关闭。 |
 |
TC1602液晶模块内带标准字库，内部的字符发生存储器（CGROM）已经存储了192个5×7点阵字符，32个5×10点阵字符。另外还有字符生成RAM（CGRAM）512字节，供用户自定义字符。如表1所示，这些字符有：阿拉伯数字、英文字母的大小写、常用的符号、和日文假名等，每一个字符都有一个固定的代码，比如大写的英文字母“A”的代码是01000001B（41H），显示时模块把地址41H中的点阵字符图形显示出来，我们就能看到字母“A”。
 |
|
表1： CGROM和CGRAM中字符代码与字符图形对应关系 |
1602液晶模块内部的控制器共有11条控制指令，如表2所示。它的读写操作、屏幕和光标的操作都是通过指令编程来实现的。（说明：1为高电平、0为低电平）
 |
|
表2： 1602液晶模块内部的控制器共有11条控制指令 |
指令1：清显示，指令码01H,光标复位到地址00H位置
指令2：光标复位，光标返回到地址00H
指令3：光标和显示模式设置 I/D：光标移动方向，高电平右移，低电平左移 S:屏幕上所有文字是否左移或者右移。高电平表示有效，低电平则无效
指令4：显示开关控制。 D：控制整体显示的开与关，高电平表示开显示，低电平表示关显示 C：控制光标的开与关，高电平表示有光标，低电平表示无光标 B：控制光标是否闪烁，高电平闪烁，低电平不闪烁
指令5：光标或显示移位 S/C：高电平时移动显示的文字，低电平时移动光标
指令6：功能设置命令 DL：高电平时为4位总线，低电平时为8位总线 N：低电平时为单行显示，高电平时双行显示 F: 低电平时显示5x7的点阵字符，高电平时显示5x10的点阵字符
指令7：字符发生器RAM地址设置
指令8：DDRAM地址设置
指令9：读忙信号和光标地址 BF：为忙标志位，高电平表示忙，此时模块不能接收命令或者数据，如果为低电平表示不忙。
指令10：写数据
指令11：读数据
下面是TC1602液晶模块的一些主要技术参数：
1、逻辑工作电压（VDD）：+4.5 ～ +5.5V
2、LCD驱动电压（VDD - VL）：+4.5 ～ +13.0V
3、工作温度（Ta）： 0 ～ 60°C（常温）/-20 ～ 75 °C（宽温）
4、工作电流： < 2.0mA
5、屏幕视域尺寸： 62.5 × 16.1mm
【TC1602EL液晶模块应用编程】
TC1602EL液晶显示模块可以和51系列单片机直接接口，下面就是S51增强型实验板的液晶接口电路(图2)。
 |
|
图2 |
液晶显示模块是一个慢显示器件，所以在执行每条指令之前一定要确认模块的忙标志为低电平，表示不忙，否则此指令失效。要显示字符时要先输入显示字符地址，也就是告诉模块在哪里显示字符，表3是TC1602EL液晶模块的内部显示地址。
 |
|
表3：1602液晶内部显示地址 |
比如第二行第一个字符的地址是40H，那么是否直接写入40H就可以将光标定位在第二行第一个字符的位置呢？这样不行，因为写入显示地址时要求最高位D7恒定为高电平1所以实际写入的数据应该是01000000B（40H）＋10000000B（80H）＝11000000B（C0H），下面就是在1602液晶模块第一行第1个字符位置显示字母“A”程序。
;*******************TC1602液晶模块字符显示试验**********************************
;******** 在1602液晶模块第一行第1个字符位置显示字母“A”程序 ********
RS EQU P3.4
RW EQU P3.5
E EQU P3.6
ORG 0000H
AJMP START
ORG 0033H
START: MOV SP,#60H
MAIN: LCALL DELAY ;判断液晶忙状态？
ACALL ENABLE
MOV P1,#00000001B ;写指令01H,清屏
ACALL ENABLE
MOV P1,#00111000B ;写指令38H,设定LCD为16×2显示，5×7点阵，8位数据接口
ACALL ENABLE
MOV P1,#00001111B ;写指令0FH,显示ON,光标ON,闪烁ON
ACALL ENABLE
MOV P1,#00000110B ;写指令06H,文字不动，光标自动右移
ACALL ENABLE
MOV P1,#80H ;第一行第1个字符地址
ACALL ENABLE
MOV P1,#01000001B ;字母A的代码(#41H)
SETB RS ;RS=1
CLR RW ;RW=0
CLR E ;E=0
ACALL DELAY ;判断液晶忙状态？
SETB E ;E=1
AJMP $
;-----------------
ENABLE: CLR RS ;写入控制命令的子程序
CLR RW
CLR E
ACALL DELAY
SETB E
RET
;-----------------
DELAY: MOV P1,#0FFH ;判断液晶显示器是否忙的子程序
CLR RS
SETB RW
CLR E
NOP
SETB E
JB P1.7,DELAY ;如果为高电平表示忙就循环等待
RET
END
程序在开始时对液晶模块功能进行了初始化设置，约定了显示格式。注意显示字符时光标是自动右移的，无需人工干预，每次输入指令都先调用判断液晶模块是否忙的子程序DELAY，然后输入显示位置的地址80H（第一行第1字符），最后输入要显示的字符"A"的代码41H，显示效果下面如图3所示。
|
图3： 1602液晶显示一个字符“A” |
前面我们进行了液晶显示一个字符“A”的实验，接下来再来编一个稍复杂点的多字符显示程序，相信你有了第一个程序的经验，下面的程序也就没有什么难度了，毕竟程序都差不多。下面程序实现两行显示：第1行显示"welcme!"，第2行显示"www.ourmpu.com"。显示效果见下图4。
;******** TC1602液晶模块字符显示试验单片机汇编程序 ********
;******** 第一行显示“welcme! ********
;******** 第二行显示“www.ourmpu.com” ********
RS EQU P3.4
RW EQU P3.5
E EQU P3.6
ORG 0000H
AJMP START
ORG 0033H
START: MOV SP,#60H
MAIN: LCALL DELAY ;延时一段时间
MOV P1,#01H ;写指令01H,清屏
LCALL ENABLE
MOV P1,#38H ;写指令38H,设定LCD为16*2显示，5*7点阵，8位数据接口
LCALL ENABLE
MOV P1,#0FH ;写指令0FH,显示ON,光标ON,闪烁ON
LCALL ENABLE
MOV P1,#06H ;写指令06H,光标输入方式增量移位
LCALL ENABLE
MOV P1,#80H ;第一行起始字符地址
LCALL ENABLE
MOV DPTR,#TABLE1 ;第一行显示字符表头地址
LCALL DISP ;显示第一行数据
MOV P1,#0C0H ;第二行起始字符地址
LCALL ENABLE
MOV DPTR,#TABLE2 ;第二行显示字符表头地址
LCALL DISP ;显示第二行数据
AJMP MAIN ;返回主程序循环
;-----------------
ENABLE: CLR RS ;写指令子程序(请参照1602LCD使用说明书)
CLR RW
CLR E
LCALL DELAY
SETB E
RET
;-----------------
DISP: MOV R1,#16 ;准备显示一行16个字符
LOOP: MOV A,#00H ;将ACC清零
MOVC A,@A+DPTR ;查表取得要显示的数据
LCALL DISP1 ;写入一个数据
INC DPTR ;数据表指针加1,准备取下一个数据
DJNZ R1,LOOP ;一行没有显示完就继续
RET
;-----------------
DISP1: MOV P1,A ;写1字节数据到显示端口
SETB RS ;写数据时序(请参照1602LCD使用说明书)
CLR RW
CLR E
LCALL DELAY
SETB E
RET
;-----------------
DELAY: MOV R7,#255 ;延时子程序
D1: MOV R6,#255
D2: DJNZ R6,D2
DJNZ R7,D1
RET
TABLE1: DB " welcome! "
TABLE2: DB " www.ourmpu.com "
END
|
图4：《单片机驱动1602液晶多字符显示效果》 |
至此，我们学习了字符型液晶模块1602在S51增强型实验板上的应用及编程，相信大家看到一定这里都有点累了吧！现在回过头来再看看，其实液晶模块编程也并没有想像的那么高深、难学！现在，你就可以充分发挥你聪明才智，按自己的意愿及要求来编写各种各样的显示应用程序了，如万年历时钟、温度计、频率计等，可以充分发挥你的想象达到你所需要的各种显示效果。最后，让我们再欣赏一个基于S51增强型实验板开发的1602液晶模块高精度(4位小数)数字温度计的图片吧，见下图5所示。
|
图5：1602液晶显示DS18B20高精度(4位小数)测温效果 |
