经过几天的努力，第一个51单片机电子时钟终于出炉了，通过4位数码管来显示时间，系统晶振11.0592MHZ，仿真图中用二极管代替时钟冒号闪烁，非门代替三极管，让仿真速度与真实速度达到一致，本设计用了6个按钮来对时间及闹钟时间的调节、关闭，p3.2接时间分加1按钮，p3.3接时间时加1按钮，p3.4接闹钟时间与当前时间切换按钮，按住不放显示闹钟的时间，闹钟初始化为00：00，放开按钮则显示当前时间，p3.5接闹钟加1按钮，p3.6接闹钟时加1按钮，p3.7接关闭闹钟按钮
有没有人会问 ，怎么没有减的按钮呢？？？
为了不用那么多按钮，所以只设置了加1的按钮，那减的怎么办？？
程序的设计是这样的，当分加到59的时候，再加一次就变00，当时加到23的时候，再加一次就变00，从而实现了减的效果，O(∩_∩)O，附带仿真图和程序源代码及实物图.........
仿真图
实物图目前还差3个按钮，准备补上\(^o^)/~，电源的指示灯太亮了╮(╯▽╰)╭，准备把它拆了
作者：胡琴
联系qq：1257394091
本程序版本规本人所有可以任意转载：
技术支持网站：http://www.51hei.com
本程序已经通过软件仿真和硬件制作.
程序源代码：
org 0000h
ajmp main ;调至主程序
org 000bh ;T0中断入口地址
ljmp inti0
org 001bh ;T1中断入口地址
ljmp inti1
org 0030h
main:mov tmod,#11h ;设T0、T1为模式1
mov ie,#8ah ;开T0、T1中断允许
mov th0,#4ch ;赋T0 50ms初值
mov tl0,#00h
mov th1,#4ch ;赋T1 50ms初值
mov tl1,#00h
mov sp,#60h ;设置堆栈指针
mov r0,#20 ; T0 50ms计数20次
mov 31h,#00 ;时间秒初始化
mov 32h,#00 ;时间分初始化
mov 33h,#00 ;时间时初始化
mov 38h,#00 ;闹钟分初始化
mov 39h,#00 ;闹钟时初始化
setb tr0 ;启动T0
setb tr1 ;启动T1
loop:lcall display ;调用时间显示子程序
lcall key ;调用时间调节按键子程序
lcall keynz ;调用闹钟按键子程序
ajmp loop
inti0:push psw ;保护现场
push acc
clr ea ;关中断
mov th0,#4ch ;重赋50ms初值
mov tl0,#00h
djnz r0,out ;对50ms计数判断
mov r0,#20 ;重赋50ms计数值
inc 31h ;秒加1
cpl p2.2 ;P2.2取反输出
mov a,31h
cjne a,#60,out ;判秒是否加到60，没有加到中断返回
mov 31h,#00 ;秒加到60，对秒清零
inc 32h ;分加1
mov a,32h
cjne a,#60,out ;判分是否加到60，没有加到就中断返回
mov 32h,#00 ;分加到60，对分清零
inc 33h ;时加1
mov a,33h
cjne a,#24,out ;判时是否加到24，没有就中断返回
mov 33h,#00 ;时加到24，对时清零
out: setb ea ;开中断
pop acc ;恢复现场
pop psw
reti ;中断返回
inti1:push psw ;保护现场
push acc
clr ea ;关中断
mov th1,#4ch ;赋50ms初值
mov tl1,#00h
inc 3ah
mov a,3ah
cjne a,#20,out1 ;判断50ms计数是否到20，没到就中断返回
mov 3ah,#00 ;50ms计数到20，将计数单元清零
mov a,32h
cjne a,38h,out1 ;闹钟分与时间分判断
mov a,33h
cjne a,39h,out1 ;闹钟时与时间时判断
clr p1.0 ;相等就清p1.0输出
out1: setb ea ;开中断
pop acc ;恢复现场
pop psw
reti ;中断返回
display:mov a,31h ;秒显示
mov b,#10
div ab
mov 20h,a ;将秒十位存20h
mov 21h,b ;将秒个位存21h
disp1: mov a,20h ;秒十位显示
mov dptr,#table ;查表
movc a,@a+dptr ;将A与查表的值相加，回存给A
mov p0,a ;将A的值赋给P0口
clr p2.0 ;点亮秒十位
lcall del1ms ;调用延时1MS子程序
setb p2.0 ;灭秒十位
disp2: mov a,21h ;秒个位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.1
lcall del1ms
setb p2.1
disp3: mov a,32h ;分显示
mov b,#10
div ab
mov 22h,a
mov 23h,b
disp4: mov a,22h ;分十位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.6
lcall del1ms
setb p2.6
disp5: mov a,23h ;分个位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.7
lcall del1ms
setb p2.7
disp6: mov a,33h ;时显示
mov b,#10
div ab
mov 24h,a
mov 25h,b
disp7: mov a,24h ;时十位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
disp8: mov a,25h ;时个位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.5
lcall del1ms
setb p2.5
ret
display1:mov a,38h ;闹钟分显示
mov b,#10
div ab
mov 26h,a
mov 27h,b
dispnz1:mov a,26h ;闹钟分十位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.6
lcall del1ms
setb p2.6
dispnz2:mov a,27h ;闹钟分个位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.7
lcall del1ms
setb p2.7
dispnz3:mov a,39h ;闹钟时显示
mov b,#10
div ab
mov 28h,a
mov 29h,b
dispnz4:mov a,28h ;闹钟时十位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
dispnz5:mov a,29h ;闹钟时个位显示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.5
lcall del1ms
setb p2.5
ret
table:db 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H ;数字0-9的十六进制数
del1ms:mov r7,#10 ;1ms延时子程序
del1: mov r6,#50
del2:djnz r6,del2
djnz r7,del1
ret
del20ms:mov r5,#40 ;20ms延时子程序
del3:mov r4,#250
del4:djnz r4,del4
djnz r5,del3
ret
key:jnb p3.2,key1 ;时间分加1按钮
jnb p3.3,key2 ;时间时加1按钮
sjmp keyout
key1:lcall del20ms ;20ms延时消抖
jb p3.2,keyout
jnb p3.2,$ ;等待按键放开
inc 32h ;分加1
mov a,32h
cjne a,#60,keyout ;判分是否加到60，没有就返回
mov 32h,#00
sjmp keyout
key2:lcall del20ms ;20ms延时消抖
jb p3.3,keyout
jnb p3.3,$ ;等待按键放开
inc 33h ;时加1
mov a,33h
cjne a,#24,keyout ;判时是否加到24，没有就返回
mov 33h,#00 ;时加到24，时清零
sjmp keyout
keyout:ret
keynz:jnb p3.4,keynz1 ;闹钟时间和当前时间切换按钮
jnb p3.5,keynz2 ;闹钟加分1按钮
jnb p3.6,keynz3 ;闹钟时加1按钮
jnb p3.7,keynz4 ;关闭闹钟按钮
sjmp nzout
nz1:lcall display1 ;调用显示闹钟时间子程序
jnb p3.5,keynz2
jnb p3.6,keynz3
keynz1:jnb p3.4,nz1 ;按住按键不放开显示闹钟时间并可以调，放开则显示当前时间
sjmp nzout
keynz2:lcall del20ms
jb p3.5,nzout
jnb p3.5,$ ;等待按键放开
inc 38h ;闹钟分加1
mov a,38h
cjne a,#60,nzout ;判闹钟分是否加到60，没有就返回
mov 38h,#00 ;闹钟分加到60，将闹钟分清零
sjmp nzout
keynz3:lcall del20ms
jb p3.6,nzout
jnb p3.6,$ ;等待按键放开
inc 39h ;闹钟时加1
mov a,39h
cjne a,#24,nzout ;判闹钟时是否加到24，没有就中断返回
mov 39h,#00 ;闹钟时加到24，闹钟时清零
sjmp nzout
keynz4:jb p3.7,nzout
jnb p3.7,$ ;等待按键放开
setb p1.0 ;关闭闹钟
sjmp nzout
nzout:ret
end